définir une plage horaire à partir d'un planning

Bonjour,

Je suis un nouveau membre et je suis à la recherche d'une formule pour me déterminer la plage horaire de travail ( colonne P et Q) de mon document excel à partir du planning allant des colonnes B à N. (Sachant que dans mes cellules je rentre une valeur quand l'employé est sur son temps de travail)

Je suis désole si ce type de question à déjà été posé sur ce forum et je n'ai pas trouvé le sujet de cette discussionPièce jointe 159976.

Bonsoir,

Je suis toujours a la recherche de la formule concernant mon sujet.
Est ce que quelqu'un aurait une idée ou des pistes a exploiter ou il n'existe pas de formule?

Merci

Bonjour,
Si la matinée d'un employé quelconque correspond toujours à 7 "mini plages" de travail(durant un quart d'heure chacune)
toujours réparties de la même façon - 3 quarts d'heure puis un arrêt d'une demi heure puis une heure (c'est ce qui se passe
pour les deux employés donnés en exemple) - le problème revient à trouver le début de la première plage ce qui peut se faire
avec la fonction EQUIV.
Ecrire en P4 la formule :

Code:

---

=INDEX($B$3:$N$3;EQUIV("T";Feuil1!$B4:$N4;0))&"/"&INDEX($B$3:$N$3;EQUIV("T";Feuil1!$B4:$N4;0)+3)

---

en Q4 la formule :

Code:

---

=INDEX($B$3:$N$3;EQUIV("T";Feuil1!$B4:$N4;0)+5)&"/"&INDEX($B$3:$N$3;EQUIV("T";Feuil1!$B4:$N4;0)+9)

---

Recopier ces formules vers le bas.
Si ce n'est pas le cas, y a-t-il des règles constantes ?
- Toujours deux plages à trouver ? (je pense que oui d'après le demande)
- Toujours 1h45 de travail c'est à dire 7 "T" dans une ligne de planning ? oui? non ?
- Toujours la même répartition 45 mn puis 1 heure ? oui? non ?
- Toujours une demi heure d'écart entre les deux plages ? oui ? non ?
En l'absence de constantes de ce genre, le problème devient autrement difficile.
Cordialement
Claude

Re,
Autre proposition nécessitant seulement qu'il n'y ait que deux plagesà trouver.
Se placer dans une cellule de la ligne 4 et définir les quatre noms suivants :
debutplage1 par :

Code:

---

=EQUIV("T";Feuil1!$A4:$N4;0)

---

finplage1 par :

Code:

---

=MIN(SI(INDIRECT(ADRESSE(LIGNE();debutplage1;2)):Feuil1!$N4="";COLONNE(INDIRECT(ADRESSE(LIGNE();debutplage1;2)):Feuil1!$N4);""))

---

debutplage2 par :

Code:

---

=EQUIV("T";INDIRECT(ADRESSE(LIGNE();finplage1)):Feuil1!$N4;0)+finplage1-1

---

finplage2 par :

Code:

---

=MIN(SI(INDIRECT(ADRESSE(LIGNE();debutplage2;2)):Feuil1!$N4="";COLONNE(INDIRECT(ADRESSE(LIGNE();debutplage2;2)):Feuil1!$N4);""))

---

Puis écrire en P4 la formule :

Code:

---

=INDEX($A$3:$N$3;debutplage1)&"/"&INDEX($A$3:$N$3;finplage1)

---

et en Q4 la formule :

Code:

---

=INDEX($A$3:$N$3;debutplage2)&"/"&INDEX($A$3:$N$3;finplage2)

---

Recopier ces deux formules vers le bas
Cordialement
Claude

Tout d'abord merci papouclo,

Pour répondre a vos questions, c'est vers les deuxièmes formules qu'il faut se tourner car il n'y a aucune régularité dans les heures successives de travail et les modèles de pause.

J'ai essayé les formules et j'ai réussi pour celle de débutplage1. Par contre, pour finplage1,debutplage2 et finplage2 je ne doit pas rentrer les bonnes valeurs de ligne et de colonne car la formule me dit #valeur.


Un dernier point que j'ai oublié de précisé c'est qu'un quart d'heure de travail peut être matérialisé dans une cellule par un "T" ou une autre abréviations comme un "S".

Cordialement

Jurunner