Liens Hypertexte dans excel

Version imprimable

19/03/2011, 15h47
rondepierre

Liens Hypertexte dans excel

"Bonjour"
J'ai rentré dans un fichier excel les titres; compositeurs, etc de tous les morceaux de musique des CD que je possède (environ 300), ce qui correspond à 4000 morceaux.
De plus, j'ai sauvé et transformé en fichier MP3 chacun de ces 4000 morceaux sur une partition de mon disque dur.
Je souhaite, dans le fichier excel, créé un lien de telle sorte qu'en cliquant sur une cellule convenable, le morceau correspondant (MP3) s'exécute.
Est-il possible d'automatiser la création de ces liens sans les créer un par un.
"Merci"
19/03/2011, 18h02
Invité

Bonjour

C'est possible mais :

Il faut que sur le nom du fichier (le MP3) que tu ais un moyen (nom de la chanson par exemple) de repérer celui-ci par rapport à ce qu'il y a dans le fichier Excel.

Si c'est le cas, c'est possible.

Tu as sur le forum et la FAQ pleins de solutions pour résoudre sur ce problème, en faisant une recherche sur la récursivité (la rechercher récursive) te permettra de parcourir les fichiers.

De plus tu trouveras dans la FAQ Excel le moyen de jouer des fichiers MP3.

Philippe
20/03/2011, 15h06
rondepierre

Liens hypertextes dans excel

Bonjour,
Merci pour ta réponse.
Je pourrais sans doute résoudre le problème si j'arrivais à recopier dans un fichier excel les chemins complets de mes 4000 fichiers mp3.
Y a-t-il un moyen d'automatiser cette copie par une macro ?
20/03/2011, 15h33
kiki29

Salut,comme dit plus haut par Philippe ,voir par exemple http://www.developpez.net/forums/d20...feuille-excel/ et adapter à ton contexte

Bonjour
Voici un code qui liste tous les fichiers d'un répertoire en lien hypertextes que j'utilise couramment, le grand mercatog a apporter son savoir faire, merci encore à lui.
Mets bien en place "Microsoft Scripting RunTime" que je t'ai bien détaillée, et tout sera comme tu le souhaites dans ta demande "Je pourrais sans doute résoudre le problème si j'arrivais à recopier dans un fichier excel les chemins complets de mes 4000 fichiers mp3", je pense que tu pourras exécuter directement tes morceaux MP3.

Cordialement

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Option Explicit
Sub Module1AppelRépertoire()
Dim Repert As FileDialog
Dim Chemin As String
 
Set Repert = Application.FileDialog(msoFileDialogFolderPicker)
Repert.Show
If Repert.SelectedItems.Count > 0 Then
    Chemin = Repert.SelectedItems(1)
    Set Repert = Nothing
    ListeFichiers Chemin
End If
 
End Sub
 Sub ListeFichiers(Repertoire As String)
'Nécessite d'activer la référence "Microsoft Scripting RunTime"
        'Dans l'éditeur de macros (Alt+F11):
        'Menu Outils
        'Références
        'Cochez la ligne "Microsoft Scripting RunTime".
        'Cliquez sur le bouton OK pour valider.
Dim Fso As Scripting.FileSystemObject
Dim SourceFolder As Scripting.Folder, SubFolder As Scripting.Folder
Dim FileItem As Scripting.File
Dim i As Long
 
Set Fso = CreateObject("Scripting.FileSystemObject")
Set SourceFolder = Fso.GetFolder(Repertoire)
'Récupère le numéro de la dernière ligne vide dans la colonne A.
i = Range("A65536").End(xlUp).Row + 1
'Boucle sur tous les fichiers du répertoire
For Each FileItem In SourceFolder.Files
    'Inscrit le nom du fichier dans la cellule
    Cells(i, 1) = FileItem.Name
    'Ajoute un lien hypertexte vers le fichier
    ActiveSheet.Hyperlinks.Add Anchor:=Cells(i, 1), Address:=FileItem.ParentFolder & "\" & FileItem.Name
    'Indique la date de création
    Cells(i, 2) = FileItem.DateCreated
    'Indique la date de dernier acces
    Cells(i, 3) = FileItem.DateLastAccessed
    'Indique la date de dernière modification
    Cells(i, 4) = FileItem.DateLastModified
    'Nom du répertoire
    Cells(i, 5) = FileItem.ParentFolder
    i = i + 1
Next FileItem
Columns("A:D").AutoFit
'--- Appel récursif pour lister les fichier dans les sous-répertoires ---.
For Each SubFolder In SourceFolder.subfolders
    ListeFichiers SubFolder.Path
Next SubFolder
Set Fso = Nothing
Set SourceFolder = Nothing
End Sub