Prob de référence dans VBA???

Salut les pros d'ACCESS,

Je voudrais savoir où trouver les noms des différentes références qu'il y a dans VBA. Car voilà mon prob, j'ai récupéré une base access 2000, chez moi j'ai access 2003 et tout marche nickel mais quand je vais au bureau où il y a access 2002 j'ai des problème de référence.

J'ai reconverti ma base en 2002 au bureau, donc sous access 2002 et j'ai toujours des problèmes.

Alors chez moi j'ai reconverti ma base initiale 2000 sous 2003 et j'aimerais savoir si j'ai encore des problème, où trouver les références qui me manque.

Car chez moi, je ne vois pas le chemin complet des références. Je pense que si je pouvais les mettre dans le meme rép que ma base et faire Ajouter dans Référence VBA cela devrait aller Non???

Merci de votre aide.

A+

A part dans Oultis / Réference, je ne vois pas :?

Salut,

Tu mets cela dans un module :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
Option Compare Database
Option Explicit
 
Sub InfoReferences()
'Objectif: Afficher toutes les références existantes et leurs emplacements sur les disques
'dans une boîte de dialogue puis sous forme d'une liste dans la fenêtre débogage
Dim strMessage As String
Dim strTitre As String
Dim BoutonsBoiteMsg As Byte
Dim ElementRef As Reference
 
On Error Resume Next
 
For Each ElementRef In References
    If IsError(ElementRef.Name) Then
        strTitre = "Référence manquante"
        strMessage = "Référence manquante :" & vbCrLf & ElementRef.FullPath
        BoutonsBoiteMsg = 16 'symbole de message d'erreur critique
    Else
        strTitre = "Affiche les références et leurs emplacements"
        strMessage = "Référence :" & ElementRef.Name & vbCrLf & _
        "Location : " & ElementRef.FullPath
        BoutonsBoiteMsg = 64 'symbole de l'information
    End If
 
    Debug.Print ElementRef.FullPath
    MsgBox Prompt:=strMessage, Title:=strTitre, Buttons:=BoutonsBoiteMsg
Next ElementRef
End Sub
 
Function ReferencerFichier(strNomFichier As String) As Boolean
'Objectif : Créer une référence à une bibliothèque spécifique.
'Ne pas oublier d'installer les fichiers spéciaux ocx, dll nécessaires.
Dim ref As Reference
Dim strVerifie As String
 
On Error GoTo ErreurTraitement
'Vérifie l'existence du chemin d'accès au fichier spécifié en entrée
strVerifie = Dir(strNomFichier)
Debug.Print strVerifie
If strVerifie <> "" Then 'Le chemin d'accès existe
    'Boucle dans la collection des références pour tester l'existence de la référence
    For Each ref In References
        If ref.FullPath = strNomFichier Then
            MsgBox "La référence existe déjà !"
            ReferencerFichier = True
            Exit Function
        End If
    Next ref
Else
    MsgBox ("Le chemin d'accès : " & strNomFichier & " est incorrect")
End If
'créer la référence
Set ref = References.AddFromFile(strNomFichier)
ReferencerFichier = True
Exit_ReferencerFichier:
    Exit Function
ErreurTraitement:
    MsgBox err & ": " & err.Description
    ReferencerFichier = False
    Resume Exit_ReferencerFichier
 
End Function

Et puis sur le formulaire général de ton appli, par exemple tu mets cela sur l'évènement OnClick d'un bouton que tu crée :

Code:

1
2
3
Private Sub Commande114_Click()
Call InfoReferences
End Sub

Et ensuite il te dis les références que tu utilises et celles qui te manquent avec leur chemin.

Nickel, non ? :D

Salut HOOKERSEVEN,

Merci pour ton code, il marche nickel, c'est sympa.

A+