Impression automatique de tout les fichiers dans un dossier

Version imprimable

28/10/2010, 09h26
bobo27110

Impression automatique de tout les fichiers dans un dossier

Bonjour,
Je dois réaliser un script en VB ayant pour but d'imprimer de façon régulière (toutes les 2 mins) et automatique tous les fichier PDF ce trouvant dans un dossier "x".

J'espère que vous comprendrais ma requête et pourrais me diriger dans les démarches à entreprendre.

Je reste à votre disposition pour d'autres informations.
28/10/2010, 17h43
l_autodidacte

Bienvenue

Bienvenue sur le forum

Tu as des exemples concernant la gestion de l'impression ici

Quand tu auras commencé et que tu éprouves des difficultés, reviens poser tes questions. On pourra alors t'aider.

Voila je voudrais un script dans ce style la, j'essaye de faire ce script depuis plusieurs semaine. J'espère que vous pourrez m'aider. On ma dit de m'orienté vers la fonction Dir utilisé si dessous mais sans grand résultat.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
Const SW_SHOWNORMAL = 1
 
Dim NbFichiers As Long
Dim Tableau() As String
Const Dossier As String = "C:\Transfert"
 
Sub Tst()
Dim hwnd As Long
Dim i As Long
Dim DossierOk As String
 
DossierOk = Dossier
If Right(DossierOk, 1) <> "\" Then DossierOk = Dossier & "\"
ListeFichiers DossierOk, "pdf"
If NbFichiers > 0 Then
For i = 1 To UBound(Tableau)
ShellExecute hwnd, "print", DossierOk & Tableau(i), "", "", SW_SHOWNORMAL
Next
End If
End Sub
 
Private Sub ListeFichiers(ByVal NomDossierSource As String, ByVal Extension As String)
Dim NomFichier As String
NomFichier = Dir(NomDossierSource & "*." & Extension)
 
Erase Tableau
NbFichiers = 0
Do While Len(NomFichier) > 0
NbFichiers = NbFichiers + 1
ReDim Preserve Tableau(1 To NbFichiers)
Tableau(NbFichiers) = NomFichier
NomFichier = Dir()
Loop
End Sub

Merci d'avance

29/10/2010, 10h14
SfJ5Rpw8

Bonjour,

Ce code n'est pas du VBScript.. , tu ne peu pas utiliser Dir en VBScript..

précise un peu mieux ton environnement de développement.

pour manipuler les fichiers en VBScript : voir
http://vb.developpez.com/faqvbs/?page=II.2

et pour débuter en VBScript :
Introduction au langage VBSCRIPT
29/10/2010, 12h41
bobo27110

Je sais, il s'agit la d'un script Vba que j'aimerais l'adapté à un script VBS. Le script que je dois réaliser est entièrement en VBS. Je sais bien utiliser l'environnement Visual basic avec visual studio mais quand à faire un script comme sa j'ai beaucoup plus de mal :s.

Salut;

Voici un bout de

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
  ' On va utiliser l'imprimante par défaut
Set colPrinters =  objWMIService.ExecQuery _
    ("Select * from Win32_Printer Where Default = TRUE")
 
 WaitAndPrint 120000 ,4  ' Imprime les fichiers toutes les 2 minutes=120000 millisecondes
                         ' 4 = Nombre de fois
Sub PrintFiles
   DossierCible = "C:\Temp" ' Ici on met le chemin du dossier contenant 
                            ' les fichiers à imprimer.
   Set objShell = CreateObject("Shell.Application")  'Référence à Shell32.dll qui contient 
            'plusieurs routines exploitables via cette référence
   Set objFolder = objShell.Namespace(DossierCible) 
   Set colItems = objFolder.Items
  For Each objItem in colItems
    If Ucase(Right(ObjItem.Name,4))=".PDF" then
       objItem.InvokeVerbEx("Print")
       'msgbox ObjItem.Name  'Pour tester, on décommente cette ligne
    End If
  Next
End Sub
 
'## Remarque : Il n'y aura pas d'impression si Acrobat Reader n'est pas installé
Sub WaitAndPrint(Byval milliSec,ByVal Cnt)
 
 ' milliSec : durée en millisecondes entre les impressions
 ' Cnt : Nombre total d'impressions
 
  i=0
  Do
    PrintFiles
    Wscript.Sleep milliSec
    i=i+1
  Loop Until i>=cnt
  If i>=cnt Then Wscript.Quit
End Sub

La durée d'attente entre deux impressions est modifiable dans la procédure(Sub) WaitAndPrint ainsi que le nombre total d'impressions partant de 1 jusqu'à un très grand nombre(donc au choix).

Mais attention : Durant l'exécution du script, Wscript.exe reste chargé en mémoire(donc occupation de la mémoire de l'ordre de 11 à 12 Mo).