problème de codage en vba ("copie d'une partie d'une cellule dans une cellule vide")

Version imprimable

1 pièce(s) jointe(s)

Bonjour,

Je veux qu'une partie de chacune des cellules se trouvant dans une plage spécifique soit copié dans une autre cellule en respectant leur emplacement.C'est à dire si j'ai une cellule I15 qui contient par exemple "c:\Documents and Settings\user123\Application Data\appl.exe" alors la chaine de caractère "user123" soit copié dans L15 et on fait rentrer la chaine de caractère "DSM" dans chacune d'elles.

Voilà le code:
Code:

1 2 3 4 5 6 7 8 9 10 11 Range("a65536").Select dernière_ligne2 = Selection.End(xlUp).Row Range("I2:I" & dernière_ligne2).Select For Each Cell In Selection If UCase(Cell.Text) Like "C:\DOCUMENTS AND SETTINGS\*" Then Matricule = Mid(UCase(Cell.Text), 27, 7) Chemin_fichier = Cell.Value Range("D" & Chemin_fichier).FormulaR1C1 = "DSM" Range("L" & Chemin_fichier).FormulaR1C1 = Matricule End If Next
Normalement lors de l'exécution il y'a une erreur au niveau des deux dernières lignes de code parce que je connais pas la formule exacte pour la copie de cette partie là.
Le nom de l'erreur est ci-joint.

Donc merçi pour une réponse et à bientôt.

Cdt,
Skipeemed

22/10/2010, 19h12
babaothe
salut

une plage se définit par des coordonnées et pas par le contenu d'une cellule !

insère donc une instruction msgbox ici :
Code:

1 2 3 4 5 6 7 8 9 '...... Chemin_fichier = Cell.Value MsgBox "D" & Chemin_fichier ' <<<<===== ICI Range("D" & Chemin_fichier).FormulaR1C1 = "DSM" '.......
et dis-nous si tu crois que ce qu'elle affiche te parait définir une plage ! 8O
non, n'est-ce-pas ?

Bonjour,

Une piste avec le code suivant

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub aa_pmo()
Const CIBLE As String = "C:\DOCUMENTS AND SETTINGS\"
Dim R As Range
Dim var
Dim LastLig&
Dim i&
Dim A$
LastLig& = ActiveSheet.[a65536].End(xlUp).Row
Set R = ActiveSheet.Range("A1:L" & LastLig& & "")
var = R
For i& = 1 To LastLig&
  If InStr(1, UCase(var(i&, 12)), CIBLE) > 0 Then
    A$ = Mid(var(i&, 12), Len(CIBLE) + 1)
    var(i&, 9) = Mid(A$, 1, InStr(1, A$, "\") - 1)
  End If
Next i&
R = var
End Sub

Cordialement.

PMO
Patrick Morange

23/10/2010, 19h27
Invité
Bonsoir,

Je ne sais pas pourquoi vous nommez votre variable "Chemin_fichier" même si cela importe peu, l'erreur n'est pas là (mais cela ne rend pas le code très clair).

Comme vous l'a dit babaothe, ce n'est pas le contenu de la cellule que vous voulez mais le n° de la ligne concernée.

Donc, en principe :

Code:

Nom_fichier = Cell.Row

Mais je remplacerais plutôt "Nom_fichier", par exemple, par : "Num_lign"

Ensuite, vous êtes sûr de vouloir utiliser :
Code:

1 2 Range("D" & Chemin_fichier).FormulaR1C1 = "DSM" Range("L" & Chemin_fichier).FormulaR1C1 = Matricule
Vous devriez avoir le même résultat avec :
Code:

1 2 Range("D" & Chemin_fichier) = "DSM" Range("L" & Chemin_fichier) = Matricule

Bonjour jacques jean,

j'ai mis ce code ci-dessous mais ça n'a pas marché, en fait il n'y a aucune erreur. Mais la copie ne marche pas. Voilà le code que j'ai utilisé:

Code:

1
2
3
4
5
6
7
8
9
10
11
Range("a65536").Select
    dernière_ligne2 = Selection.End(xlUp).Row
    Range("I2:I" & dernière_ligne2).Select
    For Each Cell In Selection
    If UCase(Cell.Text) Like "C:\DOCUMENTS AND SETTINGS\*" Then
    Matricule = Mid(UCase(Cell.Text), 27, 7)
    Num_lign = Cell.Row
    Range("D" &  Num_lign)= "DSM"
    Range("L" &  Num_lign)= Matricule
    End If
    Next

Cdt,
SKIP

25/10/2010, 16h42
skipeemed

Bonjour PMO2007,

J'ai suivi ton code à la lettre mais apparemment ça fonctionne pas surtout au niveau de la ligne de code :

Code:

If InStr(1, UCase(var(i&, 12)), CIBLE) > 0

Parce que normalement la CiBLE se trouve dans la colonne I. Et puis pour le code :

Code:

A$ = Mid(var(i&, 12), Len(CIBLE) + 1)

la fonction normalement elle doit avoir trois paramètre.

[EDIT]

En fait c'est bon ça marches, j'ai remplacé 12 par 9 et 9 par 12.
Mais j'aimerai bien comprendre le code. Pour que je puisse le programmer tout seul.

Merçi,
Cdt,
SKIP

Bonjour,

Citation:

Mais j'aimerai bien comprendre le code. Pour que je puisse le programmer tout seul.

Voici quelques commentaires

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub aa_pmo()
Const CIBLE As String = "C:\DOCUMENTS AND SETTINGS\"
Dim R As Range
Dim var As Variant
Dim LastLig&
Dim i&
Dim A$
 
'--- dernière ligne renseignée de la colonne "A" ---
LastLig& = ActiveSheet.[a65536].End(xlUp).Row
'--- affectation de la plage "A1:L dernière ligne" dans la variable R (Range) ---
Set R = ActiveSheet.Range("A1:L" & LastLig& & "")
'--- met les valeurs de la plage dans un variant (correspond à un tableau Visual Basic à 2 dimensions) ---
var = R
'--- on boucle sur toutes les lignes du tableau ---
For i& = 1 To LastLig&
  '--- si on trouve CIBLE dans la colonne 9 (I) ...
  If InStr(1, UCase(var(i&, 9)), CIBLE) > 0 Then
    '--- on extrait à partir de longueur de CIBLE + 1 jusqu'à la fin
    '--- et on affecte le résultat dans la variable A$ (String)
    A$ = Mid(var(i&, 9), Len(CIBLE) + 1)
    '--- on extrait à partir du 1er "\" - 1 jusqu'à la fin
    '--- et on met le résultat dans le tableau var(ligne traitée , colonne 12 "L")
    var(i&, 12) = Mid(A$, 1, InStr(1, A$, "\") - 1)
  End If
Next i&
'--- on écrit, d'un seul coup, le tableau dans la plage ---
R = var
End Sub

Cordialement.

PMO
Patrick Morange

26/10/2010, 17h01
skipeemed

Bonjour PMO2017,

Merçi mon pote, j'ai bien compris le code.
Salut!

Cdt,
SKIP