Générer le code SQL d'une table

Version imprimable

Bonjour,

Je dispose d'une table Access.

Je voudrais récupérer le code SQL relatif à la création de cette table
( exemple :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
-- =========================================================
--   Table : MA_TABLE
-- ============================================================
create table MA_TABLE
(
    CHB_ID               INTEGER               not null,
    CHB_NUMERO           SMALLINT              not null,
    CHB_ETAGE            CHAR(3)                       ,
    CHB_BAIN             NUMERIC(1)            not null        default 0,
    CHB_DOUCHE           NUMERIC(1)            not null        default 1,
    CHB_WC               NUMERIC(1)            not null        default 1,
    CHB_COUCHAGE         SMALLINT              not null,
    CHB_POSTE_TEL        CHAR(3)                       ,
    primary key (CHB_ID)
);

Merci d'avance 8-)

12/10/2010, 15h19
ClaudeLELOUP

Bonjour,

vois dans la FàQ
http://access.developpez.com/faq/?page=TablesAndFields
12/10/2010, 15h29
Invité

Bonjour

Je ne pense pas que ce soit possible, de mémoire la question avait été posé il y a fort longtemps.

Philippe

Bonsoir,
en voilà une bonne idée.
Il faut une moulinette VBA pour récupérer le script sql de création des tables.
Lister les TableDefs, Fields, Indexes et Relations. Il faudrait également un tableau de correspondance des data type et pourquoi pas une table de correspondance pour d'autres SGBD.

Exemple :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
Public Function GetScriptSQL() as String
 Dim LDB As DAO.Database
 Dim TBL As DAO.TableDef
 Dim FLD As DAO.Field
 Dim IND As DAO.Index
 Dim REL As DAO.Relation
 Dim DataTypes As Collection
Set DataTypes = New Collection
DataTypes.Add Key:=CStr(1), Item:="BIT"
DataTypes.Add Key:=CStr(2), Item:="TINYINT"
DataTypes.Add Key:=CStr(3), Item:="SMALLINT"
DataTypes.Add Key:=CStr(4), Item:="INTEGER"
DataTypes.Add Key:=CStr(5), Item:="CURRENCY"
DataTypes.Add Key:=CStr(6), Item:="SINGLE"
DataTypes.Add Key:=CStr(7), Item:="DOUBLE"
DataTypes.Add Key:=CStr(8), Item:="DATE"
DataTypes.Add Key:=CStr(9), Item:="BINARY"
DataTypes.Add Key:=CStr(10), Item:="VARCHAR"
DataTypes.Add Key:=CStr(11), Item:="LONGBINARY"
DataTypes.Add Key:=CStr(12), Item:="LONGCHAR"
DataTypes.Add Key:=CStr(15), Item:="GUID"
DataTypes.Add Key:=CStr(16), Item:="BIGINT"
DataTypes.Add Key:=CStr(17), Item:="VARBINARY"
DataTypes.Add Key:=CStr(18), Item:="CHAR"
DataTypes.Add Key:=CStr(19), Item:="NUMERIC"
DataTypes.Add Key:=CStr(20), Item:="NUMERIC"
DataTypes.Add Key:=CStr(21), Item:="DOUBLE"
DataTypes.Add Key:=CStr(22), Item:="TIME"
DataTypes.Add Key:=CStr(23), Item:="TIMESTAMP"
DataTypes.Add Key:=CStr(24), Item:="VARBINARY"
DataTypes.Add Key:=CStr(101), Item:="LONGBINARY"
 Dim Script As String
 Dim Fk_fld As String
 Dim Fk_src As String
 Set LDB = CurrentDb
 For Each TBL In LDB.TableDefs
   If (TBL.Attributes And (dbSystemObject Or dbAttachedTable)) = 0 Then
       Script = Script & "CREATE TABLE " & TBL.Name & vbCrLf & "(" & vbCrLf
       For Each FLD In TBL.Fields
          Script = Script & vbTab & FLD.Name & vbTab & DataTypes(CStr(FLD.Type)) & IIf(FLD.Type = 10 Or FLD.Type = 18, "(" & FLD.Size & ")", "") & IIf(FLD.Required, vbTab & "NOT NULL", "") & IIf(Len(FLD.DefaultValue) > 0, vbTab & "DEFAULT VALUE " & FLD.DefaultValue, "") & "," & vbCrLf
       Next
       For Each IND In TBL.Indexes
          If (IND.Name = "PrimaryKey") Then
            Script = Script & vbTab & "PRIMARY KEY ("
            For Each FLD In IND.Fields
               Script = Script & FLD.Name & ", "
            Next
            Script = Left(Script, Len(Script) - 2) & ")" & vbCrLf
          End If
       Next
       Script = Script & ");" & vbCrLf & vbCrLf
   End If
 Next
 For Each REL In LDB.Relations
   Script = Script & "ALTER TABLE " & REL.ForeignTable & " ADD CONSTRAINT " & REL.Name
   Fk_fld = ""
   Fk_src = ""
   For Each FLD In REL.Fields
     Fk_fld = Fk_fld & FLD.Name & ", "
     Fk_src = Fk_src & FLD.ForeignName & ", "
   Next
   Script = Script & " FOREIGN KEY (" & Left(Fk_fld, Len(Fk_fld) - 2) & ")"
   Script = Script & " REFERENCES " & REL.table & "(" & Left(Fk_src, Len(Fk_src) - 2) & ");" & vbCrLf
 Next
 LDB.Close
 Set LDB = Nothing
 GetScriptDSQL = Script
End Function

13/10/2010, 04h12
Invité

Bonjour

Excellente idée, ce que je voulais dire c'est qu'il n'y a pas de fonction native, contrairement aux requêtes crées en mode graphique dont on peut récupérer le code SQL.

Philippe
13/10/2010, 08h34
ClaudeLELOUP

Merci ilank,

J’ai souvent regretté qu'une telle fonction n'était pas disponible.
As-tu, sous la main l'équivalent pour d'autres objets (Formulaires, Etats, Macro, Module) ?

Une faute de frappe :

GetScriptDSQL = Script ---> GetScriptSQL = Script

Remarque après essais :

le nom des champs doit être encadré de crochets(s'il contient des espaces par exemple) --->

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
Public Function GetScriptSQL() As String
 Dim LDB As DAO.Database
 Dim TBL As DAO.TableDef
 Dim FLD As DAO.Field
 Dim IND As DAO.Index
 Dim REL As DAO.Relation
 Dim DataTypes As Collection
Set DataTypes = New Collection
DataTypes.Add Key:=CStr(1), Item:="BIT"
DataTypes.Add Key:=CStr(2), Item:="TINYINT"
DataTypes.Add Key:=CStr(3), Item:="SMALLINT"
DataTypes.Add Key:=CStr(4), Item:="INTEGER"
DataTypes.Add Key:=CStr(5), Item:="CURRENCY"
DataTypes.Add Key:=CStr(6), Item:="SINGLE"
DataTypes.Add Key:=CStr(7), Item:="DOUBLE"
DataTypes.Add Key:=CStr(8), Item:="DATE"
DataTypes.Add Key:=CStr(9), Item:="BINARY"
DataTypes.Add Key:=CStr(10), Item:="VARCHAR"
DataTypes.Add Key:=CStr(11), Item:="LONGBINARY"
DataTypes.Add Key:=CStr(12), Item:="LONGCHAR"
DataTypes.Add Key:=CStr(15), Item:="GUID"
DataTypes.Add Key:=CStr(16), Item:="BIGINT"
DataTypes.Add Key:=CStr(17), Item:="VARBINARY"
DataTypes.Add Key:=CStr(18), Item:="CHAR"
DataTypes.Add Key:=CStr(19), Item:="NUMERIC"
DataTypes.Add Key:=CStr(20), Item:="NUMERIC"
DataTypes.Add Key:=CStr(21), Item:="DOUBLE"
DataTypes.Add Key:=CStr(22), Item:="TIME"
DataTypes.Add Key:=CStr(23), Item:="TIMESTAMP"
DataTypes.Add Key:=CStr(24), Item:="VARBINARY"
DataTypes.Add Key:=CStr(101), Item:="LONGBINARY"
 Dim Script As String
 Dim Fk_fld As String
 Dim Fk_src As String
 Set LDB = CurrentDb
 For Each TBL In LDB.TableDefs
   If (TBL.Attributes And (dbSystemObject Or dbAttachedTable)) = 0 Then
       Script = Script & "CREATE TABLE " & TBL.Name & vbCrLf & "(" & vbCrLf
       For Each FLD In TBL.Fields
          Script = Script & vbTab & "[" & FLD.Name & "]" & vbTab & DataTypes(CStr(FLD.Type)) & IIf(FLD.Type = 10 Or FLD.Type = 18, "(" & FLD.Size & ")", "") & IIf(FLD.Required, vbTab & "NOT NULL", "") & IIf(Len(FLD.DefaultValue) > 0, vbTab & "DEFAULT VALUE " & FLD.DefaultValue, "") & "," & vbCrLf
       Next
       For Each IND In TBL.Indexes
          If (IND.Name = "PrimaryKey") Then
            Script = Script & vbTab & "PRIMARY KEY ("
            For Each FLD In IND.Fields
               Script = Script & FLD.Name & ", "
            Next
            Script = Left(Script, Len(Script) - 2) & ")" & vbCrLf
          End If
       Next
       Script = Script & ");" & vbCrLf & vbCrLf
   End If
 Next
 For Each REL In LDB.Relations
   Script = Script & "ALTER TABLE " & REL.ForeignTable & " ADD CONSTRAINT " & REL.Name
   Fk_fld = ""
   Fk_src = ""
   For Each FLD In REL.Fields
     Fk_fld = Fk_fld & FLD.Name & ", "
     Fk_src = Fk_src & FLD.ForeignName & ", "
   Next
   Script = Script & " FOREIGN KEY (" & Left(Fk_fld, Len(Fk_fld) - 2) & ")"
   Script = Script & " REFERENCES " & REL.Table & "(" & Left(Fk_src, Len(Fk_src) - 2) & ");" & vbCrLf
 Next
 LDB.Close
 Set LDB = Nothing
 GetScriptSQL = Script
End Function

J'ai aussi un problème pour les valeurs par défaut : la fonction génère ceci

Code:

1
2
3
4
5
6
7
8
9
10
CREATE TABLE Catégories
(
    [ValeurSansDoublon] INTEGER,
    [Nom de catégorie]  VARCHAR(25) NOT NULL,
    [Description]   LONGCHAR,
    [Illustration]  LONGBINARY,
    [CodeLivre] VARCHAR(50),
    [selection] BIT DEFAULT VALUE 0,
    PRIMARY KEY (ValeurSansDoublon)
);

qui donne une erreur de syntaxe sur "default"

NB j'ai cherché dans la FàQ pour trouver la bonne syntaxe,
j'ai trouvé ceci

Code:

ALTER TABLE <table1> ALTER COLUMN <champ1> <typeChamp1> DEFAULT <valeurParDéfaut>

à l'adresse
http://access.developpez.com/faq/?pa...mps#DefaultSQL

Par exemple

Code:

ALTER TABLE Catégories ALTER COLUMN ValeurSansDoublon DEFAULT 0 ;

qui me donne aussi une erreur mais sur la valeur 0.

13/10/2010, 11h43
ilank

Bonjour,
je n'ai effectivement pas pensé aux espaces dans les libellés. Dans ce cas, il faut encadrer, les noms des tables, les noms des colonnes, les noms des colonnes dans les contraintes.
De plus, il n'y a pas de gestion des CONSTRAINT CHECK via la propriété validationrules et je me suis trompé concernant les foreign key en inversant les champs.
13/10/2010, 11h49
ClaudeLELOUP

pas de souci, cela reste super intéressant.
As-tu un équivalent pour d'autres objets ?
01/08/2011, 16h46
Mistraldor

Bonjour,

Je débute sous Access. Je voudrais utiliser la fonction proposée sur ce topic. Malheureusement je ne connais rien en VBA. Comment on appelle une fonction sous VBA ?
01/08/2011, 17h08
ClaudeLELOUP

Bonjour,

Par exemple, tu ouvres une fenêtre d'exécution : <alt> + <F11> et tu saisis :

? Public Function GetScriptSQL() As String