[VBS] décodage base 64

salut a tous,

existe-t-il une fonction API ou uneautre maniere de décoder une chaine codée en base 64 ( je ne connais rien en algo )

merci

Salut,

Ce code c'est du VBS, mais je pense qu'il doit etre adaptable en moins de deux au VB (logique :wink:)

Teste-le et tiens-moi au courant stp...
Merci :wink:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
Function Base64Decode(ByVal base64String)
  Const Base64 = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
  Dim dataLength, sOut, groupBegin
 
  'remove white spaces, If any
  base64String = Replace(base64String, vbCrLf, "")
  base64String = Replace(base64String, vbTab, "")
  base64String = Replace(base64String, " ", "")
 
  'The source must consists from groups with Len of 4 chars
  dataLength = Len(base64String)
  If dataLength Mod 4 <> 0 Then
    Err.Raise 1, "Base64Decode", "Bad Base64 string."
    Exit Function
  End If
 
 
  ' Now decode each group:
  For groupBegin = 1 To dataLength Step 4
    Dim numDataBytes, CharCounter, thisChar, thisData, nGroup, pOut
    ' Each data group encodes up To 3 actual bytes.
    numDataBytes = 3
    nGroup = 0
 
    For CharCounter = 0 To 3
      ' Convert each character into 6 bits of data, And add it To
      ' an integer For temporary storage.  If a character is a '=', there
      ' is one fewer data byte.  (There can only be a maximum of 2 '=' In
      ' the whole string.)
 
      thisChar = Mid(base64String, groupBegin + CharCounter, 1)
 
      If thisChar = "=" Then
        numDataBytes = numDataBytes - 1
        thisData = 0
      Else
        thisData = InStr(1, Base64, thisChar, vbBinaryCompare) - 1
      End If
      If thisData = -1 Then
        Err.Raise 2, "Base64Decode", "Bad character In Base64 string."
        Exit Function
      End If
 
      nGroup = 64 * nGroup + thisData
    Next
 
    'Hex splits the long To 6 groups with 4 bits
    nGroup = Hex(nGroup)
 
    'Add leading zeros
    nGroup = String(6 - Len(nGroup), "0") & nGroup
 
    'Convert the 3 byte hex integer (6 chars) To 3 characters
    pOut = Chr(CByte("&H" & Mid(nGroup, 1, 2))) + _
      Chr(CByte("&H" & Mid(nGroup, 3, 2))) + _
      Chr(CByte("&H" & Mid(nGroup, 5, 2)))
 
    'add numDataBytes characters To out string
    sOut = sOut & Left(pOut, numDataBytes)
  Next
 
  Base64Decode = sOut
End Function

ça merche tres bien ,meme pas besoin d'adaptation, merci bcp

PS: je pense que ça pourrait aller dans les astuces ou la FAQ