création de table pour Treeview

Version imprimable

10/09/2010, 18h26
ManCéRien

1 pièce(s) jointe(s)

création de table pour Treeview

Bonjour à tous

Je possède une table reflétant des nomenclatures d'articles que je voudrais afficher avec une hiérarchisation dépendante donc un Treeview.
Cette Table est un extract de notre ERP et donc non modifiable par principe.

cette table est composée de:
1 colonne "Composé" : le code article disons parent
1 colonne avec un Tag alphabétique composé "M" un composé, "L" un sous ensemble
1 colonne "Composant" le code enfant
1 colonne avec un Tag alphabétique composant "M" un composé, "L" un sous ensemble, "P" un composant (non divisable)

mon problème est que je n'arrive pas à regrouper tout cela sous un format du type: Article / noeud / noeud parent donc sur une seule colonne.

je mets à dispo un petit exemple en PJ de la table et du final souhaité.

Pouvez-vous m'aiguiller sur la marche à suivre SVP

merci beaucoup
10/09/2010, 18h43
f-leb

bonjour,

tu devrais trouver des idées à reprendre dans la source:
Exemple de remplissage de treeview avec DAO

peut-être là aussi: http://www.developpez.net/forums/d94...s/#post5329727

J'ai un doute, il s'agit d'une nomenclature:
Article-1----∞-Composer-∞-----1-Article_1
Article(idArticle, Reference)
Composer(#idArtComposant, #idArtComposé)

ou bien d'une hiérarchie:
Article-∞-------1-Article_1
Article(idArticle, Reference, #idArticleParent)
10/09/2010, 20h33
ManCéRien

.

merci pour les liens, je connais celui de Tofalu (que je garde sous le coude pour quand j'aurai constitué ma table;) ), l'autre me rappelle qq chose mais n'est pas très abouti pour le coup...

concernant les jointures: je vais prendre mon exemple concret:
les références sont des assemblages électroniques:
un montage est composé de 3 cartes électroniques (en gras dans le xls) elles même composées de composants
Donc le montage 1....1 carte électronique
et composant électronique 1....n cartes électroniques
10/09/2010, 22h28
f-leb

c'est donc bien une nomenclature:

Citation:

Envoyé par f-leb

Article-1----∞-Composer-∞-----1-Article_1

Article(idArticle, Reference)
Composer(#idArtComposant, #idArtComposé)

donc après avoir importé ta source dans une table temporaire, quelques requêtes devraient suffire pour alimenter tes tables Article et Composer.
11/09/2010, 23h31
ManCéRien

content de savoir que cela reste possible :P

pourrais-tu me donner quelques conseils pour arriver à mes fins ??

par avance merci

bonjour ManCéRien,

par exemple avec le schéma suivant, avec une table Import reprenant les noms de champs dans Excel (voir Importation de fichier Excel):
http://upimages.free.fr/10/254/59781.png

On peut créer une requête qui ajoute dans la table Référence les composants qui n'y sont pas encore:
R_AjoutComposant:
Code:

1 2 3 4 INSERT INTO Reference ( NomRef, TypeRef ) SELECT DISTINCT Import.Composant, Import.P_M_Composant FROM Import LEFT JOIN Reference ON Import.Composant=Reference.NomRef WHERE Reference.NomRef Is Null;
même principe pour les composés,
R_AjoutComposé:
Code:

1 2 3 4 INSERT INTO Reference ( NomRef, TypeRef ) SELECT DISTINCT Import.Composé, Import.P_M_Composé FROM Import LEFT JOIN Reference ON Import.Composé = Reference.NomRef WHERE Reference.NomRef Is Null;
Reste à remplir la table Assembler, seulement dans le fichier Excel il y a des doublons avec notamment des Qty=0 qu'il faut prendre en compte.
Code:

1 2 3 4 composé composant Qty xxxx yyyy 5 xxxx yyyy 30 xxxx yyyy 0
Que faire dans ce cas ?

12/09/2010, 17h43
ManCéRien

Bonjour f-leb

Je ne l'avais pas précisé au départ mais le fichier excel en PJ constituait un simple exemple, la table réelle fait dans les 122k lignes ...

le projet est de faire en sorte que sous une proposition de l'opérateur d'une référence père, l'on puisse créer une table nomenclature formatée pour construire un treeview, table n'incluant qu'une seule nomenclature.
(je pense que comme cela, ce sera moins lourd et plus simple à gérer)

j'imaginais donc:
1-vidage de la table Nomenclature
2-entrée de la valeur du choix de l'utilisateur (input box par exemple ou par un champs de formulaire) avec association des références nodes
3- On lance une 1ère requête pour identifier les composants, ceux taguer en 'P' sont imédiatement ajoutés à la table Nomenclature
4- s'il existe des lignes avec un tag 'M', il s'agit de composants eux même "composés" --> on relance alors la requête avec chacun de ces composants et on ajoute à la table Nomenclature sans oublier les niveaux de nodes.

hum... sur le papier ça me parait simple mais la mise en pratique est carrément chaotique :calim2:

Concernant les qty à zéro, faut les virer !! je le ferai dés le début

j'ai essayé les requêtes que tu as réalisé:ccool: mais elles me remontent les réf sans corrélation hiérarchique...

suis-je à côté de la plaque?

à+
12/09/2010, 19h29
f-leb

il y a toujours un truc qui me chiffonne:aie:

Par exemple dans l'onglet "Résultat souhaité", la référence FC000100 a un seul nœud parent correspondant à la référence ZA04180C.

Or dans l'onglet "Source", le composant FC000100 a pour composés DEUX références qui sont ZA04180C et ZA04170C.

Si la source est exacte et qu'un nœud peut hériter de plusieurs parents, tu ne peux pas avoir un modèle avec un seul nœud parent.
A moins que quelque chose m'échappe:calim2:

Si j'ai bien compris, tu cherches les descendants d'un nœud particulier, un peu comme dans le message:http://www.developpez.net/forums/d94...s/#post5353207

Ici j'avais demandé d'afficher dans un msgbox les descendants de "e2"
http://upimages.free.fr/10/199/57977.png
Il me semble que c'est un truc de ce genre que tu recherches. Il faut bien sûr l'adapter pour remplir non pas une chaîne de caractères dans un msgbox mais une autre table, un treeview...
12/09/2010, 21h58
f-leb

si je demande les descendants de "e1", on obtient:
http://upimages.free.fr/10/254/59821.png

de la même façon que FC000100 a pour parents ZA04180C et ZA04170C,
ici "e4" a pour parents "e1" et "e2".

"e4" et ses descendants "e6" et "e9" apparaissent donc deux fois dans le "treeview".
13/09/2010, 09h04
ManCéRien

Bonjour,

c'est exactement ça :ccool:

En effet, la table xls n'est pas complète sur cet article car je pensais à tort, que son contenu suffisait pour la compréhension du sujet, dsl :?

certains composants peuvent être rattachés à plusieurs composés dans une même nomenclature et ce, à des niveaux hiérarchiques qui peuvent être différents
http://imagik.fr/view-rl/297205

des articles peuvent donc apparaitre plusieurs fois dans le même treeview.

Bonjour

j'avance, j'avance...;)

J'ai fini la première partie, à savoir le reformatage de la table source afin d'obtenir une table que j'espère convenablement structurée, pour la construction d'un treeview

Pourriez-vous commenter ce code, SVP?
point faible: la redondance de certaines parties et le fait qu'elle ne couvre que 3 niveaux hiérarchique.

merci à vous ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
Private Sub btnBOM_Click()
 
Dim db As DAO.Database
Dim rstQd1 As DAO.Recordset
Dim rstQd2 As DAO.Recordset
Dim rstQd3 As DAO.Recordset
Dim rstBOM As DAO.Recordset
Dim qdRazBOM As DAO.QueryDef
Dim intNode  As Integer
Dim intNodeParent As Integer
Dim strCode As String
Dim strSQL1  As String
Dim strSQL2 As String
Dim strSQL3  As String
 
On Error GoTo GestErr
 
If IsNull(Me.txtCodeParent) Then
        MsgBox "Pas d'article renseigné"
        Exit Sub
    Else
        strCode = Me.txtCodeParent
End If
 
 
 
strSQL1 = "SELECT TABLE_DOMERAT_BOM.Composé, TABLE_DOMERAT_BOM.Composant, TABLE_DOMERAT_BOM.P_M_Composant"
strSQL1 = strSQL1 + " FROM TABLE_DOMERAT_BOM"
strSQL1 = strSQL1 + " WHERE (((TABLE_DOMERAT_BOM.Composé)=""" & strCode & """) AND ((TABLE_DOMERAT_BOM.Qty)<>0))"
strSQL1 = strSQL1 + " ORDER BY TABLE_DOMERAT_BOM.P_M_Composant DESC;"
 
Set db = CurrentDb()
Set rstQd1 = db.OpenRecordset(strSQL1)
Set rstBOM = db.OpenRecordset("T_BOM")
 
'si pas d'enregistrement alos moveLast renverra une erreur 3021
rstQd1.MoveLast
'si pas d'erreur alors on enregistre strCodeParent apres avoir RAZ la table T_BOM
Set qdRazBOM = db.CreateQueryDef("", "DELETE T_BOM.* FROM T_BOM;")
qdRazBOM.Execute
qdRazBOM.Close
Set qdRazBOM = Nothing
 
intNode = 1
intNodeParent = 0
rstBOM.AddNew
rstBOM.Fields(0).Value = strCode
rstBOM.Fields(1).Value = intNode
rstBOM.Fields(2).Value = intNodeParent
rstBOM.Update
 
'on remplit avec le reste du 1er niveau
rstQd1.MoveFirst
intNodeParent = intNode
Do While Not rstQd1.EOF
        intNode = intNode + 1
        rstBOM.AddNew
        rstBOM.Fields(0).Value = rstQd1.Fields("Composant").Value
        rstBOM.Fields(1).Value = intNode
        rstBOM.Fields(2).Value = intNodeParent
        rstBOM.Update
     'on remplit le2ème niveau
    If rstQd1.Fields("P_M_Composant").Value = "M" Then
        strCode = rstQd1.Fields("Composant").Value
        strSQL2 = "SELECT TABLE_DOMERAT_BOM.Composé, TABLE_DOMERAT_BOM.Composant, TABLE_DOMERAT_BOM.P_M_Composant"
        strSQL2 = strSQL2 + " FROM TABLE_DOMERAT_BOM"
        strSQL2 = strSQL2 + " WHERE (((TABLE_DOMERAT_BOM.Composé)=""" & strCode & """) AND ((TABLE_DOMERAT_BOM.Qty)<>0))"
        strSQL2 = strSQL2 + " ORDER BY TABLE_DOMERAT_BOM.P_M_Composant DESC;"
        Set rstQd2 = db.OpenRecordset(strSQL2)
        intNodeParent = intNode
        Do While Not rstQd2.EOF
            intNode = intNode + 1
            rstBOM.AddNew
            rstBOM.Fields(0).Value = rstQd2.Fields("Composant").Value
            rstBOM.Fields(1).Value = intNode
            rstBOM.Fields(2).Value = intNodeParent
            rstBOM.Update
            'on remplit le 3ème niveau
            If rstQd2.Fields("P_M_Composant").Value = "L" Then
                    strCode = rstQd2.Fields("Composant").Value
                    strSQL3 = "SELECT TABLE_DOMERAT_BOM.Composé, TABLE_DOMERAT_BOM.Composant, TABLE_DOMERAT_BOM.P_M_Composant"
                    strSQL3 = strSQL3 + " FROM TABLE_DOMERAT_BOM"
                    strSQL3 = strSQL3 + " WHERE (((TABLE_DOMERAT_BOM.Composé)=""" & strCode & """) AND ((TABLE_DOMERAT_BOM.Qty)<>0))"
                    strSQL3 = strSQL3 + " ORDER BY TABLE_DOMERAT_BOM.P_M_Composant DESC;"
                    Set rstQd3 = db.OpenRecordset(strSQL3)
                    intNodeParent = intNode
                    Do While Not rstQd3.EOF
                        intNode = intNode + 1
                        rstBOM.AddNew
                        rstBOM.Fields(0).Value = rstQd3.Fields("Composant").Value
                        rstBOM.Fields(1).Value = intNode
                        rstBOM.Fields(2).Value = intNodeParent
                        rstBOM.Update
                        rstQd3.MoveNext
                    Loop
            End If
            rstQd2.MoveNext
        Loop
 
    End If
    rstQd1.MoveNext
Loop
 
 
BeforeToClose:
Set db = Nothing
rstQd1.Close
Set rstQd1 = Nothing
rstQd2.Close
Set rstQd2 = Nothing
rstBOM.Close
Set rstBOM = Nothing
 
Exit Sub
 
GestErr:
Select Case Err
    Case 3021 'aucun enregistrement trouvé
        MsgBox "Pas de BOM pour cet référence"
        Resume BeforeToClose
    Case Else
        MsgBox Err.Number & vbCrLf & Err.Description
 
End Select
 
End Sub

Bonjour,

pour ne pas être limité à un nombre de niveaux, utilises peut-être une fonction récursive pour les composants de type "M" et "L"

Exemple : appelle la fonction récursive

Code:

1
2
3
4
5
6
7
sub btnBom_Click()
If Not  IsNull(Me.txtCodeParent) Then 
  GetComposition(Me.txtCodeParent)
  Exit sub
End if
  MsgBox "Pas d'article renseigné"
End sub

la fonction récursive

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Function GetComposition(strCompose)
 static db as DAO.Database
 if (db is nothing) Then Set db=Currentdb()
....
....
 rstSQL="SELECT Composé,Composant,P_M_Composant FROM Table_Domerat_Bom WHERE Composé=" & strCompose
 
 set rstQd = db.Openrecordset(rstSQL)
 
 While Not rstQd.EOF
  ........
  ......
  If rstQd!P_M_Composant="M" or rstQd!P_M_Composant="L" Then
     GetComposition(rstQd!Composant)
  End if 
  rstQd.MoveNext
 Wend
 .......
End Function

1 pièce(s) jointe(s)

merci ilank pour ton post que je vais tacher d'assimiler (dur pour le vieil autodidacte que je suis :cry:)

sinon je pensais m'en sortir avec mon treeview, prétentieux que je suis !!

j'ai épluché le pdf de jacma mais j'ai bloqué sur une erreur indécelable à mon niveau.
J'ai tout effacé et j'ai alors honteusement pompé le code de Tofalu http://access.developpez.com/sources/?page=Treeview

même résultat :cry:
étant donné le peu voire l'absence de documentation sur les treeviews et leurs propriétés, je me permet de poster ici mon besoin d'aide.

le code s'arrête après avoir créé le noeud racine...
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 Dim oRst As DAO.Recordset Dim strLibelle As String Set oRst = odb.OpenRecordset("T_BOM") With oRst While Not .EOF 'Récupère le codeArticle strLibelle = .Fields("CodeArticle").Value 'Test le cas de la racine If intNodeParent = 0 Then oT.Nodes.Add Key:="Emp" & .Fields("IDNode").Value, Text:=strLibelle Else PLANTAGE --> oT.Nodes.Add "Emp" & intNodeParent, tvwChild, "Emp" & .Fields("IDNode").Value, strLibelle End If 'Lance le même traitement avec ce responsable remplissageTreeView oT, odb, .Fields("IDNode").Value 'Passe à l'enregistrement suivant .MoveNext Wend End With 'Ferme le recordset oRst.Close: Set oRst = Nothing
Si ça peut aider, je vous met au format xls l'export de la table T_BOM généré par le code de mon post précédent.

merci encore pour votre coup de main

Bonsoir,

voici un bout de code qui remplit le treeview oT en une passe depuis la table Table_Domrat_Bom

Exemple : Sur click vérifie que le code est renseigné

Code:

1
2
3
4
5
6
7
8
 
Private Sub MyButton_Click()
    If Not IsNull(Me.txtCodeParent) Then
    GetCompose (Me.txtCodeParent)
    Exit Sub
   End If
   MsgBox "Pas d'article renseigné"
End Sub

Fonction qui vide le treeview,crée le node article s'il existe et appelle
sa composition ou affiche "Article introuvable"

Code:

1
2
3
4
5
6
7
8
9
10
11
 
Function GetCompose(strCompose As String)
     oT.Nodes.Clear
    If DLookup("Composé", "Table_Domerat_Bom", "Composé='" & strCompose & "'") = strCompose Then
        oT.Nodes.Add , , "Emp0", strCompose
        GetCompositions strCompose, 0
    oT.Nodes("Emp0").Expanded = True
    Else
        oT.Nodes.Add , , "Emp0", "Article introuvable"
    End If
End Function

Fonction récursive qui crée l'arborescence du composé

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Function GetCompositions(strCompose As String, parentkey As Long) As Long
    Static LDB As DAO.Database
    Dim nodeKey As Long
    Dim RcdComposants As DAO.Recordset
    Dim RcdSQL As String
 
RcdSQL = "SELECT Composé, composant, P_M_Composant FROM Table_Domerat_Bom WHERE composé='" & strCompose & "'"
If LDB Is Nothing Then Set LDB = CurrentDb()
 nodeKey = parentkey + 1
Set RcdComposants = LDB.OpenRecordset(RcdSQL)
With RcdComposants
    While Not .EOF
        oT.Nodes.Add "Emp" & CStr(parentkey), tvwChild, "Emp" & CStr(nodeKey), !composant
        If !P_M_Composant = "M" Or !P_M_Composant = "L" Then
            nodeKey = GetCompositions(!composant, nodeKey)
        Else
            nodeKey = nodeKey + 1
        End If
        .MoveNext
    Wend
.Close
End With
Set RcdComposants = Nothing
GetCompositions = nodeKey
End Function

25/09/2010, 19h49
ManCéRien

:ccool: ça marche
j'ai intégré tout ça à mon appli, merci ilank

mais je ne comprend pas comment :calim2: c'est balo...

avant de taguer RESOLU, on pourrait faire un bout de code avec ma table T_BOM réalisée plus haut qui remplirait un TV?

merci

Bonjour,

A partir de la table "T_BOM" il suffit de la parcourir

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
 Dim oRst As DAO.Recordset
 Set oRst = odb.OpenRecordset("SELECT * FROM T_BOM ORDER BY NumNodeParent, IDNode")
 With oRst
       While Not .EOF
            'Récupère le codeArticle
             'Test le cas de la racine
            If !NumNodeParent = 0 Then
                oT.Nodes.Add Key:="Emp" & !IDNode, Text:=!CodeArticle
            Else
  oT.Nodes.Add "Emp" & !NumNodeParent, tvwChild, "Emp" & !IDNode, !CodeArticle
            End If
            .MoveNext
        Wend
        .Close
    End With
    'Ferme le recordset
    Set oRst = Nothing