Intercepter les erreurs cmd dans un vbs

Version imprimable

25/08/2010, 22h19
fleurparis

Intercepter les erreurs cmd dans un vbs
Bonjour à tous,

Est-il possible de récupérer l'erreur d'un cmd lorsque je lance des commandes dos dans un vbs ?

Comme exemple j’ai un programme blabla.exe qui n’existe pas, le script vbs ne retourne aucune erreur. (ce n'est pas normal...)
Code:

1 2 3 4 5 6 7 Option explicit On error goto 0 Dim objShell Set objShell = CreateObject("Wscript.Shell") objShell.Run "%comspec% /c blabla.exe", 0, True wscript.echo "erreur : " & Err.number
Avez-vous une solution pour intercepter les codes de retour différent de 0 dans un cmd ?

Merci pour votre aide.

Quand tu mets "On Error Goto 0" tu n'auras pas de message d'erreur.
De plus, l'exécution de cmd avec le commutateur /C a pour effet de fermer la fenêtre DOS sans te laisser le temps de voir l'erreur.
Enfin, il faut faire le test sur l'existence du fichier que tu appelles "blabla.exe"
Voici un bout de code pour le test:
Code:

1 2 3 4 5 6 7 Dim objShell,fso, NoError 'On error goto 0 set fso=CreateObject("Scripting.FileSystemObject") NoError=fso.FileExists("Blabla.exe") Set objShell = CreateObject("Wscript.Shell") objShell.Run "%comspec% /k blabla.exe", 1, True msgbox NoError '"erreur : " & Err.number

Tu peux récupérer les erreurs d'un programme lancé un vbscript ainsi que le StdOut et le StdErr.
Regarde ces exemples de code (fonctions utiles) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
'--------------------------------------------------------------------------
' Convert to unicode.
' For french language (for example), the text returned by ExecCommandShell
' should be converted to unicode with correct code page to be correct (with accent).
'
' Parameters :
'-------------
'   strTextToConvert : Text to convert to unicode
'
' Return :
'---------
'   The text converted into unicode string.
'
'--------------------------------------------------------------------------
Function ConvertToUnicode(strTextToConvert)
    ConvertToUnicode=g_objConv.ToUnicode(strTextToConvert,g_CodePage)
End Function
 
' Converter to Unicode (global variable) - Initialisation
Dim g_objConv,g_CodePage
InitCodePage() ' Initialize converter to unicode (make only once)
Sub InitCodePage()
    Set g_objConv=CreateObject("OlePrn.OleCvt")     ' Converter
    g_CodePage=Split(CreateObject("WScript.Shell").Exec("cmd /c chcp").StdOut.ReadAll,":")(1) ' Get Code Page
End Sub
 
'--------------------------------------------------------------------------
' Execute a shell command.
' Wait the end of command and get the stdout / stderr output.
'
' Parameters :
'-------------
'   strCommand  : Commande to execute
'   objShell    : Shell created with CreateObject("WScript.Shell")
'   strStdOut   : String that will receive Std Out output. If Null, this parameter is ignored.
'   strStdErr   : String that will receive Std Err output. If Null, this parameter is ignored.
'
' Return :
'---------
'   The return value of executed program (generally 0 if all is good).
'
'--------------------------------------------------------------------------
Function ExecCommandShell(strCommand,objShell,strStdOut,strStdErr)
    Dim objExec     ' Objet permettant de contrôler l'exécution
 
    ' Initialiser le StdOut à chaîne vide
    If VarType(strStdOut)=vbString Then
        strStdOut = ""
    End If
 
    ' Initialiser le StdErr à chaîne vide
    If VarType(strStdErr)=vbString Then
        strStdErr = ""
    End If
 
    strCommand = strCommand
    On Error Resume Next
    Set objExec = objShell.Exec(strCommand) ' objExec est de type WshScriptExec
    If Err.Number <> 0 Then
        ' Si la commande n'a pas pu être lancée
        ExecCommandShell = Err.Number
        If VarType(strStdErr)=vbString Then
            strStdErr   = Err.Description
        End If
        On Error Goto 0
        Call Err.Clear()
    Else
        On Error Goto 0
        Dim iStatus
        Do
            Call WScript.Sleep(10)   ' Attendre la fin
 
            iStatus = objExec.Status
            If VarType(strStdOut)=vbString And Not objExec.StdOut.AtEndOfStream Then
                ' Lire la sortie standard
                strStdOut = strStdOut & objExec.StdOut.ReadAll
            End If
            If VarType(strStdErr)=vbString And Not objExec.StdErr.AtEndOfStream Then
                ' Lire la sortie d'erreur
                strStdErr = strStdErr & objExec.StdErr.ReadAll
            End If
        Loop While iStatus = 0   ' => Vaut 1 quand terminé, 0 indique qu'il est en cours
 
        ExecCommandShell = objExec.ExitCode
    End If
 
    ' Convert to unicode
    If VarType(strStdOut)=vbString Then
        strStdOut = ConvertToUnicode(strStdOut)
    End If
 
    ' Convert to unicode
    If VarType(strStdErr)=vbString Then
        strStdErr = ConvertToUnicode(strStdErr)
    End If
 
    Set objExec    = Nothing
End Function
 
'--------------------------------------------------------------------------
' Exécuter une commande.
' Permet d'attendre la fin de la commande et de récupérer en sortie
' le StdErr.
'
' Paramètres :
'-------------
'   strCommand  : Commande à exécuter
'   strStdOut   : Chaine de caractère qui va recevoir le Std Out, si vaut Null, ce paramètre est ignoré
'   strStdErr   : Chaine de caractère qui va recevoir le Std Erreur, si vaut Null, ce paramètre est ignoré
'
' Retour :
'---------
'   La valeur de retour de l'exécution du programme (0 en général si
'   tout s'est bien passé)
'
'--------------------------------------------------------------------------
Function ExecCommand(strCommand,strStdOut,strStdErr)
    ExecCommand = ExecCommandShell(strCommand,CreateObject("WScript.Shell"),strStdOut,strStdErr)
End Function

26/08/2010, 22h32
fleurparis

Merci pour le code :), c'est tout à fait ce que je cherche.

Est-il possible d'avoir un exemple de l'appel à la fonction
Function ExecCommand(strCommand,strStdOut,strStdErr)

par exemple pour strCommand = "cmd /c dir /blabla"

Merci.
26/08/2010, 22h41
SfJ5Rpw8

Citation:

Envoyé par fleurparis

....
par exemple pour strCommand = "cmd /c dir /blabla"
....

évite des balbla ... essai de mettre des commandes plus réaliste la commade dir n'as pas d'option /blabla..;
26/08/2010, 23h07
fleurparis

comme exemple je pendrais "cmd /c dir z:"

sachant que je n'ai pas de lecteur z:, je devrais avoir une erreur du genre

"Le chemin d'accès spécifié est introuvable."

L'important étant de récupérer le code de sortie "cmd /c dir z:"

Par exemple rajoute a la fin du code..

Code:

1
2
3
4
5
6
7
8
9
Dim stCde,stOut,stErr
 Dim Ret
 stcde="cmd /c dir z:" 
 stOut=""
 stErr=""
 
 ret=ExecCommand(stCde,stOut,stErr)
 
 msgbox "ret : " & ret & vbcrlf & "Out = " & stOut & vbCrlf & "Err = " & stErr

07/09/2010, 10h54
fleurparis

Merci cela a résolu mon problème de remonter d'erreur sur un script exécuté localement.

Auriez-vous une solution pour remonter les erreurs sur un script vbs lancer sur un serveur distant ?
07/09/2010, 13h56
Feneck91

Merci bbil et désolé fleurparis je n'avais pas vu que tu m'avais posé une question...
Rien à dire de plus, bbil a bien répondu.