Deux evenements Before_save dans un Workbook.

Version imprimable

Bonjour à tous et d'avance merci de votre aide,
j'ai trouvé ces deux paragraphes de codes sur le net, que j'aimerais mixer afin d'en faire un seul (sinon Excel renvoie un message d'erreur).

Code 1: par lequel j'oblige l'utilisateur à saisir dans la cellule C6 avant de pouvoir sauvegarder

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Dim msg As String
 
    If Worksheets("Formulaire ZIMP-ZFHG").Range("C6").Value = "" Then
        msg = "Merci de saisir un type de demande!"
        Cancel = True
    End If
 
    If Cancel Then
        MsgBox msg
    End If
End Sub

Code 2:par lequel j'oblige l'utilisateur à sauvegarder uniquement sous format .xls

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    Application.EnableEvents = False
           fileSaveName = Application.GetSaveAsFilename(fileFilter:="Excel 2003 Files (*.xls), *.xls")
            If fileSaveName <> "False" And Right(fileSaveName, 4) <> ".xls" Then
               MsgBox ("Merci d'enregistrer uniquement en .xls!")
            End If
        If fileSaveName <> "False" Then
           ThisWorkbook.SaveAs Filename:=fileSaveName
        End If
 
        Cancel = True
   Application.EnableEvents = True
End Sub

24/08/2010, 12h54
AlainTech
Bonjour,

Mets les instructions des 2 sub dans une seule.
Les unes à la suite des autres.
Et dans ton
Code:

1 2 3 If Cancel Then MsgBox msg End If
insère un Exit Sub, comme ceci
Code:

1 2 3 4 If Cancel Then MsgBox msg Exit Sub End If

Peut être

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
Dim FileSaveName As Variant
 
Cancel = True
If Worksheets("Formulaire ZIMP-ZFHG").Range("C6").Value = "" Then
    MsgBox "Merci de saisir un type de demande!"
Else
    FileSaveName = Application.GetSaveAsFilename(fileFilter:="Excel 2003 Files (*.xls), *.xls")
    If FileSaveName <> False Then
        If Right(FileSaveName, 4) <> ".xls" Then
            MsgBox "Merci d'enregistrer uniquement en .xls!"
        Else
            Application.EnableEvents = False
            Application.DisplayAlerts = False
            ThisWorkbook.SaveAs Filename:=FileSaveName
            Application.DisplayAlerts = True
            Application.EnableEvents = True
        End If
    End If
End If
End Sub

25/08/2010, 10h29
ATI75

Merci infiniment...ca a marché du premier coup...exactement comme je le voulais.

Bravo pour la réactivité.