Problème avec la méthode "RANGE"

Version imprimable

Bonjour à tous!!!

Je viens vers vous car j'ai un petit souci avec un petit code vba,étant novice dans cet art j'aurais besoin d'une petite aide s'il vous plait.

Mon souci:je souhaiterais sur une meme feuille Excel coller des données sur différentes plages de cellules.
Par exemple:mon code permet via un UserForm de coller des données sur la Feuil2 à partir de la cellule A2,et j'aurais aimé coller aussi des données en H2 et P2.
Le message d'erreur afficher est "impossible de coller les infos car les zones copier et de collage sont de formes et tailles différentes..."

Donc j'ai essayé d'utiliser la méthode Range sous toutes ces formes ,impossible de réussir.

voici mon code:(souhaitant coller à partir de la cellule P2)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 Private Sub CommandButton13_Click() Dim Tabl(): j = 0 With Me.ListBoxLocataire For i = 0 To .ListCount - 1 If .Selected(i) = True Then j = j + 1 ReDim Preserve Tabl(0 To j) Tabl(j) = .List(i, 0) .Selected(i) = False End If Next End With Sheets("EXTRACTION").Activate Range([A1], [A65536].End(xlUp)).Select Set Plg = Selection For w = 1 To j For Each cell In Plg If CStr(cell.Value) = Tabl(w) Then Rows(cell.Row & ":" & cell.Row).EntireRow.Select Set maPlage = Selection 'LE METTRE EN P2 Set Destination = Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1, 0) maPlage.Copy Destination Exit For Else End If Next cell Next w Call Reaffiche End Sub
Merci beaucoup pour votre aide futur!!!!:lol:

03/08/2010, 15h56
mercatog

Sans tester le code (avec des Select et activate) non nécessaires; tu veux copier une ligne entière dans une cellule de la colonne P

Code:

Set Destination = Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1, -15)

c'est à dire la cellule correspondante de la colonne A
03/08/2010, 16h05
mikapwel2004

SLT mercatog,

J'ai essayé ton code cad en modifiant mon offset ,et désolé ça ne fonctionne pas ,il me le colle la ligne entiere à partir de A2.
C'est exactement ce que tu m'as décrit ,c'est de coller à partir de P2 la ligne entière,puis qu'il s'incrémente comme dans A pour P.

Merci de ta réponse en tout cas!:ccool:

Non, je n'avais pas répondu
J'avais montré que tu ne peux pas copier une ligne entière (256colonnes en excel 2003) et la coller à partir de la colonne P
tu veux copier une plage de 256 colonnes dans une autre plage ne contenant que 241 colonnes.

J'ai modifié ton code sans pouvoir tester ce que tu veux faire. d'abord, déclaration des variables, ensuite choix des noms des variables, ensuite indenter le code, virer les Select et activate et enfin libérer les plages.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
 
Private Sub CommandButton13_Click()
Dim i As Integer, j As Integer, w As Integer
Dim Plg As Range, MaPlage As Range, Cel As Range, Destin As Range
Dim Tabl()
 
With Me.ListBoxLocataire
    For i = 0 To .ListCount - 1
        If .Selected(i) = True Then
            j = j + 1
            ReDim Preserve Tabl(0 To j)
            Tabl(j) = .List(i, 0)
            .Selected(i) = False
        End If
    Next
End With
With Sheets("EXTRACTION")
    Set Plg = .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp))
    For w = 1 To j
        For Each Cel In Plg
            If CStr(Cel.Value) = Tabl(w) Then
                Set MaPlage = .Range("A" & Cel.Row & ":P" & Cel.Row)    '???? ICI à VOIR ce que tu veux copier
                Set Destin = Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1, -15)  '??? Où tu veux coller?
                MaPlage.Copy Destin
                Set MaPlage = Nothing
                Set Destin = Nothing
                Exit For
            End If
        Next Cel
    Next w
    Set Plg = Nothing
End With
Call Reaffiche
End Sub

PS: j'ai mis des questions en commentaire.

Edit: Tu peux utiliser Find (F1 pour la synthaxe) au lieu de la boucle sur les cellules de la colonne A

Salut mikapwel2004 et le forum
Pour avoir accès aux balises de code, clique simplement sur le # de la barre de mise en forme (ou édite un poste qui en contient et regade).

Citation:

Le message d'erreur affiché est "impossible de coller les infos car les zones copier et de collage sont de formes et tailles différentes..."

Les messages d'erreur de microsoft ne veulent pas toujours dire ce qu'ils "expliquent" :mrgreen:
Code:

1 2 3 4 5 6 7 8 Range([A1], [A65536].End(xlUp)).Select Set Plg = Selection For w = 1 To j For Each cell In Plg If CStr(cell.Value) = Tabl(w) Then Rows(cell.Row & ":" & cell.Row).EntireRow.Select Set maPlage = Selection 'LE METTRE EN P2
Hormis les select/selection qui ne servent à rien à part rendre illisible un code et à le ralentir...
je copie une ligne dans MaPlage. Soit, sous les versions avant 2007, 256 cellules. et je veux les copier à parir de P, jusqu'à la dernière soit mettre 256 cellules sur 240. À moins d'avoir un bon chasse-pied... :mrgreen:
Regarde dans l'aide à Resize, propriété
A+

03/08/2010, 16h18
mikapwel2004

re,

Ah ok excuse moi mercatog,si j'ai bien compris ce que tu m'as expliqué,si je ne copie pas la ligne entière mais seulement le nombre de colonnes (donc le nombre d'éléments) ça pourrait fonctionner?!

j'essaye ton code et je te tiens au courant!!merciiiiiii

Bonjour Gorfael,

Oui justement mercatog m'expliquer cela,donc sous la version 2007 ça peut fonctionner?et si je choisis q'un nombre de colonnes limités ça peut marcher?

merci
03/08/2010, 16h21
mercatog

Tu adaptes les 2 lignes où j'ai mis des questions en commentaire dans le code
03/08/2010, 16h50
mikapwel2004
mercatog,

j'ai adapté le code et les deux lignes comme tu me l'as conseillé ,ça ne fonctionne pas il continue à me le copier en A.

voici comment j'ai adapté les deux lignes:
Code:

1 2 3 set MaPlage=.Range("A" & Cel.Row & "F:" & Cel.Row) Set Destin=Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1,-15)
03/08/2010, 16h52
mikapwel2004

Non super je viens de trouver il fallait modifier le "Offset"!!!

Merci beaucoup!!:ccool::lol:

Tu n'as pas adpté la 2ème ligne
tu veux copier la plage de A à F à partir de P

Code:

1
2
set MaPlage=.Range("A" & Cel.Row & "F:" & Cel.Row)
Set Destin=Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1,0)

une proposition d'amélioration avec Find

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub CommandButton13_Click()
Dim i As Integer, j As Integer, w As Integer
Dim Plg As Range, Cel As Range
Dim Tabl()
 
With Me.ListBoxLocataire
    For i = 0 To .ListCount - 1
        If .Selected(i) = True Then
            j = j + 1
            ReDim Preserve Tabl(0 To j)
            Tabl(j) = .List(i, 0)
            .Selected(i) = False
        End If
    Next
End With
If j >= 1 Then
    With Sheets("EXTRACTION")
        Set Plg = .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp))
        For w = 1 To j
            Set Cel = Plg.Find(Tabl(w), LookIn:=xlValues, lookat:=xlWhole) 'à voir les données de la colonne A
            If Not Cel Is Nothing Then
                .Range("A" & Cel.Row & ":F" & Cel.Row).Copy Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1, 0) 
                Set Cel = Nothing
            End If
        Next w
        Set Plg = Nothing
    End With
End If
Call Reaffiche
End Sub

03/08/2010, 16h58
mikapwel2004

Ah oui pourtant ça marche très bien.
Exactement je veux copier de la plage A à F de la feuille "extraction" ,à partir de la colonne P de la feuille "Urgence".
tu peux m'indiquer où j'ai fait une erreur stp?(pour ma progression!!lol)

Je teste ton autre code!!!merciiiiiiiiiiiii.

Cordialement.
03/08/2010, 17h01
mercatog

Code:

Set Destin=Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1,-15)

donne la cellule de la colonne A (reculer de 15 colonne à partir de la colonne P)

Code:

Set Destin=Sheets("URGENCE").Range("P65536").End(xlUp).Offset(1,0)

tu copie dans la cellule de la colonne P. Tu as déjà rectifié
03/08/2010, 17h12
mikapwel2004

ah ok :ccool:

je vais l'adapter à tout mes boutons d'extraction!!

en tout cas un big big merci ,sincerement!!!!

Cordialement,

Tu peux t'en passer du tableau (une boucle en moins)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub CommandButton13_Click()
Dim i As Integer
Dim Plg As Range, Cel As Range
 
Application.ScreenUpdating = False
If Me.ListBoxLocataire.ListCount > 0 Then
   With Sheets("EXTRACTION")
      Set Plg = .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp))
      For i = 0 To Me.ListBoxLocataire.ListCount - 1
         If Me.ListBoxLocataire.Selected(i) Then
            Set Cel = Plg.Find(Me.ListBoxLocataire.List(i, 0), LookIn:=xlValues, lookat:=xlWhole)
            If Not Cel Is Nothing Then .Range("A" & Cel.Row & ":F" & Cel.Row).Copy Sheets("URGENCE").Cells(Rows.Count, "P").End(xlUp)(2)
            Me.ListBoxLocataire.Selected(i) = False
         End If
      Next i
      Set Plg = Nothing
   End With
   Call Reaffiche
End If
End Sub

04/08/2010, 10h15
mikapwel2004

Merci beaucoup Mercatog!!!!!:P