Modifier un fichier XHTML avec XSL

Version imprimable

20/07/2010, 15h46
m1ckros

Modifier un fichier XHTML avec XSL

Bonjour à tous,

J'ai des fichiers xhtml, de toutes formes, et j'aimerai pouvoir y effectuer des changements à la volée sur certaines balises.
Par exemple, changer un champ input de la forme :

Code:

<input type="text" value="machin" />

... en span :

Code:

<span>machin</span>

Je me débats maintenant depuis un petit moment avec XSL et j'avoue que je commence à douter.
Est-ce que c'est possible de lui dire "change moi tous les input du fichier en span" sans que l'on précise le chemin par lequel il devra passer pour trouver chacun des input ?
Parce que là, comme je suis parti, je suis obligé de recréer entièrement le XHTML (balise par balise quasiment) que j'avais pour refaire quasiment la même chose à un détail près. De plus, ça commence à ne plus être applicable à tous types de structures.

Dois-je continuer sur cette voix ou penser à aller voir ailleurs (DOM, SAX...) ?

Voilà, je suis peut-être allé un peu vite. N'hésitez pas à me demander plus de détails si besoin est. ;)

Merci pour votre aide.
21/07/2010, 11h44
polymorphisme

Bonjour m1ckros,

tu trouvera les réponses dans les tutoriels XML destinés aux débutants.

Bonne lecture. ;)

Hello,
XSL-T est très performant & concis dans ce genre de tache. En gros on part d'une transformation en copie et on y ajoute les exceptions qu'on souhaite introduire.

Un XSL-T en copie c'est ça :

Code:

1
2
3
4
5
6
7
8
9
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
    <xsl:template match="node() | @*">
         <xsl:copy>
              <xsl:apply-templates select="node() | @*"/>
         </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Après si on prend ton exemple avec les champs "input" :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
    <xsl:template match="input">
         <span><xsl:value-of select="@value"/></span>
    </xsl:template>
 
    <xsl:template match="node() | @*">
         <xsl:copy>
              <xsl:apply-templates select="node() | @*"/>
         </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Si tu traites du xhtml, attention au namespace qu'il faut bien préciser dans le XSL-T

Merci Morbo, je commençais tout juste à partir dans cette direction.

Par contre, c'est un peu bizarre.
Prenons un fichier xhtml basique :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="fr" lang="fr">
<head>
	<meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
	<title></title>
</head>
<body>
	<p>bonjour</p>
	<form>
		<input type="text" value="voiture" />
		<input type="submit" />
	</form>
</body>
</html>

Si j'y applique le XSL suivant :

Code:

1
2
3
4
5
6
7
<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:root="http://localhost:8080/monProjet">
	<xsl:template match="node()|@*">
		<p>Salut</p>
	</xsl:template>
</xsl:stylesheet>

... j'ai du html généré (pas vraiment valide, je vous l'accorde) qui ressemble à ça :

Code:

1
2
<?xml version="1.0" encoding="UTF-8"?>
<p xmlns:root="http://localhost:8080/monProjet">Salut</p>

Mais, dès que je veux faire plus compliqué :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:root="http://localhost:8080/monProjet">
 
	<xsl:template match="node()|@*">
		<xsl:copy>
			<xsl:apply-templates select="node()|@*" />
		</xsl:copy>
	</xsl:template>
 
	<xsl:template match="input">
		<span><xsl:value-of select="@value"/></span>
	</xsl:template>
 
</xsl:stylesheet>

... lui ne veut pas.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
<?xml version="1.0" encoding="UTF-8"?>
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="fr" lang="fr">
<head>
	<meta http-equiv="Content-Type" content="text/html; charset=UTF-8"/>
	<title/>
</head>
<body>
	<p>bonjour</p>
	<form>
		<input type="text" value="voiture"/>
		<input type="submit"/>
	</form>
</body>
</html>

Est-ce que cela pourrait venir de cette histoire de namespace ?

Ouaip, ça vient des namespaces :

Code:

<html xmlns="http://www.w3.org/1999/xhtml" >

Ca veut dire que toute les élements enfants sans préfixes appartiennent au namespace "http://www.w3.org/1999/xhtml" (sauf si un élement redéfini le namespace par défaut).
Une notation équivalente possible en utilisant le préfixe 'x' pourrait être :

Code:

<x:html xmlns:x="http://www.w3.org/1999/xhtml" >

Bref, ça veut dire qu'il faut le spécifier dans le xsl :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 <?xml version="1.0" encoding="utf-8" ?> <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xhtml="http://www.w3.org/1999/xhtml">  <xsl:output method="html" version="4.0" encoding="iso-8859-1" indent="yes"/> <xsl:template match="node()|@*"> <xsl:copy> <xsl:apply-templates select="node()|@*" /> </xsl:copy> </xsl:template> <xsl:template match="xhtml:input"> <span><xsl:value-of select="@value"/></span> </xsl:template> </xsl:stylesheet>
Note que les préfixes du xml en entrée et celui du xsl peuvent être différents, tout ce qui compte c'est l'unicité de "http://www.w3.org/1999/xhtml"

21/07/2010, 15h56
m1ckros

Merci, c'est exactement ça ! :ccool:

Pour method="html", je crois que je vais oublier. Il me pourrit tellement mon HTML que ç'en est choquant (ajout de balises meta en majuscules, modification des <balise /> en <balise>...). :lol:

On pourrait préférer l'approche :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns="http://www.w3.org/1999/xhtml"
  xmlns:xhtml="http://www.w3.org/1999/xhtml"
  exclude-result-prefixes="xhtml"
  >

	<xsl:template match="node()|@*">
		<xsl:copy>
			<xsl:apply-templates select="node()|@*" />
		</xsl:copy>
	</xsl:template>
 
	<xsl:template match="xhtml:input">
		<span><xsl:value-of select="@value"/></span>
	</xsl:template>
 
</xsl:stylesheet>