Compter le nombre de niveau dans une arborescence

Version imprimable

09/07/2010, 12h08
Guiiil

Compter le nombre de niveau dans une arborescence
Bonjour à tous,

J'ai encore un dernier problème sur lequel je coince... Je dois récupérer le nom du niveau d'une arborescence rentré par l'utilisateur. Je pensais donc compter le nombre d'antislash pour récupérer la dernière partie avec un tokens.

Hors, je n'ai vraiment pas la moindre idée de comment compter le nombre d'un caractère spécifique dans une chaine de caractère. J'ai cherché sans fin toute la mâtiné, sans rien trouvé... A croire que personne n'a eu ce problème avant moi T.T.

Voici ce que j'ai déjà tenté de faire, mais bien évidement, ça ne m'avance pas beaucoup...
Code:

1 2 3 for /f "delims=\" %%u in ("%DossierPhotos%") do set /a nb=!nb!+1 echo %nb% pause
Si vous avez une idée ou un conseil ^_^.
09/07/2010, 13h41
I'm_HERE

salut,

Citation:

Envoyé par Guiiil

A croire que personne n'a eu ce problème avant moi T.T.

voir par ici, ici aussi et encore là
09/07/2010, 14h54
Guiiil

Salut à toi, et merci pour ta réponse.

Mais aucun des trois ne me correspond ^^". Ou alors j'ai loupé un passage important.

En fait j'ai toujours mon script qui renomme les fichiers selon le nom du dossier et qui les déplaces dans un dossier à part. Jusqu'à maintenant tout fonctionnait... Hors ! On m'a demandé de donner la possibilité de rentrer le nom du chemin dans l'invité de commande.

Ce qui fait que je ne peux plus soustraire de la chaine la partie qui m'intéressait, puisque je ne la connais plus.

Par exemple, l'utilisatrice rentrera C:\Users\ChauffeMarcel\Documents\CMD, et le programme récupèrera les fichiers dans C:\Users\ChauffeMarcel\Documents\CMD\DossierUn, C:\Users\ChauffeMarcel\Documents\CMD\DossierDeux...

Le truc, c'est que %~nx1 me sort le nom du fichier. Donc j'ai le droit à C:\Users\ChauffeMarcel\Documents\CMD\DossierUn\DossierUn1.jpg. Mais ce que je souhaite, c'est récupérer le nom de son dossier, donc C:\Users\ChauffeMarcel\Documents\CMD\DossierUn\DossierUn1.jpg.

Voilà pourquoi je souhaite connaitre le nombre de niveau, comme ça je n'ai qu'à récupérer la partie qui m'intéresse grâce à tokens en incrémentant une fois.

En te remerciant pour ton aide ^_^ (et celle de ceux qui passeront).

salut,

tu peux t'inspirer de ceci:
Code:

1 2 3 set dossier=chemin du rep for /d %%a in ("%dossier%\*") do echo %%a

09/07/2010, 16h44
Guiiil

Mmmh... Dommage... Je pense que ça n'ira pas (pourtant j'y ai cru).
Le problème de la méthode que tu m'as donné et qu'elle implique que je ne fasse que le tour des dossiers... Je m'y attelle depuis tout à l'heure, mais ce n'est guère concluant, étant donné que le for commence par vérifier tous les dossiers avant les fichiers. Du coup, impossible de savoir quand le script change de dossier. Même si je peux récupérer le nom des dossiers, si je ne sais pas quand les utiliser pour renommer les fichiers...

N'y a t-il vraiment aucune moyen de compter les antislashs (ou autre) dans une chaine ?
Comme ça, ça me permettrait de ne prendre que la partie de la chaine qui m'intéresse...
09/07/2010, 17h51
I'm_HERE
salut,
Code:

1 2 3 set dossier=chemin du rep for /d %%a in ("%dossier%\*") do echo %%a
ce script fait exactement ce que tu demandes:

Par exemple, l'utilisatrice rentrera "C:\Users\ChauffeMarcel\Documents\CMD", et le programme récupèrera les fichiers dans "C:\Users\ChauffeMarcel\Documents\CMD\DossierUn", "C:\Users\ChauffeMarcel\Documents\CMD\DossierDeux"...

donc il va récupérer tous les dossiers "enfants" du répertoire %dossier%
ensuite tu peux récupérer tes fichiers dans ces répertoires

Merci pour ta réponse ^^,

Je n'ai réellement pas réussi à l'intégré dans mon programme... Je dois être fatigué...

Voici le programme d'origine :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
@echo off
SETLOCAL ENABLEdelayedExpansion

REM Pour comprendre les %~x1 et autres joyeusetés du genre, taper call /? |find "~" dans l'invité de commandes

set nb=1
set point=.
set dossier=dossier

REM On récupère les differents chemins requis
echo Bonjour,
echo.
echo Dans quel dossier sont places les photos ?
echo Exemple : C:\Users\Francis\Documents\ZePhotos
set /p DossierPhotos=
echo.
echo Quel est le dossier de destination ?
echo Exemple : C:\Users\Francis\Desktop\ZeDossier
set /p DossierDestination=


REM Ce script permet le renommage des fichiers dans des sous dossiers avant de les copier dans un dossier général.

for /f "delims=" %%a in ('dir %DossierPhotos% /s/b') do call :cmd "%%a"
REM On arrive ici à la fin du script
echo "les fichiers ont tous ete renomme"
pause

REM Les fichiers sont copiés dans le répertoire choisi 
for /r %DossierPhotos% %%i in (*.*) do (
set /a nbdossier+=1
copy %%i %DossierDestination%
)
REM echo %nbdossier% "photos transferes"
echo "les fichiers ont tous ete transfere"
pause

:cmd
	set chemin=%~p1
	set ext=%~x1
	set chemin=%chemin:\=%
	set chemin=%chemin:UsersFrancisDocumentsCMD=%
	
	REM Si on change de dossier, on revient à 1
	if "%chemin%" NEQ "%dossier%" set nb=1
	
	REM On élimine les derniers caractères litigeux
	set fichier=%chemin: =_%
	set fichier=%chemin:(=_%
	set fichier=%chemin:)=_%
	
	REM Si la variable ne possède pas d'extension, c'est que c'est un dossier, donc on passe outre
	set ext=%ext:~0,1%
	if "%ext%" NEQ "%point%" goto Continuer
	
	REM On attribue au fichier son nouveau nom
	set fichier=%chemin%_%nb%
	set /a nb=!nb!+1
	REM echo %fichier%%~x1
	ren "%~f1" %fichier%%~x1
	set dossier=%chemin%
	
	:Continuer

Et les améliorations apportés avec ton bout de code, mais qui ne m'ont mené que devant un mur...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
@echo off
SETLOCAL ENABLEdelayedExpansion

REM Pour comprendre les %~x1 et autres joyeusetés du genre, taper call /? |find "~" dans l'invité de commandes

set nb=0
set nbBoucle=0
set nbBoucleDeux=0
set nbVraiDossier=0
set nbDossier=0
set point=.
set dossier=vide
set nbLesDossiers=1;

REM On récupère les differents chemins requis
echo Bonjour,
echo.
echo Dans quel dossier sont places les photos ?
echo Exemple : C:\Users\Francis\Documents\ZePhotos
set /p DossierPhotos=
echo.
echo Quel est le dossier de destination ?
echo Exemple : C:\Users\Francis\Desktop\ZeDossier
set /p DossierDestination=

for /d %%a in ("%DossierPhotos%\*") do set /a nbDossier=!nbDossier!+1

REM Ce script permet le renommage des fichiers dans des sous dossiers avant de les copier dans un dossier général.

for /f "delims=" %%a in ('dir %DossierPhotos% /s/b') do call :cmd "%%a"
REM On arrive ici à la fin du script
echo "les fichiers ont tous ete renomme"
pause

REM Les fichiers sont copiés dans le répertoire choisi 
for /r %DossierPhotos% %%i in (*.*) do (
set /a nbLesDossiers+=1
copy %%i %DossierDestination%
)
REM echo %nbLesDossiers% "photos transferes"
echo "les fichiers ont tous ete transfere"
pause

:cmd

	set ext=%~x1
	
	if "%nbBoucleDeux%" GTR "%nbDossier%" (
		if "%ext%" NEQ "%point%" 
		
		for /d %%e in ("%DossierPhotos%\*") do (
			if "%nbBoucle%" EQU "%nbDossier%" (
				chemin=%~n1
			)
			set /a nbBoucle=!nbBoucle!+1
		)
		set /a nbVraiDossier=!nbVraiDossier!+1
		echo vlan
	)
	
	echo %chemin%
	pause
	
	REM Si on change de dossier, on revient à 1
	if "%chemin%" NEQ "%dossier%" set nb=1
	
	REM On élimine les derniers caractères litigeux
	set chemin=%chemin: =_%
	set chemin=%chemin:(=_%
	set chemin=%chemin:)=_%
	
	REM Si la variable ne possède pas d'extension, c'est que c'est un dossier, donc on passe outre
	set ext=%ext:~0,1%
	
	set /a nbBoucleDeux=!nbBoucleDeux!+1 
	
	if "%ext%" NEQ "%point%" goto Continuer
	
	REM On attribue au fichier son nouveau nom
	set fichier=%chemin%_%nb%
	set /a nb=!nb!+1
	REM echo %fichier%%~x1
	ren "%~f1" %fichier%%~x1
	set dossier=%chemin%
	
	:Continuer

Je dois avoir un sérieux problème de logique, mais je ne vois pas comment agencer tout ça...

09/07/2010, 18h55
I'm_HERE
désolé, de ce monde je déteste deux choses: la fumée et le débogage..
mais puisque tu as essayer de trouver une solution alors j'essayerais de t'aider.
De ce que j'ai compris de tes scripts tu veux renommer tous les fichiers d'une arborescence donnée par le nom de leurs dossiers-parent tout en créant un compteur pour ne pas avoir des écrasement à la fin de la copie:

une chose du genre:
Code:

1 2 3 4 5 C:\Users\Francis\po.jpg c:\User\Francis\Doc\ht.jpg c:\User\Jean\hs\jo.txt c:\User\Chris\Document\drop.js c:\User\Chris\Document\stop.txt
et au final le resultat sera:
Code:

1 2 3 4 5 Francis_1.jpg Doc_2.jpg hs_3.txt Document_4.js Document_5.txt
?
12/07/2010, 09h13
Guiiil
C'est exactement ça. On m'a demandé de créer un script en batch permettant de prendre des photos placés dans plusieurs dossiers et de les déplacer dans un dossier général où elles seront traités tout en les renommant avec le nom du dossier pour que l'on sache d'où elles viennent.

Je ne connaissais pas franchement les .cmd et .bat, mais j'ai réussi tant bien que mal à réaliser le premier script. L'ennuie, c'est que j'avais totalement zappé cette partie :
Code:

1 2 set chemin=%chemin:\=% set chemin=%chemin:UsersFrancisDocumentsCMD=%
En gros, le script ne pouvait marcher que sur mon ordi... Et les personnes à qui le script est destiné ne sont pas vraiment apte à l'ouvrir à chaque utilisation pour changer le chemin (d'où les questions au début du programme).

Au final, j'ai rajouté une question où elles doivent rentrer le nombre de niveau, afin de pouvoir traiter le chemin, mais bon, je trouve cette solution assez... triste ?

Mais bon, vu que globalement, désormais ça marche, si tu n'as pas le temps, je comprendrais ! ;-)

En tout cas un grand merci.

salut,

essayes ceci:
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 @Echo oFF Setlocal enabledelayedexpansion Set Dossier=C:\DUMP\TIPS Set Destination=D:\Documents and Settings\walid\Bureau\destop Set /A nb=1 For /F "Delims=" %%s In ('Dir "%Dossier%" /A-D/B/S') Do ( If Not ""!Z!""==""%%~pds."" Set /A nb=1 For %%i In ("%%~pds.") Do ( Set "z=%%~i" Echo=%%~ni_!nb!%%~xs Set /A nb+=1 ) ) Endlocal & pause
- le 1er FOR va lister tous les fichiers voir commutateur "A-D"
- le 2eme FOR va extraire le nom du dossier du dernier niveau
- la setlocal enabledelayedexpansion va te permettre de switcher vers la nouvelle syntaxe de variables (expansion de variables)

<EDIT>
Le compteur nb va se réinitialiser automatiquement pour chaque niveau. Si tu veux que l'incrément continue tu effaces les lignes:
If Not ""!Z!""==""%%~pds."" Set /A nb=1
Set "z=%%~i"
</EDIT>

12/07/2010, 10h10
Guiiil
Ou comment faire en 4 lignes ce que je fais en 15 V_v... Il me reste beaucoup à apprendre ;-p.

Pourrais-tu m'expliquer ces deux lignes ?
Code:

1 2 For /F "Delims=" %%s In ('Dir "%Dossier%" /A-D/B/S') Do ( If Not ""!Z!""==""%%~pds."" Set /A nb=1
A quoi correspondent les formulations /A-D/ et ""%%~pds."" (ainsi que le pourquoi du comment des doubles doubles quotes ?

En te remerciant ^_^
12/07/2010, 10h28
I'm_HERE

Citation:

Envoyé par Guiiil

/A-D
[/code]

c'est pour filter les fichiers

Code:

hh ntcmds.chm::/dir.htm

Citation:

Envoyé par Guiiil

%%~pds.

tu peux combiner les différents modificateurs ici c'est %~ps + %~ds + .

Citation:

Envoyé par Guiiil

des doubles doubles quotes ?

c'est une double protection dans des cas précis.
12/07/2010, 11h25
Guiiil

Citation:

Envoyé par I'm_HERE

c'est pour filter les fichiers

Code:

hh ntcmds.chm::/dir.htm

Oui, j'avais déjà vu ce fichier, mais quand j'essaye de l'ouvrir, on me dit que c'est impossible...

Pour revenir au programme, une fois dans la boucle, les echo sur mes variables ne fonctionnent plus (ou affiche du vide). Tu sais à quoi cela pourrait être dû ?

Et merci pour tes explications ^^.
12/07/2010, 11h46
I'm_HERE

Citation:

Envoyé par Guiiil

les echo sur mes variables ne fonctionnent plus (ou affiche du vide). Tu sais à quoi cela pourrait être dû ?

dans ton cas il faut utiliser !variable! à la place de %variable%
12/07/2010, 11h54
Guiiil

Ah d'accord ! Je pensais qu'il ne fallait faire ça que dans le cas d'un calcul.

Tiens, puis-je te déranger une dernière fois ? Il m'a été dit que le concept "rentrer l'adresse dans l'invité de commande était trop complexe pour ces dames" (je doute, mais bon, il parait que...). Maintenant je dois réaliser un concept pour qu'elles n'aient qu'à cliquer sur les dossiers voulu dans l'explorer (ou un truc du genre). Étant donné que je ne vois même pas quoi taper dans google pour visualiser comment atteindre ce résultat, tu aurais une idée ? Et si c'est impossible, tant mieux, je leur dis et je passe à autre chose !

(en te remerciant, pour respecter la tradition ;-p)

tu peux faire une chose du genre:

pas bien tester, mais je crois que t'as compris le concept..on utilise la fonction VBS browseforfolder() de l'objet shell.application qui va nous restituer une boite de selection.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@Echo oFF
@Set tmpvbs="%Temp%.\t.vbs"
@Goto :up ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  set osh1=createobject("shell.application").namespace(&H11&).self 'VBS
  set osh2=createobject("shell.application") 'VBS
  Set ojf=osh2.browseforfolder(0,"Selection",0,osh1.path) 'VBS
  if ojf is nothing then 'VBS
      wsh.quit 'VBS
  end if 'VBS
  set oitem = ojf.self 'VBS
  stp = oitem.path 'VBS
  wsh.echo stp 'VBS
:up ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Setlocal enabledelayedexpansion
>%tmpvbs% FindStr "'VBS$" %0
for /f "delims=" %%a in ('
  cscript -nologo %tmpvbs% ^& del %tmpvbs%
 ') do set $dossier=%%a
if not defined $dossier exit /b 1
 Set Destination=D:\Documents and Settings\walid\Bureau\destop
  Set /A nb=1
  For /F "Delims=" %%s In ('Dir "%$Dossier%" /A-D/B/S') Do (
    If Not ""!Z!""==""%%~pds."" Set /A nb=1
    For %%i In ("%%~pds.") Do (
       Set "z=%%~i"
       Echo=%%~ni_!nb!%%~xs  
       Set /A nb+=1 
    )   
)
Endlocal & pause

12/07/2010, 14h03
Guiiil

Merci beaucoup, effectivement je vois à peu près comment ça fonctionne.
On m'a donné un autre truc urgent à faire, donc je ne viendrais plus (ou alors pas tout de suite) t'importuner, et je pense que j'arriverai à me débrouiller avec ton dernier code.

Merci encore pour toute ton aide, et à la prochaine ^_^.