Ventiler des données par détection de Sauts de page

Version imprimable

10/06/2010, 09h34
Abyssale

Ventiler des données par détection de Sauts de page

Bonjour,

J'ai un classeur avec une seule feuille nommée feuille :).

Dans cette feuille, j'ai une succession de données séparées par des sauts de page.

Exemple :

VOITURE 1
bla bla bla

SAUT DE PAGE

VOITURE 2
bla bla bla

SAUT DE PAGE

VOITURE 3
bla bla bla

Est-il possible de séparer ces "blocs" pour en faire autant de feuilles ou classeur distincts ?

Merci
10/06/2010, 10h31
Fvandermeulen

Bonjour et bienvenue sur le forum,

J'imagine que tu pense à une macro pour faire ceci...hormis le saut de page, y a t'il un autre élément qui permet de distinguer un bloc d'un autre?
Comme dans ton exemple, on peut utiliser Voiture.

A+
10/06/2010, 10h57
Abyssale

Non, seul le saut de page permet de distinguer les blocs.

J'ai indiqué VOITURE pour simplifier mon message.
Dans le vrai fichier il y aurait à la place le modèle de la voiture...

Re,

Je posais la question car il me semblait que ça allait être plus chaud de définir les plages en fonction du saut de page mais en fait non.
Dans le code ci-dessous, en fonction des sauts de pages on copie la plage dans une nouvelle feuille renommée suivant le contenu de la première cellule de cette plage (j'imagine le modèle)
J'ai considéré une seule colonne.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub CopieSelonSautDePage()
Dim NbHPB As Long, R As Long, Rdeb As Long, Rfin As Long
 
NbHPB = Sheets("TaFeuil").HPageBreaks.Count 'Compte le nombre de saut de page
Rdeb = 1 'Si premier modèle en ligne 1, servira pour délimiter le début de plage à copier
 
For R = 1 To NbHPB 'Boucle sur chaque saut de page
    Rfin = Sheets("TaFeuil").HPageBreaks(R).Location.Row - 1 'Indique le numéro de ligne précédent le saut de page
    Sheets.Add.Name = Sheets("TaFeuil").Cells(Rdeb, 1).Value  'Renomme la feuille ajoutée avec le contenu de la première cellule de la plage
    Sheets("TaFeuil").Range(Sheets("TaFeuil").Cells(Rdeb, 1), Sheets("TaFeuil").Cells(Rfin, 1)).Copy Destination:=Range("a1") 'Copie la plage concernée sur la nouvelle feuille
    Rdeb = Rfin + 1 'Défini le début de plage suivant
Next R 'Passe au saut de page suivant
 
End Sub

A+

10/06/2010, 12h23
Abyssale

Génial !!!

Je ne n'y comprends pas grand chose mais génial !

Il me semble que dans la macro, le nom Tafeuil doit être celui de la feuille contenant les données, c'est ça ?
Si oui, la macro ne peut-elle pas se servir du nom de la feuille directement ?

La création des feuilles se faiten "ordre inverse", du style :

VOITURE 3 VOITURE 2 VOITURE 1

Est-il possible d'avoir :

VOITURE 1 VOITURE 2 VOITURE 3

En tous cas, merci déjà pour tout cela. :)

Et comment faire pour que les cellules copiées incluent toutes les cellules à copier ?
Pas clair ça. ;)
Dans mon premier bloc, la première cellule sert de nom de la future feuille : ok.
En dessous et jusqu'au saut de page les cellules doivent aussi être copiées. Si par exemple j'ai les cellules de A2 à J20 de remplies, bien il faudrait les copier.

J'ai compris que tout ce joue là, mais comment le modifier ?
Sheets("Feuil1").Range(Sheets("Feuil1").Cells(Rdeb, 1), Sheets("Feuil1").Cells(Rfin, 1)).Copy Destination:=Range("a1")

Re,

En deux mot:
HPBreaks = saut de page, grâce à ça on trouve la ligne où le saut de page est défini.
On compte le nombre de saut de page, on passe sur chaque saut de page pour avoir la ligne de fin de la plage.
On copie la plage.

Pour la position des feuilles, j'ai ajouter une ligne pour que la feuille ajoutéé soit déplacée dernière la dernière.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 Sub CopieSelonSautDePage() Dim NbHPB As Long, R As Long, Rdeb As Long, Rfin As Long NbHPB = Sheets("TaFeuil").HPageBreaks.Count 'Compte le nombre de saut de page Rdeb = 1 'Si premier modèle en ligne 1, servira pour délimiter le début de plage à copier For R = 1 To NbHPB 'Boucle sur chaque saut de page Rfin = Sheets("TaFeuil").HPageBreaks(R).Location.Row - 1 'Indique le numéro de ligne précédent le saut de page Sheets.Add.Name = Sheets("TaFeuil").Cells(Rdeb, 1).Value 'Renomme la feuille ajoutée avec le contenu de la première cellule de la plage Sheets(Sheets("TaFeuil").Cells(Rdeb, 1).Value).Move After:=Sheets(Sheets.Count) Sheets("TaFeuil").Range(Sheets("TaFeuil").Cells(Rdeb, 1), Sheets("TaFeuil").Cells(Rfin, 1)).Copy Destination:=Range("a1") 'Copie la plage concernée sur la nouvelle feuille Rdeb = Rfin + 1 'Défini le début de plage suivant Next R 'Passe au saut de page suivant End Sub
A+

Edit: J'ai oublié de répondre à ta question sur le nom de la feuille, oui "TaFeuil" est le nomp de la feuille sur laquelle il y a les données.

10/06/2010, 12h47
Abyssale

Ca marche impeccable.

Cependant, comment faire pour que la plage copiée aille au-delà de la colonne B ?

En le testant, je n'ai que la colonne A qui se copie ???

En tous cas, merci pour ton aide.
10/06/2010, 12h56
Fvandermeulen

Re,
C'est cette ligne ci qu'il faut modifier:

Code:

Sheets("TaFeuil").Range(Sheets("TaFeuil").Cells(Rdeb, 1), Sheets("TaFeuil").Cells(Rfin, 1)).Copy Destination:=Range("a1") 'Copie la plage concernée sur la nouvelle feuille.

Range indique une plage et fonctionne avec deux arguments, cellule de début de plage et cellule de fin de plage.
Pour définir la cellule, j'utilise Cells qui fonctionne aussi avec deux arguments, numéro de ligne et ensuite numéro de colonne.
Donc cells(2,1) = cellule A2 et range(cells(2,1),Cells(5,2) = A2:B5

Admettons que tu copie de A à E:

Code:

Sheets("TaFeuil").Range(Sheets("TaFeuil").Cells(Rdeb, 1), Sheets("TaFeuil").Cells(Rfin, 5)).Copy Destination:=Range("a1") 'Copie la plage concernée sur la nouvelle feuille.

A+
10/06/2010, 13h45
Abyssale

Ok, j'ai pigé le truc, mais pas facile de coder une seule ligne quand on en a jamais fait. ;)

Et pour récupérer automatiquement le nom de l'onglet de la feuille à partir de laquelle tu lances la macro, comment faut'il faire ?

J'avais pensé remplacer "TaFeuil" par un truc du style Sheet.Name, mais bien sur ça ne fonctionne pas.

Hop hop hop, je crois avoir trouvé, faut remplacer par ActiveSheet.Name, c'est ça ?
10/06/2010, 16h52
Abyssale

Bon, j'ai bien solutionné tout ce qui est mentionné ci-avant.
Ma feuille initialle est ainsi constituée (tirets = mes saut de pages, points = saut de page d'Excel ???):

VOITURE 1 XXXXX XXXXX
VOITURE 1 XXXXX XXXXX
VOITURE 1 XXXXX XXXXX
------------------------------
VOITURE 2 XXXXX XXXXX
VOITURE 2 XXXXX XXXXX
------------------------------
VOITURE 3 XXXXX XXXXX
VOITURE 3 XXXXX XXXXX
..........................................
VOITURE 3 XXXXX XXXXX
------------------------------

Donc, lorsque la macro créée les nouvelles feuilles, elle se casse les chicots sur les points car elle veut donner le nom VOITURE 3 à une feuille qui existe déjà.

Comment faire, please ?
10/06/2010, 18h20
Fvandermeulen

Re,
Donc OK pour le nom de la feuille, par contre je comprends pas MES sauts de pages et saut de page Excel.
Il n'y a qu'un type de saut de page, celui qui fait la différence à l'impression.
Qu'appelles tu exactement MES sauts de page ?
11/06/2010, 12h00
Abyssale

Désolé, je me suis mal exprimé.

Mon fichier d'origine est en fait tout "tassé" :

VOITURE 1 XXXXX XXXXX
VOITURE 1 XXXXX XXXXX
VOITURE 1 XXXXX XXXXX
VOITURE 2 XXXXX XXXXX
VOITURE 2 XXXXX XXXXX
VOITURE 3 XXXXX XXXXX
VOITURE 3 XXXXX XXXXX
VOITURE 3 XXXXX XXXXX

Pour diverses raisons (passons) une macro supprime tous les sauts de page existant éventuellement puis sépare les blocs par des sauts de page. Ces ceux-là que je nomme les miens. Mais ces sauts de page crées par la macro ne sont pas nécessairement ceux qui délimitent la taille de la feuille à l'impression (A4 par exemple).

VOITURE 1 XXXXX XXXXX
VOITURE 1 XXXXX XXXXX
VOITURE 1 XXXXX XXXXX
------------------------------
VOITURE 2 XXXXX XXXXX
VOITURE 2 XXXXX XXXXX
------------------------------
VOITURE 3 XXXXX XXXXX
VOITURE 3 XXXXX XXXXX
..........................................
VOITURE 3 XXXXX XXXXX
------------------------------

Seulement, quand je lance la macro qui va se baser sur les sauts de page pour créer autant de feuilles que de sauts de page en nommant les onglets du nom VOITURE 1 etc, bin elle plante car elle m'indique que l'onglet VOITURE 1 existe déjà.

Donc je vais voir le numéro de ligne incriminé et là, paf, en plein milieu des lignes concernant VOITURE 1 je vois un saut de page ??? Je pense qu'il s'agît d'un saut de page délimitant la taille de la feuille pour l'impression qu'Excel ajout en dépit de tout. Du coup, forcément, la macro plante.

Une idée ?
11/06/2010, 15h28
Fvandermeulen

Peux tu mettre le code qui crée les "saut de page" ?

A mon avis, on peut se baser sur celui là pour directement copier les blocs sur les nouvelles feuilles.

A+

Voilà le mix entre ton code et ce que j'ai tenté :mouarf:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
Sub Test_WhileWend()
    Dim NbHPB As Long, R As Long, Rdeb As Long, Rfin As Long, NomFeuilleActive As String, i As Integer
 
    ActiveSheet.ResetAllPageBreaks
 
    i = 1
    'Sépare chaque bloc par un saut de page pour pouvoir ensuite les éclater en autant de feuilles
    Do
        'Boucle sur les cellules de la colonne C
        'On sort de la boucle si la cellule testée (Cells(i, 3)) est vide
        While Not IsEmpty(Cells(i, 3))
            'Incrémente la variable d'une unité afin de tester la cellule suivante
            i = i + 1
        Wend
        i = i + 1
        Cells(i, 1).Select
        'Insère un saut de page
        ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=ActiveCell
    Loop Until IsEmpty(Cells(i + 1, 1))
 
    ' Attribut à NomFeuilleActive le nom de l'onglet courant
    NomFeuilleActive = ActiveSheet.Name
 
    'Compte le nombre de saut de page dans l'onglet courant
    NbHPB = Sheets(NomFeuilleActive).HPageBreaks.Count
 
    'Si premier modèle en ligne 1, servira pour délimiter le début de plage à copier
    Rdeb = 1
 
    'Boucle sur chaque saut de page
    For R = 1 To NbHPB
        'Indique le numéro de ligne précédent le saut de page
        Rfin = Sheets(NomFeuilleActive).HPageBreaks(R).Location.Row - 1
 
        'Renomme la feuille ajoutée avec le contenu de la première cellule de la plage
        Sheets.Add.Name = Sheets(NomFeuilleActive).Cells(Rdeb, 1).Value
        Sheets(Sheets(NomFeuilleActive).Cells(Rdeb, 1).Value).Move After:=Sheets(Sheets.Count)
 
        'Copie la plage concernée sur la nouvelle feuille
        Sheets(NomFeuilleActive).Range(Sheets(NomFeuilleActive).Cells(Rdeb, 1), Sheets(NomFeuilleActive).Cells(Rfin, 256)).Copy Destination:=Range("a1")
 
        'Défini le début de plage suivant
        Rdeb = Rfin + 1
    'Passe au saut de page suivant
    Next R
 
End Sub