[Vim] mark ring

Version imprimable

18/05/2010, 23h32
Ekinoks

[Vim] mark ring

Salut,

Je cherche depuis pas mal de temps une fonctionnalité (ou un plug-in si cela n'existe pas par défaut) dans vim. Je ne trouve nulle part de solutions, vous éte ma dernière chance :p
Je cherche à faire un "mark ring" à la emacs, j'explique :
Quand on fait par exemple "C-SPC", on empile une marque de la position actuelle, et quand on fait "C-x C-SPC" on va à la position de la dernière marque ajoutée, et on la retire de la file.

J'ai presque trouvé une fonction vim qui fait ca (tagstack), mais cela ne marche que pour la navigation dans des fonctions taguées (le seul moyen de rajouter une position dans la pile est de sauter vers une fonction taguée).

Voyez vous une solution pour faire cela ?

Merci pour votre aide.

Cela ne doit pas être compliqué à implémenter.
Je ne serai pas surpris qu'un tel truc existe déjà, et avec plus de fonctionnalités comme montrer où se trouvent les marques, la possibilité de ne pas les retirer de la pile, etc.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
"=============================================================================
" $Id$
" File:         plugin/markring.vim                               {{{1
" Author:       Luc Hermitte <EMAIL:hermitte {at} free {dot} fr>
"		<URL:http://code.google.com/p/lh-vim/>
" Version:      0.0.1
" Created:      19th May 2010
" Last Update:  $Date$
"------------------------------------------------------------------------
" Description:
"       «description»
" 
"------------------------------------------------------------------------
" Installation:
"       Drop this file into {rtp}/plugin
"       Requires Vim7+
"       «install details»
" History:      «history»
" TODO:         «missing features»
" }}}1
"=============================================================================
 
" Avoid global reinclusion {{{1
let s:k_version = 001
if &cp || (exists("g:loaded_markring")
      \ && (g:loaded_markring >= s:k_version)
      \ && !exists('g:force_reload_markring'))
  finish
endif
let g:loaded_markring = s:k_version
let s:cpo_save=&cpo
set cpo&vim
" Avoid global reinclusion }}}1
"------------------------------------------------------------------------
" Commands and Mappings {{{1
 
nnoremap <silent> <Plug>PushMark :call <sid>PushMark()<cr>
if !hasmapto('<Plug>PushMark', '')
  nmap <silent> <c-space> <Plug>PushMark
endif
nnoremap <silent> <Plug>PopMark :call <sid>PopMark()<cr>
if !hasmapto('<Plug>PopMark', '')
  nmap <silent> <c-x><c-space> <Plug>PopMark
endif
 
" Commands and Mappings }}}1
"------------------------------------------------------------------------
" Functions {{{1
" Note: most functions are best placed into
" autoload/«your-initials»/«markring».vim
" Keep here only the functions are are required when the plugin is loaded,
" like functions that help building a vim-menu for this plugin.
 
let s:marks = []
 
function! s:PushMark() " {{{2
  let m = getpos('.')
  call add(s:marks, m)
  echo "mark pushed"
endfunction
 
function! s:PopMark() " {{{2
  if empty(s:marks) 
    throw "MarkRing: no mark left in the stack"
  endif
  let m = remove(s:marks, -1)
  call setpos('.', m)
endfunction
 
function! s:ClearRing() " {{{2
  let s:marks = []
endfunction
 
" Functions }}}1
"------------------------------------------------------------------------
let &cpo=s:cpo_save
"=============================================================================
" vim600: set fdm=marker:

19/05/2010, 19h32
Ekinoks

Whouahou !!! je suis impressionné !!
Je ne pensais pas que ça pouvait ce faire aussi facilement O_O

Ca ma convaincu d'apprendre le langage script de vim, je vais commencer par essayer de comprendre ce code là ^^

Un grand merci pour ton aide Luc :D
19/05/2010, 20h26
Ekinoks

Ah, en fait, apres utilisation il y a un problème dans la solution proposé :^/

En effet, si on met une marque à la ligne 100, et que l'on rajoute 10 ligne en début de fichier par exemple, la marque reste à la ligne 100 et ne ce déplace pas en ligne 110...
Les marks font ça automatiquement mais ils semble être limités en nombres et sont nominatives.

Vois-tu une solution pour prendre ce cas en compte ?

En effet. Je vois le problème.
Une autre solution serait à la place de travailler avec les 26 marques usuelles. Et de shifter au fur et à mesure.
Cette fois-ci, il faut jouer avec :exe+:normal
Code:

1 2 3 4 5 6 7 8 9 10 let s:crt_mark = 'a' ... " push let s:crt_mark =nr2char(char2nr(s:crt_mark)+1) " += 1 ne marche pas sur les caractères... :( " + penser au côté z + 1 = a exe ":normal! m".s:crt_mark " pop exe ":normal! '".s:crt_mark let s:crt_mark =nr2char(char2nr(s:crt_mark)-1)
Seulement, il y a beaucoup de plugins et autres macros qui trainent le net qui bidouillent les marques au lieu de les laisser tranquilles. Donc, tu aurais vite fait d'être parasité par l'extérieur.
Je ne peux que te conseiller de faire une recherche sur "mark" sur vim.org, ou sur vim.wikia.org. Ce que tu cherches me dit quelque chose.

PS: sinon, le Viml est un langage assez simple. Il faut juste savoir comment gérer les changements de modes et les formes nominales des fonctions en fonction des modes dans lesquels elles sont sensées pouvoir s'exécuter (cf le :exe+:normal), ou depuis quoi (commande, menu/map, abbr, ...).

20/05/2010, 10h54
frp31

tiens c'est pratique ça
merci du tuyau
20/05/2010, 21h04
Ekinoks

Yep, ca marche nickel comme ca :D
Quelque améliorations possible :
- remplacer 'a' par 'A' pour pouvoir se déplacer entre plusieurs fichiers
- remplacer ' par ` pour revenir à la position exacte ou l'on se trouvais

Encore merci pour ton aide Luc :D

PS : Whoula oui, la syntaxe est un peu plus complexe cette foi ci 8O
20/05/2010, 21h18
Ekinoks

Hum... J'ai une petite dernière question qui me viens à l'esprit :p
N'est il pas possible de rajouter nous même des marques dans le "tagstack" ?
Cela permettrait de corriger le petit défaut de risque "d'interférence" avec d'autre plugin, mais également de gérer dans une seule pille les marques de saut vers un etag et nos marques personnels.

Vois-tu un moyen de faire cela ?

OK. Peut-être alors en injectant vilainement des tags temporaires ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
let s:marks = []
if !exists('s:tags')
  let s:tags = tempname()
endif
 
let &tags .= ','.s:tags
 
function! s:UpdateTags()
  let lines = []
  let i = 0
  while i != len(s:marks)
    let l = 'MarkRing'.i."\t". (s:marks[i].file) .
	  \ "\t" . ':call setpos(".",'.(string(s:marks[i].pos)).')'
    call add(lines, l)
    let i += 1
  endwhile
  call writefile(lines, s:tags)
  " :exe 'sp '.s:tags
endfunction
 
function! s:PushMark() " {{{2
  let m = getpos('.')
  call add(s:marks, {'pos':m, 'file':expand('%:p')})
  call s:UpdateTags()
  exe 'tag MarkRing'.(len(s:marks)-1)
  echo "mark pushed"
endfunction
 
function! s:PopMark() " {{{2
  if empty(s:marks) 
    throw "MarkRing: no mark left in the stack"
  endif
  let m = remove(s:marks, -1)
  call s:UpdateTags()
  echo "mark poped"
  " pop!
  pop
endfunction
 
function! s:ClearRing() " {{{2
  let s:marks = []
  call s:UpdateTags()
endfunction

23/05/2010, 23h57
Ekinoks

Wouha !! ca marche incroyablement bien 8O !
peu être vilain mais très efficace, voila une fonctionnalité de plus dont je ne vais plus pouvoir me passer ^^

Un grand merci pour ton aide Luc :D
25/05/2010, 16h26
Luc Hermitte

Avec plaisir.

Il y a toutes fois un petit hic: Si tu ajoutes d'autres tags (par navigation), immanquablement, il va y avoir un problème de synchro entre le contenu du fichier et les :pop.
29/05/2010, 19h52
Ekinoks

Effectivment en utilisant PopMark il y a quelque conflits qui peuvent ce créer...
mais en utilisant à la place la commande pop mark par défaut (CTRL-t) cela corrige ce problème :D