Mise en forme d'une ListView

Bonjour,

Je voudrais savoir s'il est possible de mettre en forme le texte contenu dans une listView: afficher par exemple des tabulation parce que j'ai essayé mais ça ne marche pas.

Merci d'avance

Il faut utiliser CellFactory, je te met le code brut de fonderie

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
def configCellFactory: function ():javafx.scene.control.ListCell =
    function ():javafx.scene.control.ListCell {
        def cell: ListCell = ListCell { styleClass: "config-cell" }
        var offset = 5;
        var itemWidth = cell.listView.width;
        var name: String;
        var create: String;
        var modif: String;
        var comment: String;
        def dateFormat = DateFormat.getDateTimeInstance(DateFormat.MEDIUM, DateFormat.MEDIUM, Locale.FRANCE);
        def ci: ConfigInfo = bind cell.item as ConfigInfo on replace {
            if(ci != null) {
                name = StringEscapeUtils.unescapeXml(ci.getName());
                create = dateFormat.format(ci.getCreate());
                modif = dateFormat.format(ci.getLast());
                comment = StringEscapeUtils.unescapeXml(ci.getComment());
            }
        }
        def box = VBox {
            visible: bind not cell.empty
            spacing: offset
            content: [
                Label {
                    styleClass: "config-name-label"
                    hpos: HPos.CENTER
                    textAlignment: TextAlignment.CENTER
                    text: bind name
                }
                Label {
                    id: "create-label"
                    text: bind "Création: {create}"
                }
                Label {
                    id: "modif-label"
                    text: bind "Modification: {modif}"
                }
                HBox {
                    content: [
                        Label {
                            text: "Commentaire:"
                        }
                        Label {
                            id: "comment-label"
                            text: bind comment
                        }
                    ]
                }
            ]
        }
        cell.node = box;
        return cell;
    }

Mon NetBeans ne connait apparemment CellFactory :(.

J'imagine que c'est parce que je ne suis pas au JavaFx 1.3 mais 1.2.

Est ce que le portage du codage vers la 1.3 est compliqué? Est-ce que ça vaut vraiment le coup de s'y mettre?

Je rajoute juste une petite question au passage puisque je suis entrain de regarder un peu javaFX 1.3 avec Netbeans 6.9, comment on fait pour rajouter des trucs dans une scrollview?

Il faut absolument que tu passes à la 1.3