Copie de Range via une inputbo

Version imprimable

Bonjour à tous,

Tout d'abord je tiens à préciser que je suis débutant en Vba.

J'ai une question concernant une macro que j'ai crée. Le but de celle-ci est d'inviter l'utilisateur à sélectionner une plage de cellules et de copier cette plage de cellules dans une nouvelle feuille de calcul.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 Sub SelectionCellules() 'Sélection de la plage de cellules par l'utilisateur Dim maPlage As Range On Error Resume Next Set maPlage = Application.InputBox("Sélectionnez la plage de cellule à importer sous format doc ", Type:=8) On Error GoTo 0 If maPlage Is Nothing Then MsgBox "Sélection annulée" ' On copie la sélection Range(maPlage.Address).Copy ' Création d'une feuille de calcul temporaire Dim NouvelleFeuille As Worksheet Set NouvelleFeuille = ThisWorkbook.Worksheets.Add(before:=ThisWorkbook.Worksheets(1)) Worksheets(1).Name = "FeuilleTest" 'On colle la sélection dans la feuille de calcul temporaire Sheets("FeuilleTest").Activate Rows("1:1").Select Selection.PasteSpecial Paste:=xlPasteAll Application.CutCopyMode = xlCopy End Sub
Après plusieurs essais, je me suis aperçu que cette routine fonctionne correctement, uniquement quand l'utilisateur, lance la macro depuis la feuille dans laquelle les cellules à copier sont situées.

Je vous donne un exemple pour être sur d'être clair:

Imaginons que je veuille, sélectionner les cellules A1:G26, dans la feuille "Feuil3".
Si je lance la macro (Alt+F8) alors que je suis déjà dans la feuille "Feuil3", cela fonctionne.

En revanche, si je lance la macro depuis la feuille "Feuil2", les cellules copiées seront les cellules A1:G26 de la feuille "Feuil2" même si lorsque l'inputbox est lancée, l'utilisateur a bien sélectionné les cellules A1:G26 de la "Feuil3".

Comment dois-je m'y prendre pour que cette routine fonctionne quelque soit la feuille depuis laquelle elle est lancée.

Merci d'avance pour le temps que vous voudrez bien prendre pour traiter ma demande.

Cire190

bonjour Cire190 ,

active la feuil3 avant l'inputbox,

Code:

1
2
 Sheets("Feuil3").Activate
 Set maPlage = Application.InputBox("Sélectionnez la plage de cellule à importer sous format doc ", Type:=8)

Salut cire190 et le forum
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 Sub SelectionCellules() Dim maPlage As Range Dim NouvelleFeuille As Worksheet On Error Resume Next Set maPlage = Application.InputBox("Sélectionnez la plage de cellule à importer sous format doc ", Type:=8) On Error GoTo 0 If maPlage Is Nothing Then MsgBox "Sélection annulée" Exit sub end If ' On copie la sélection maPlage.Copy ' Création d'une feuille de calcul temporaire Set NouvelleFeuille = ThisWorkbook.Worksheets.Add(before:=ThisWorkbook.Worksheets(1)) Worksheets(1).Name = "FeuilleTest" 'On colle la sélection dans la feuille de calcul temporaire 'Sheets("FeuilleTest").Activate Rows("1:1").PasteSpecial Paste:=xlPasteAll Application.CutCopyMode = False End Sub
Macro complêtement changée, hein :D.

Quelques remarques en passant :
Il est préférable de regrouper toutes les déclarations en début de la macro : ça évite de rechercher dans le code où elles sont, ça ne change strictement rien à la macro, et le code en devient plus lisible. Regroupées, ça évite d'en oublier en cas de changements de type quand tu les modifies en cours de mise au point.

Quand tu crées une feuille, elle devient automatiquement la feuille active. Pas besoin de la sélectionner/activer, puisqu'elle l'est déjà.

"Application.CutCopyMode = False" ne sert qu'à supprimer les tirets clignotant qui indiquent que la sélection va servir dans une opération copier/couper.

Si tu ne détermines pas de plage, tu préviens l'utilisateur : ça c'est bien. Mais si tu ne veux pas qu'Excel se fâche, avertis-le qu'il faut qu'il arrête la macro, sous peine d'un violent message d'erreur :mrgreen:.

Tu te garantis de pouvoir sélectionner une plage, dont tu n'utilises que l'adresse => ce ne sont pas les cellules déterminées qui sont copiées, mais celles ayant la même adresse, de la feuille active au moment du lancement de la macro qui sont copiées. Donc, utilise directement le range.

Dans le même odre d'idée, Plage.Select puis Selection.Action n'est souvent que générateur de problèmes. Plage.Action est nettement mieux (pour la plupart des cas).

Tu copies sur une ligne. Comme je ne connais pas les besoins, je ne peux proposer de solution, mais le xlPasteAll ne gène dans ce cas. Je mettrais plutot un xlValue.
A+

26/04/2010, 11h13
cire190

Bonjour,

Merci sabzzz et Gorfael pour vos réponses et vos conseils concernant ma routine.

Citation:

Tu te garantis de pouvoir sélectionner une plage, dont tu n'utilises que l'adresse => ce ne sont pas les cellules déterminées qui sont copiées, mais celles ayant la même adresse, de la feuille active au moment du lancement de la macro qui sont copiées. Donc, utilise directement le range.

En effet, c'est bien ici que j'avais un problème, je ne copiais que les cellules de la feuille active et non pas les cellules sélectionnées par l'utilisateur. En passant par:

Code:

maPlage.Copy

Cela a résolu le problème.

Concernant le collage: je souhaite conserver la mise en forme, c'est pour cela que j'ai mis XlPasteAll.

Merci encore.

A bientôt

Cire190