Déplacer, réduire, fermer une fenêtre sans bordure

Version imprimable

15/04/2010, 09h59
Stefounette

Déplacer, réduire, fermer une fenêtre sans bordure

Bonjour,

Alors voilà je voudrais améliorer l'apparence de mes fenêtres en javaFx.

Je voudrais réaliser une fenêtre sans bordure donc ca je sais faire c'est avec

Code:

StageStyle.UNDECORATED

mais je voudrais quand même que l'on puisse la déplacer sur l'écran de l'ordinateur, la fermer et la réduire.

Comment puis je faire?

Donc effectivement quand il n'y a pas de barre de menu il faut faire les choses à la main et creer un zone et scroll pour la déplacer et un bouton pour fermer.
donc pour fermer c'est stage.close() et pour la déplacer utiliser l'évènement onMouseDragged.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
 
package main;
 
import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.stage.StageStyle;
import javafx.scene.shape.Rectangle;
import javafx.scene.input.MouseEvent;
import javafx.scene.control.Button;
import javafx.scene.paint.Color;
import javafx.scene.control.Label;
import javafx.scene.Cursor;
 
/**
 * @author Alex
 */
var sx: Number = 0;
var sy: Number = 0;
var text: String = "POSITION";
def stage: Stage = Stage {
    style: StageStyle.UNDECORATED
    scene: Scene {
        fill: Color.GRAY
        width: 300
        height: 200
        content: [
            Rectangle {
                width: 300 height: 40 cursor: Cursor.MOVE
                onMousePressed: function (e: MouseEvent): Void {
                    sx = e.screenX - stage.x;
                    sy = e.screenY - stage.y;
                }
                onMouseDragged: function (e: MouseEvent): Void {
                    stage.x = e.screenX - sx;
                    stage.y = e.screenY - sy;
                    text = "Position [{stage.x}, {stage.y}]"
                }
            }
            Button {
                translateX: 220 translateY: 10
                text: "Fermer"
                action: function(): Void {
                    stage.close();
                }
            }
            Label {
                width: 200
                translateX: 50
                translateY: 50
                textFill: Color.WHITE
                text: bind text;
            }
        ]
    }
}

Enfait, j'ai du mal à utiliser ton exemple car mon code est un peu particulier j'utilise le designer de netbeans pour m'aider dans la création de mes interfaces.

Donc en fait mon code se présente comme ceci:

J'ai la classe ci-desoous:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
package test2;
 
import javafx.scene.input.MouseEvent;
 
public class Main {
 
    public var sceneModif:javafx.scene.Scene;
    public-read var sx: Number;
    public-read var sy: Number;
    public-read var rectangle: javafx.scene.shape.Rectangle;
    public-read var panel: javafx.scene.layout.Panel;
    public-read var scene: javafx.scene.Scene;
 
    public-read var currentState: org.netbeans.javafx.design.DesignState;
 
    // <editor-fold defaultstate="collapsed" desc="Generated Init Block">
    init {
        rectangle = javafx.scene.shape.Rectangle {
            layoutX: 2.0
            layoutY: 2.0
            onMouseDragged: rectangleOnMouseDragged
            onMousePressed: rectangleOnMousePressed
            width: 300.0
            height: 20.0
        };
        panel = javafx.scene.layout.Panel {
            layoutX: 0.0
            layoutY: 0.0
            width: 300.0
            height: 320.0
            layoutInfo: javafx.scene.layout.LayoutInfo {
                width: bind panel.width
                height: bind panel.height
            }
            content: [ rectangle, ]
        };
        scene = javafx.scene.Scene {
            width: 300.0
            height: 320.0
            content: javafx.scene.layout.Panel {
                content: getDesignRootNodes ()
            }
        };
 
        currentState = org.netbeans.javafx.design.DesignState {
            names: [ ]
            stateChangeType: org.netbeans.javafx.design.DesignStateChangeType.PAUSE_AND_PLAY_FROM_START
            createTimeline: function (actual) {
                null
            }
        }
    }// </editor-fold>
 
    // <editor-fold defaultstate="collapsed" desc="Generated Design Functions">
    public function getDesignRootNodes () : javafx.scene.Node[] {
        [ panel, ]
    }
 
    public function getDesignScene (): javafx.scene.Scene {
        scene
    }// </editor-fold>
 
    function rectangleOnMouseDragged(event: javafx.scene.input.MouseEvent): Void {
        stage.x = event.screenX - sx;
        stage.y = event.screenY - sy;
 
            }
 
    function rectangleOnMousePressed(event: javafx.scene.input.MouseEvent): Void {
        sx = event.screenX - stage.x;
        sy = event.screenY - stage.y;
 
 
            }
 
}

Et dans un autre fichier j'ai ceci:

Code:

1
2
3
4
5
6
7
8
package test2;
 
var design = Main {}
 
javafx.stage.Stage {
    title: "Main"
    scene: design.getDesignScene ()
}

Ce qui fait que je ne pas créer de variable stage que je pourrait utiliser et modifier dans ma classe Main lors du déplacement avec la souris.

Donc comment est-ce que je pourrais faire dans mon cas?

Merci d'avance

Avant ton dernier Post j'ai un petit exemple de généralisation.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
 
public class FrameHandler {
 
    public-init var moveBar: Node;
    public-init var btnClose: Button;
    public-init var nodeClose: Node;
 
    var stage: Stage;
    var sx: Number = 0;
    var sy: Number = 0;
 
    function close(): Void {
        stage.close();
    }
    init {
        stage = moveBar.scene.stage;
        moveBar.onMousePressed = function (e: MouseEvent): Void {
            sx = e.screenX - stage.x;
            sy = e.screenY - stage.y;
        };
        moveBar.onMouseDragged = function (e: MouseEvent): Void {
            stage.x = e.screenX - sx;
            stage.y = e.screenY - sy;
        }
        if(nodeClose != null) {
            nodeClose.onMousePressed = function (e: MouseEvent): Void { close() };
        } else if(btnClose != null) {
            btnClose.action = function(): Void { close() }
        }
    }
}
 
function run() {
    var bar1: Node;
    var bar2: Node;
    var nodeClose: Node;
    var btnClose: Button;
 
    Stage {
        style: StageStyle.UNDECORATED
        scene: Scene {
            fill: Color.GRAY
            width: 300
            height: 200
            content: [
                bar1 = Rectangle {
                    width: 300 height: 40 cursor: Cursor.MOVE
                }
                btnClose = Button {
                    translateX: 260 translateY: 10
                    text: "X"
                    font: Font.font("Tahoma bold", 14)
                }
            ]
        }
    }
    Stage {
        style: StageStyle.UNDECORATED
        scene: Scene {
            fill: Color.GRAY
            width: 300
            height: 200
            content: [
                bar2 = Rectangle {
                    width: 300 height: 40 cursor: Cursor.MOVE
                }
                nodeClose = Rectangle {
                    x: 270 y: 10 width: 20 height: 20 cursor: Cursor.HAND fill: Color.RED
                }
            ]
        }
    }
    FrameHandler {
        moveBar: bar1
        btnClose: btnClose;
    }
    FrameHandler {
        moveBar: bar2
        nodeClose: nodeClose;
    }
}

Dans ton cas il faut que tu crée les deux objets qui te permettrons de déplacer et fermer la fenetre, disont un Button "btnClose" et un Rectangle "barRect"
Ensuite tu peut lancer ton appli tel que
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 package test2; var design = Main {} Stage { title: "Main" scene: design.getDesignScene () } FrameHandler { moveBar: design.barRect btnClose: design.btnClose; }

15/04/2010, 15h58
Stefounette

OK, Merci beaucoup beaucoup pour ton aide ! :D

Ça marche du feu de Dieu et j'ai réussis à faire ce que je voulais :D!
15/04/2010, 19h34
galien

deeeeeeeeeeeeeeeuuuuuuuux rien