Jour de la semaine dans un script

Version imprimable

02/03/2010, 20h11
Yannick30

Jour de la semaine dans un script

Bonjour,

Je m'interroge à savoir s'il est possible, dans un script batch, d'y inclure des jours de la semaine.

Exemple : Je veux que chaque dimanche le script fasse QQCH...

etc.. pour les autres jours de la semaine.

Mais tout ça, dans un seul script. Est-ce possible ?

Merci
03/03/2010, 09h15
Acris

Bonjour

peut être voir ces sujets :
http://www.developpez.net/forums/d51...-jour-semaine/

http://support.microsoft.com/kb/461799/fr
03/03/2010, 10h14
Flamby38

Sinon, si ton cas s'y prete, il y a toujours la possibilité de faire des taches planifiées et de lancer des scripts différents chaque jour de la semaine, ca a le merite d'etre simple a faire.

En fait, avec les extensions de commande, tu ne peux hélas PAS déterminer comme ça le jour courant...

Petite illustration :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off
setlocal enableextensions
echo With extensions:
REM Habituellement remplacé par "date /t", qui évite d'avoir à découper le résultat...
echo. > __dummy__
date < __dummy__ > __dummy2__
type __dummy2__
del /q __dummy__ __dummy2__ > NUL
echo.
endlocal

setlocal disableextensions
echo No extensions:
echo. > __dummy__
date < __dummy__ > __dummy2__
type __dummy2__
del /q __dummy__ __dummy2__ > NUL
echo.
endlocal

Le résultat de la commande donne ceci :

Code:

1
2
3
4
5
6
7
With extensions:
La date du jour est : 03/03/2010
Entrez la nouvelle date : (jj-mm-aa)

No extensions:
La date du jour est : mer. 03/03/2010
Entrez la nouvelle date : (jj-mm-aa)

Notez la partie en rouge.

Donc, pour récupérer la date courante, tu peux tester ce batch :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
@echo off
setlocal enableextensions enabledelayedexpansion

call :getcurrentday JOUR
echo Nous sommes le jour !JOUR! de la semaine.
goto :eof

REM Paramètre %1 : ***NOM*** de la variable qui va recevoir le jour de la semaine.
REM Retour : jour numérique de la semaine, Lundi=1, Mardi=2, ... Dimanche=7.
:getcurrentday
if @%1==@ (
	echo :getcurrentday =^> missing parameter.
	goto :eof
)
set gcd_tmp=__dummy__
REM Bloc sans extensions de commandes.
	setlocal disableextensions
	echo. > %gcd_tmp%2
	date < %gcd_tmp%2 > %gcd_tmp%
	endlocal
REM Filtrage du résultat.
for /f "usebackq tokens=1,* delims=:" %%I in (`type %gcd_tmp% ^| find "%DATE%"`) do (
	set gcd_date=%%J
)
del /q %gcd_tmp% %gcd_tmp%2 > NUL
REM Découpe du jour de la semaine, on garde 3 lettres uniquement.
for /f "usebackq tokens=1" %%I in (`echo %gcd_date%`) do (
	set gcd_day=%%I
	set gcd_day=!gcd_day:.=!
	set gcd_day=!gcd_day:~0,3!
)
REM Analyse du jour (français/anglais).
if /i !gcd_day! EQU lun set /a %1=1
if /i !gcd_day! EQU mon set /a %1=1
if /i !gcd_day! EQU mar set /a %1=2
if /i !gcd_day! EQU tue set /a %1=2
if /i !gcd_day! EQU mer set /a %1=3
if /i !gcd_day! EQU wed set /a %1=3
if /i !gcd_day! EQU jeu set /a %1=4
if /i !gcd_day! EQU thu set /a %1=4
if /i !gcd_day! EQU ven set /a %1=5
if /i !gcd_day! EQU fri set /a %1=5
if /i !gcd_day! EQU sam set /a %1=6
if /i !gcd_day! EQU sat set /a %1=6
if /i !gcd_day! EQU dim set /a %1=7
if /i !gcd_day! EQU sun set /a %1=7
set gcd_tmp=
set gcd_date=
set gcd_day=
goto :eof

Tu peux directement copier/coller le sous-programme ":getcurrentday" dans ton propre batch, et regarde l'exemple d'utilisation au début.
Attention, il te FAUT ajouter le "setlocal" initial (ligne 2), tel quel, sinon cela ne marchera pas.

Citation:

Envoyé par Mac LAK

En fait, avec les extensions de commande, tu ne peux hélas PAS déterminer comme ça le jour courant...

Petite illustration :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off
setlocal enableextensions
echo With extensions:
REM Habituellement remplacé par "date /t", qui évite d'avoir à découper le résultat...
echo. > __dummy__
date < __dummy__ > __dummy2__
type __dummy2__
del /q __dummy__ __dummy2__ > NUL
echo.
endlocal

setlocal disableextensions
echo No extensions:
echo. > __dummy__
date < __dummy__ > __dummy2__
type __dummy2__
del /q __dummy__ __dummy2__ > NUL
echo.
endlocal

Le résultat de la commande donne ceci :

Code:

1
2
3
4
5
6
7
With extensions:
La date du jour est : 03/03/2010
Entrez la nouvelle date : (jj-mm-aa)

No extensions:
La date du jour est : mer. 03/03/2010
Entrez la nouvelle date : (jj-mm-aa)

Notez la partie en rouge.

Donc, pour récupérer la date courante, tu peux tester ce batch :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
@echo off
setlocal enableextensions enabledelayedexpansion

call :getcurrentday JOUR
echo Nous sommes le jour !JOUR! de la semaine.
goto :eof

REM Paramètre %1 : ***NOM*** de la variable qui va recevoir le jour de la semaine.
REM Retour : jour numérique de la semaine, Lundi=1, Mardi=2, ... Dimanche=7.
:getcurrentday
if @%1==@ (
	echo :getcurrentday =^> missing parameter.
	goto :eof
)
set gcd_tmp=__dummy__
REM Bloc sans extensions de commandes.
	setlocal disableextensions
	echo. > %gcd_tmp%2
	date < %gcd_tmp%2 > %gcd_tmp%
	endlocal
REM Filtrage du résultat.
for /f "usebackq tokens=1,* delims=:" %%I in (`type %gcd_tmp% ^| find "%DATE%"`) do (
	set gcd_date=%%J
)
del /q %gcd_tmp% %gcd_tmp%2 > NUL
REM Découpe du jour de la semaine, on garde 3 lettres uniquement.
for /f "usebackq tokens=1" %%I in (`echo %gcd_date%`) do (
	set gcd_day=%%I
	set gcd_day=!gcd_day:.=!
	set gcd_day=!gcd_day:~0,3!
)
REM Analyse du jour (français/anglais).
if /i !gcd_day! EQU lun set /a %1=1
if /i !gcd_day! EQU mon set /a %1=1
if /i !gcd_day! EQU mar set /a %1=2
if /i !gcd_day! EQU tue set /a %1=2
if /i !gcd_day! EQU mer set /a %1=3
if /i !gcd_day! EQU wed set /a %1=3
if /i !gcd_day! EQU jeu set /a %1=4
if /i !gcd_day! EQU thu set /a %1=4
if /i !gcd_day! EQU ven set /a %1=5
if /i !gcd_day! EQU fri set /a %1=5
if /i !gcd_day! EQU sam set /a %1=6
if /i !gcd_day! EQU sat set /a %1=6
if /i !gcd_day! EQU dim set /a %1=7
if /i !gcd_day! EQU sun set /a %1=7
set gcd_tmp=
set gcd_date=
set gcd_day=
goto :eof

salut,

très bonne astuce Mac LAK, ça permettera de ne plus utiliser des algo mathématiques ou passer par VBS

tu peux la simplifier comme ceci:

Code:

for /f "tokens=2 delims=:." %%o in ('"<nul (cmd /e:off /cdate | find "/")"') do echo %%o

Citation:

Envoyé par I'm_HERE

très bonne astuce Mac LAK, ça permettera de ne plus utiliser des algo mathématiques ou passer par VBS

Merci. Et en plus, c'est une différence de comportement entre avec et sans extensions que je ne connaissais pas : je pensais que la seule différence de la commande date était le paramètre "/T".

Citation:

Envoyé par I'm_HERE

tu peux la simplifier comme ceci:

Effectivement, je n'avais pas pensé à utiliser un shell secondaire. J'en ai profité pour blinder un peu plus la commande (utilisation de %COMSPEC% et recherche par la date courante, ce qui renforcera une exécution correcte). J'en ai profité pour rajouter une gestion d'erreur primaire (cf. exemple), qui retournera la chaîne de trois lettres obtenue par découpage au lieu d'un code numérique en cas d'erreur (support des langues autres que français / anglais).

Du coup, voilà le code simplifié correspondant :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 @echo off setlocal enableextensions enabledelayedexpansion call :getcurrentday JOUR if %ERRORLEVEL% EQU 0 ( echo Nous sommes le jour !JOUR! de la semaine. ) else ( echo Impossible d'obtenir le jour de la semaine ^(obtenu : !JOUR!^). ) goto :eof REM Paramètre %1 : ***NOM*** de la variable qui va recevoir le jour de la semaine. REM Retour : jour numérique de la semaine, Lundi=1, Mardi=2, ... Dimanche=7. REM Si -1 : erreur de traitement. :getcurrentday if @%1==@ ( echo :getcurrentday =^> missing parameter. goto :eof ) for /f "usebackq tokens=2 delims=:." %%I in (`echo. ^| (%COMSPEC% /e:off /v:off /c date ^| find "%DATE%"^)`) do ( set gcd_day=%%I set gcd_day=!gcd_day: =! ) REM Analyse du jour (français/anglais). set /a %1=-1 if /i !gcd_day! EQU lun set /a %1=1 if /i !gcd_day! EQU mon set /a %1=1 if /i !gcd_day! EQU mar set /a %1=2 if /i !gcd_day! EQU tue set /a %1=2 if /i !gcd_day! EQU mer set /a %1=3 if /i !gcd_day! EQU wed set /a %1=3 if /i !gcd_day! EQU jeu set /a %1=4 if /i !gcd_day! EQU thu set /a %1=4 if /i !gcd_day! EQU ven set /a %1=5 if /i !gcd_day! EQU fri set /a %1=5 if /i !gcd_day! EQU sam set /a %1=6 if /i !gcd_day! EQU sat set /a %1=6 if /i !gcd_day! EQU dim set /a %1=7 if /i !gcd_day! EQU sun set /a %1=7 if !%1! LEQ 0 ( set %1=!gcd_day! set gcd_day= exit /B 1 ) set gcd_day= exit /B 0 goto :eof

Citation:
Envoyé par Mac LAK
Merci. Et en plus, c'est une différence de comportement entre avec et sans extensions que je ne connaissais pas : je pensais que la seule différence de la commande date était le paramètre "/T".

Effectivement, je n'avais pas pensé à utiliser un shell secondaire. J'en ai profité pour blinder un peu plus la commande (utilisation de %COMSPEC% et recherche par la date courante, ce qui renforcera une exécution correcte). J'en ai profité pour rajouter une gestion d'erreur primaire (cf. exemple), qui retournera la chaîne de trois lettres obtenue par découpage au lieu d'un code numérique en cas d'erreur (support des langues autres que français / anglais).

Du coup, voilà le code simplifié correspondant :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 @echo off setlocal enableextensions enabledelayedexpansion call :getcurrentday JOUR if %ERRORLEVEL% EQU 0 ( echo Nous sommes le jour !JOUR! de la semaine. ) else ( echo Impossible d'obtenir le jour de la semaine ^(obtenu : !JOUR!^). ) goto :eof REM Paramètre %1 : ***NOM*** de la variable qui va recevoir le jour de la semaine. REM Retour : jour numérique de la semaine, Lundi=1, Mardi=2, ... Dimanche=7. REM Si -1 : erreur de traitement. :getcurrentday if @%1==@ ( echo :getcurrentday =^> missing parameter. goto :eof ) for /f "usebackq tokens=2 delims=:." %%I in (`echo. ^| (%COMSPEC% /e:off /v:off /c date ^| find "%DATE%"^)`) do ( set gcd_day=%%I set gcd_day=!gcd_day: =! ) REM Analyse du jour (français/anglais). set /a %1=-1 if /i !gcd_day! EQU lun set /a %1=1 if /i !gcd_day! EQU mon set /a %1=1 if /i !gcd_day! EQU mar set /a %1=2 if /i !gcd_day! EQU tue set /a %1=2 if /i !gcd_day! EQU mer set /a %1=3 if /i !gcd_day! EQU wed set /a %1=3 if /i !gcd_day! EQU jeu set /a %1=4 if /i !gcd_day! EQU thu set /a %1=4 if /i !gcd_day! EQU ven set /a %1=5 if /i !gcd_day! EQU fri set /a %1=5 if /i !gcd_day! EQU sam set /a %1=6 if /i !gcd_day! EQU sat set /a %1=6 if /i !gcd_day! EQU dim set /a %1=7 if /i !gcd_day! EQU sun set /a %1=7 if !%1! LEQ 0 ( set %1=!gcd_day! set gcd_day= exit /B 1 ) set gcd_day= exit /B 0 goto :eof
merci Mac LAK de ton partage,

sinon, on peux aussi utiliser WMIC:

Code:

for /f "Skip=1 Tokens=*" %%o in ('wmic path win32_localtime get dayofweek') Do echo DOW=%%o

Citation:

Envoyé par I'm_HERE

sinon, on peux aussi utiliser WMIC:

Hélas, non ! WMI n'est pas supporté sur toutes les plate-formes, notamment, si je me souviens bien, sur les éditions familiales de Windows... :cry:

EDIT : Bien que l'on pourrait faire un code adaptatif à ce niveau, en fonction de la présence / absence / échec de la commande WMI...

EDIT 2 : Allez, le v'là, tiens, je dois dire que ce problème m'amuse beaucoup... :mrgreen:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
@echo off
setlocal enableextensions enabledelayedexpansion

call :getcurrentday JOUR
if %ERRORLEVEL% EQU 0 (
	echo Nous sommes le jour !JOUR! de la semaine.
) else (
	echo Impossible d'obtenir le jour de la semaine ^(obtenu : !JOUR!^).
)
goto :eof

REM Paramètre %1 : ***NOM*** de la variable qui va recevoir le jour de la semaine.
REM Retour : jour numérique de la semaine, Lundi=1, Mardi=2, ... Dimanche=7.
REM Si -1 : erreur de traitement.
:getcurrentday
if @%1==@ (
	echo :getcurrentday =^> missing parameter.
	goto :eof
)
REM Test WMI en premier lieu. Indépendant de la langue de l'OS.
for /f "usebackq skip=1 tokens=*" %%I in (`wmic path win32_localtime get dayofweek 2^>^&1`) do (
	set gcd_day=%%I
	set gcd_day=!gcd_day:~0,1!
	if !gcd_day! GEQ 1 (
		if !gcd_day! LEQ 7 (
			REM OK, trouvé => on s'en va.
			set %1=!gcd_day!
			goto :getcurrentdayexit
		)
	)
)
REM Si on est ici : pas de WMI => on tente la méthode brutale.
for /f "usebackq tokens=2 delims=:." %%I in (`echo. ^| (%COMSPEC% /e:off /v:off /c date ^| find "%DATE%"^)`) do (
	set gcd_day=%%I
	set gcd_day=!gcd_day: =!
)
REM Analyse du jour (français/anglais).
set /a %1=-1
if /i !gcd_day! EQU lun set /a %1=1
if /i !gcd_day! EQU mon set /a %1=1
if /i !gcd_day! EQU mar set /a %1=2
if /i !gcd_day! EQU tue set /a %1=2
if /i !gcd_day! EQU mer set /a %1=3
if /i !gcd_day! EQU wed set /a %1=3
if /i !gcd_day! EQU jeu set /a %1=4
if /i !gcd_day! EQU thu set /a %1=4
if /i !gcd_day! EQU ven set /a %1=5
if /i !gcd_day! EQU fri set /a %1=5
if /i !gcd_day! EQU sam set /a %1=6
if /i !gcd_day! EQU sat set /a %1=6
if /i !gcd_day! EQU dim set /a %1=7
if /i !gcd_day! EQU sun set /a %1=7
if !%1! LEQ 0 (
	set %1=!gcd_day!
	set gcd_day=
	exit /B 1
)
:getcurrentdayexit
set gcd_day=
exit /B 0
goto :eof

04/03/2010, 16h46
I'm_HERE

Citation:

Envoyé par Mac LAK

Hélas, non ! WMI n'est pas supporté sur toutes les plate-formes, notamment, si je me souviens bien, sur les éditions familiales de Windows... :cry:

c'est dommage pour les xp home , j'avais fais quelques script avec WMIC et je peux te dire que ça m'a impressionner.. espèrant qu'il sera stable dans les prochaines versions
05/03/2010, 10h33
Acris

Citation:

Envoyé par I'm_HERE

c'est dommage pour les xp home , j'avais fais quelques script avec WMIC et je peux te dire que ça m'a impressionner.. espèrant qu'il sera stable dans les prochaines versions

Moi de même, j'utilise wmic en batch et sous Home impossible.
Du coup, j'ai refais tout mon programme en utilisant du VBS.

Merci Mac LAK pour le code