Modifier fonction : audit configuration DNs sur carte réseau

Version imprimable

Bonjour,

J'ai cette fonction qui me permet d'auditer les configuration DNS d'une ou des carte(s) réseaux présent sur un PC :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
' ############ Sous fonction pour auditer la configuration DNS du poste distant ############
Sub Showdns(strServer)
	strWinMgmt = "winmgmts:{impersonationLevel=impersonate}!//"& strServer &""
	Set objNICs = GetObject( strWinMgmt ).InstancesOf( "Win32_NetworkAdapterConfiguration" )
 
	WScript.echo "Hostname : " & strServer & vbCrlf
	For Each objNIC In objNICs
		If objNIC.IPEnabled Then
			WScript.echo "  - " & objNIC.Description & " : " & vbCrlf & "    "
	        	n = 1
			For Each strDns In objNIC.DNSServerSearchOrder 
				WScript.echo vbTab & "DNS n°" & n & " : " & strDns & " "
				n = n + 1
			Next
			WScript.echo vbCrlf
		End If
	Next
End Sub

J'aimerai pouvoir filtrer les types de cartes réseau remonter (comme exclure des cartes VMware, des cartes FIREWIRE, etc..)

J'ai trouve des requette WMI de ce type pour exclure :

Code:

1
2
Set objWMI_NETwork = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
		Set collection_Network = objWMI_NETwork.ExecQuery("Select * from Win32_NetworkAdapter where AdapterType=""Ethernet 802.3"" and ServiceName<>""VMnetAdapter"" ")

mais je ne sais comment modifier ma fonction en conséquence.

Merci pour votre aide.

Arnaud

Salut.

Pour que tes informations concordent, tu peux utiliser l'attribut Caption, qui est le même dans les 2 objets WMI que tu utilises : Win32_NetworkAdapterConfiguration et Win32_NetworkAdapter

Ce que tu peux donc faire, c'est une requête pour trouver le Caption de tes cartes réseau <> VMWare et utiliser ce résultat pour récupérer la config DNS de ces cartes :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
strComputer = "."
Set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set collection_Network = objWMI.ExecQuery("Select Caption from Win32_NetworkAdapter where AdapterType=""Ethernet 802.3"" and ServiceName<>""VMnetAdapter"" ")
strResult = ""
For each objNetworkCard In collection_Network
	Set collection_Nics = objWMI.ExecQuery("Select * from Win32_NetworkAdapterConfiguration where Caption=""" & objNetworkCard.Caption & """")
	For each objNIC In collection_Nics
		If NOT (IsNull(objNIC.DNSServerSearchOrder) OR IsEmpty(objNIC.DNSServerSearchOrder)) Then
			strResult = strResult & "  - " & objNIC.Description & " : " & vbCrlf & "    "
			n = 1
			For Each strDns In objNIC.DNSServerSearchOrder 
				strResult = strResult & vbTab & "DNS n°" & n & " : " & strDns & " "
				n = n + 1
			Next
			strResult = strResult & vbCrlf
		End If
	Next
Next
 
WScript.echo strResult

(Bon en fait, vu que ça m'intéressait je l'ai fait...)

04/03/2010, 16h32
arnaudperfect

ok merci, je vais testé ceci.

après j'ai une autre fonction a faire pour modifier les DNS 1 et 2 suivant la carte réseau que je souhaite.