TextBox à un autre avec la touche "enter"

Version imprimable

Bonjour,
Je désire utiliser la touche "enter" au lieux de la touche tab pour passer d'un TextBox à l'autre, comment éléminer le "beep sonore",? voici mon code qui fontionne bien à part le "beep"
Code:

1 2 3 4 5 6 Private Sub TextBox1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles TextBox1.KeyDown If e.KeyCode = Keys.Enter Then TextBox2.Select() End If End Sub
Dans vb je faisais dans keyPress

Code:

If KeyAscii = 13 Then KeyAscii = 0

Mais ici je cale :oops:

Merci à vous
vb

Bonjour,

C'est Focus() à utiliser plutot que Select() je pense.

Code:

1
2
3
4
5
6
7
Private Sub TextBox1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles TextBox1.KeyDown
 
        If e.KeyCode = Keys.Enter Then
            TextBox2.Focus()
        End If
    End Sub

22/02/2010, 16h03
vb

Bonjour,
J'ai essayé

Code:

TextBox2.Focus()

Le beep est toujours là
vb

Effectivement le beep est toujours la :(

Pour contrer ce problème j'ai opté pour une prefiltrage des messages Windows :
Je l'ai codé en C# mais je te livre la chose traduite (j'espère correctement) en VB.NET :

Petite classe de prétraitement des messages

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
Public Class MyMessageFilter 
    Implements IMessageFilter 
Private _Form As Form 
    Public Property Form() As Form 
        Get 
            Return _Form 
        End Get 
        Private Set(ByVal value As Form) 
            _Form = value 
        End Set 
    End Property 
 
    Public Sub New(ByVal form As Form) 
        Me.Form = form 
    End Sub 
 
    Public Function PreFilterMessage(ByRef m As Message) As Boolean 
        If Me.Form IsNot Nothing AndAlso Me.Form.ActiveControl IsNot Nothing Then 
            If m.Msg = 256 Then 
                ' code d'une touche appuyé 
                If m.WParam.ToInt32() = 13 Then 
                    Dim textbox As TextBox = TryCast(Form.ActiveControl, TextBox) 
 
                    If textbox IsNot Nothing AndAlso (textbox.Multiline = False OrElse (textbox.Multiline = True AndAlso textbox.AcceptsReturn = False)) Then 
                        ' va chercher le prochain control 
                        Dim nextControl As Control = Form.GetNextControl(textbox, True) 
 
                        If nextControl IsNot Nothing Then 
                            nextControl.Focus() 
                        End If 
 
                        Return True 
                    End If 
                End If 
            End If 
        End If 
 
        Return False 
    End Function 
End Class

Dans la Form :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
' La form sur laquelle on travaille 
 
Public Partial Class Form1 
    Inherits Form 
    Private filter As MyMessageFilter 
 
    ''' <summary> 
    ''' Constructeur 
    ''' </summary> 
 
    Public Sub New() 
        InitializeComponent() 
 
 
        filter = New MyMessageFilter(Me) 
        Application.AddMessageFilter(filter) 
 
        AddHandler Me.Load, AddressOf Form1_Load 
    End Sub 
 
    Protected Overloads Overrides Sub OnClosed(ByVal e As EventArgs) 
        Application.RemoveMessageFilter(filter) 
        MyBase.OnClosed(e) 
    End Sub 
End Class

La touche enter ne Beep plus et se comporte comme une tabulation.
Ca ne prend en compte que les textboxs (mais pas les multilignes sauf celle n'acceptant pas le caractères Return).
Cela s'applique a toute les textboxs de ta Form.

22/02/2010, 18h10
vb

Bonjour,
Merci pour votre code
J'ai juste deux petits message d'erreur
Je crée une classe selon votre premier code
juste sur -->IMessageFilter
vb.net me dis

Citation:

MyMessageFilter doit implémenter'Function PreFiterMessage'ByRef m as message) as Boolean'pour l'interface System.Windows.Forms.IMessageFilter'

Dans le deuxième code après Form1_Load VB.net me dis que

Citation:

Form1_Load n'est pas déclaré.

Les classes et moi je suis un peu perdu dans ce domaine:?
Merci de me donner autant d'attention.
vb
22/02/2010, 19h23
Samuel Blanchard

Citation:

J'ai juste deux petits message d'erreur
Je crée une classe selon votre premier code
juste sur -->IMessageFilter
vb.net me dis MyMessageFilter doit implémenter'Function PreFiterMessage'ByRef m as message) as Boolean'pour l'interface System.Windows.Forms.IMessageFilter'

Désolé je ne vois pas... Il y aurait une star de VB.NET qui pourrait te répondre ?

Citation:

Dans le deuxième code après Form1_Load VB.net me dis que Form1_Load n'est pas déclaré.

Le deuxième code est à placer dans ta Form. Form1 est un exemple que j'ai pris. Ta Form doit surement avoir un autre nom.

Voilà code modifié, en parlant d'un formulaire nommé Form1

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
 
Public Class Form1
 
    Private _Filter As MyMessageFilter
 
    Public Sub New()
        ' Cet appel est requis par le Concepteur Windows Form.
        InitializeComponent()
        ' Ajoutez une initialisation quelconque après l'appel InitializeComponent().
 
        _Filter = New MyMessageFilter(Me)
        Application.AddMessageFilter(_Filter)
    End Sub
 
    Protected Overloads Overrides Sub OnClosed(ByVal e As EventArgs)
        Application.RemoveMessageFilter(_Filter)
        MyBase.OnClosed(e)
    End Sub
 
End Class
 
Public Class MyMessageFilter
    Implements IMessageFilter
 
    Private _Form As Form
    Public Property Form() As Form
        Get
            Return _Form
        End Get
        Private Set(ByVal value As Form)
            _Form = value
        End Set
    End Property
 
    Public Sub New(ByVal form As Form)
        Me.Form = form
    End Sub
 
    Public Function PreFilterMessage(ByRef m As Message) As Boolean Implements IMessageFilter.PreFilterMessage
        If Me.Form IsNot Nothing AndAlso Me.Form.ActiveControl IsNot Nothing Then
            If m.Msg = 256 Then
                ' code d'une touche appuyé 
                If m.WParam.ToInt32() = 13 Then
                    Dim textbox As TextBox = TryCast(Form.ActiveControl, TextBox)
 
                    If textbox IsNot Nothing AndAlso (textbox.Multiline = False OrElse (textbox.Multiline = True AndAlso textbox.AcceptsReturn = False)) Then
                        ' va chercher le prochain control 
                        Dim nextControl As Control = Form.GetNextControl(textbox, True)
 
                        If nextControl IsNot Nothing Then nextControl.Focus()
 
                        Return True
                    End If
                End If
            End If
        End If
 
        Return False
    End Function
 
End Class

22/02/2010, 20h08
Samuel Blanchard

Merci la star du VB :)
Il était ou mon souci de convertion ?
22/02/2010, 20h31
Sehnsucht

Citation:

Envoyé par Samoteph

Merci la star du VB :)
Il était ou mon souci de convertion ?

Star du VB faut pas exagérer ;)

Code:

AddHandler Me.Load, AddressOf Form1_Load

Est inutile, c'est déjà le comportement par défaut.

Ton code:

Code:

Public Function PreFilterMessage(ByRef m As Message) As Boolean

Le mien:

Code:

Public Function PreFilterMessage(ByRef m As Message) As Boolean Implements IMessageFilter.PreFilterMessage

Quand tu implémente une Interface, tu spécifies après le prototype de la méthode implémentée, la méthode de l'interface correspondante, car tu n'es pas obliger de la nommer pareil (exemple j'aurais pu aussi écrire ça)

Code:

Public Function Toto(ByRef m As Message) As Boolean Implements IMessageFilter.PreFilterMessage
22/02/2010, 21h13
Samuel Blanchard

@Sehnsucht

Citation:

Quand tu implémente une Interface, tu spécifies après le prototype de la méthode implémentée, la méthode de l'interface correspondante, car tu n'es pas obliger de la nommer pareil (exemple j'aurais pu aussi écrire ça)

Ouaaaa c'est puissant et verbeux le VB :)

@vb

Alors avec la convertion plus soignée de Sehnsucht est-ce que ma petite astuce fonctionne ? (Ca marche en C#, y a pas de raison :) )
22/02/2010, 23h02
vb

Bonjour,
Merci à vous pour avoir contribué à résoudre ma question et par la même occasion d'en savoir un peu plus.:ccool:
Je mets ma question ...résolu
Bien à vous
vb