Validateurs Flex appliqué à plusieurs composants

Bonjour,

je voudrais savoir s'il y a moyen de déclarer un seul validateur qui soit applicable pour plusieurs champs de texte par exemple, pcq les contraintes que j'ai sont les mémes pour une vingtaine de champs donc ça sera embetant de recopier le code à chaque fois!

merci de me répondre

Bonjour,

Etant donné que les validateurs sont ciblés sur un composant cela me paraît difficilement possible.

merci d'avoir répondu Ellene, oui c'est ce que je me suis dit aussi mais ça sera dommage de retaper le code surtout lorsqu'il s'agit de formulaire avec plusieurs champs.si par exemple on peut declarer plusieurs sources à la fois ça sera génial!!

Sinon tu peux surcharger le textinput pour qu'il intégre un validateur par défaut mais je ne verrais que cette solution pour l'instant.

je vois pas qu'est ce que tu veux dire par "surcharger" un textinput! peut ètre créer un textinput personnalisé?

Tu surcharges(/étends/fais hériter de) la classe TextInput déjà existante et tu ajoutes ton validateur dedans.

Citation:

ça sera embetant de recopier le code à chaque fois!

Ce n'est parce qu'il faut créer un "validator" pour chaque champ que tu es obligé de réécrire le code de validation à chaque fois.
Il faut créer un "validator" personnalisé que tu utiliseras pour chacun de tes champs.

Sinon j'ai trouvé dans la doc de Flex un exemple appelé Validating multiple fields Peut-être es-tu dans cette situation ?

tu peux creer un validateur qui va valider plusieurs composant en une passe.
Le résultat de la validation est en fait une liste de résultat. Voici un exemple de code que j'utilise (pour valider un formulaire par exemple)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
package com.register.validation
{
	import com.model.User;
	import com.register.components.LinkButtonCheckBox;
 
	import mx.validators.IValidatorListener;
	import mx.validators.ValidationResult;
	import mx.validators.Validator;
 
	public class RegistrationValidator extends Validator
	{
		private const LOGIN_FIELD:String = "login";
		private const PASSWORD_FIELD:String = "pwd";
		private const LASTNAME_FIELD:String = "lastname";
		private const FIRSTNAME_FIELD:String = "firstname";
		private const CGU_FIELD:String = "cgu";
 
		public function RegistrationValidator()
		{
			super();
		}
 
		private var _loginListener:IValidatorListener;
 
		public function set loginListener(value:IValidatorListener) : void {
			if (_loginListener == value) {
				return;				
			}
 
			removeListenerHandler();
			_loginListener = value;
			addListenerHandler();
		}
 
		private var _confirmLoginListener:IValidatorListener;
 
		public function set confirmLoginListener(value:IValidatorListener) : void {
			if (_confirmLoginListener == value) {
				return;				
			}
 
			removeListenerHandler();
			_confirmLoginListener = value;
			addListenerHandler();
		}
 
		private var _passwordListener:IValidatorListener;
 
		public function set passwordListener(value:IValidatorListener) : void {
			if (_passwordListener == value) {
				return;				
			}
 
			removeListenerHandler();
			_passwordListener = value;
			addListenerHandler();
		}
 
		private var _confirmPasswordListener:IValidatorListener;
 
		public function set confirmPasswordListener(value:IValidatorListener) : void {
			if (_confirmPasswordListener == value) {
				return;				
			}
 
			removeListenerHandler();
			_confirmPasswordListener = value;
			addListenerHandler();
		}
 
		private var _lastnameListener:IValidatorListener;
 
		public function set lastnameListener(value:IValidatorListener) : void {
			if (_lastnameListener == value) {
				return;				
			}
 
			removeListenerHandler();
			_lastnameListener = value;
			addListenerHandler();
		}
 
		private var _firstnameListener:IValidatorListener;
 
		public function set firstnameListener(value:IValidatorListener) : void {
			if (_firstnameListener == value) {
				return;				
			}
 
			removeListenerHandler();
			_firstnameListener = value;
			addListenerHandler();
		}
 
		private var _cguListener:IValidatorListener;
 
		public function set cguListener(value:IValidatorListener) : void {
			if (_cguListener == value) {
				return;
			}
 
			removeListenerHandler();
			_cguListener = value;
			addListenerHandler();
		}
 
		override protected function doValidation(value:Object):Array
		{
			var user:User = value as User;
 
			var loginResult:ValidationResult;
			var passwordResult:ValidationResult;
			var lastnameResult:ValidationResult;
			var firstnameResult:ValidationResult;
			var cguResult:ValidationResult;
 
			var results:Array = [];
 
			if (user.login) {
				if (!user.login.match("[a-zA-Z0-9._%+-]+@[a-zA-Z0-9.-]+\.[a-zA-Z]{2,4}")) {
					loginResult = new ValidationResult(true, LOGIN_FIELD, "loginError", "L'adresse E-Mail saisie n'est pas valide.");
				} else {
					if (user.login != user.confirmLogin) {
						loginResult = new ValidationResult(true, LOGIN_FIELD, "loginError", "Les adresses E-Mail que vous avez saisies ne correspondent pas.");
					} else {
						loginResult = new ValidationResult(false, LOGIN_FIELD);
					}
				}
			} else {
				loginResult = new ValidationResult(true, LOGIN_FIELD, "loginError", "Vous n'avez pas saisi d'adresse E-Mail.");
			}
 
			if (user.stringPassword) {
				if (user.stringPassword.length < 6) {
					passwordResult = new ValidationResult(true, PASSWORD_FIELD, "passError", "Le mot de passe doit faire 6 caractères minimum.");
				} else {
					if (user.stringPassword != user.confirmStringPassword) {
						passwordResult = new ValidationResult(true, PASSWORD_FIELD, "passError", "Les mots de passe que vous avez saisis ne correspondent pas.");
					} else {
						passwordResult = new ValidationResult(false, PASSWORD_FIELD);
					}
				}
			} else {
				passwordResult = new ValidationResult(true, PASSWORD_FIELD, "passError", "Vous n'avez pas saisi de mot de passe.");
			}
 
			if (user.personnalDatas.firstName) {
				firstnameResult = new ValidationResult(false, FIRSTNAME_FIELD);
			} else {
				firstnameResult = new ValidationResult(true, FIRSTNAME_FIELD, "firstnameError", "Vous n'avez pas saisi de prénom");
			}
 
			if (user.personnalDatas.lastName) {
				lastnameResult = new ValidationResult(false, LASTNAME_FIELD);
			} else {
				lastnameResult = new ValidationResult(true, LASTNAME_FIELD, "firstnameError", "Vous n'avez pas saisi de nom");
			}
 
			if (_cguListener != null) {
				if ((_cguListener as LinkButtonCheckBox).checkBox.selected) {
					cguResult = new ValidationResult(false, CGU_FIELD);
				} else {
					cguResult = new ValidationResult(true, CGU_FIELD, "cguError", "Vous devez accepter les conditions générales d'utilisateur");
				}
			} else {
				cguResult = new ValidationResult(true, CGU_FIELD, "cguError", "Vous devez accepter les conditions générales d'utilisateur");
			}
 
			results.push(loginResult);
			results.push(passwordResult);
			results.push(lastnameResult);
			results.push(firstnameResult);
			results.push(cguResult);
 
			return results;
		}
 
		override protected function get actualListeners():Array 
		{
            var results:Array = [];
 
			if (_loginListener)
			{
				results.push(_loginListener);
				IValidatorListener(_loginListener).validationSubField = LOGIN_FIELD;
			}
 
			if (_confirmLoginListener)
			{
				results.push(_confirmLoginListener);
				IValidatorListener(_confirmLoginListener).validationSubField = LOGIN_FIELD;
			}
 
			if (_passwordListener)
			{
				results.push(_passwordListener);
				IValidatorListener(_passwordListener).validationSubField = PASSWORD_FIELD;
			}
 
			if (_confirmPasswordListener)
			{
				results.push(_confirmPasswordListener);
				IValidatorListener(_confirmPasswordListener).validationSubField = PASSWORD_FIELD;
			}
 
			if (_firstnameListener)
			{
				results.push(_firstnameListener);
				IValidatorListener(_firstnameListener).validationSubField = FIRSTNAME_FIELD;
			}
 
			if (_lastnameListener)
			{
				results.push(_lastnameListener);
				IValidatorListener(_lastnameListener).validationSubField = LASTNAME_FIELD;
			}
 
			if (_cguListener)
			{
				results.push(_cguListener);
				IValidatorListener(_cguListener).validationSubField = CGU_FIELD;
			}
 
			if (results.length > 0 && listener)
				results.push(listener);
			else
				results = results.concat(super.actualListeners);
 
			return results;
        }
 
		override protected function getValueFromSource():Object
		{
			return this.source;
		}  
	}
}

La solution de jylaxx est bien meilleure que la mienne ;) et plus simple je te la conseille.