Ajouter supprimer items listbox avec textbox et commandbutton

Version imprimable

18/01/2010, 12h11
Invité(e)

Ajouter supprimer items listbox avec textbox et commandbutton
Bonjour à tous,

Je suis en train de faire une userform qui va permettre de nommer des colonnes. J’ai des choix obligatoires, des proposées et des libres.

Mon userform se lance avec le classeur.

Ce que je souhaite faire c’est, avoir une texbox ou écrire « toto1 », un bouton ajouter, qui va ajouter « toto1 » à la listbox. Pareil pour « toto2 » qui va être ajouter à la listbox.

Si erreur, je selectionne « toto1 » dans la listbox et appuis ensuite sur un bouton supprimer, qui va enlever seulement « toto1 ».

Une fois les choix effectué, j’ai un bouton « lancer » qui va regarder les items ajoutés à la listbox et les ajouter sur Row1 et column la plus à gauche.

Mon problème c’est que je m’embrouille dans les additem, removeitem

De plus je penses qu’il y a plusieurs moyen de proceder.

Que le bouton ajouter, ajoute la value textbox sur une plage que regardera la listbox ? Mais dans ce cas là, ça me dérange d’avoir des blancs dans ma listbox.

Que le bouton ajouter fasse un additem avec la valeur de la textbox, mais dans ce cas là, comment est le code ? Est comment faire ecrire ensuite les items de la listbox sur ma feuille ?

Mon userform ressemble à ça :

http://img195.imageshack.us/img195/386/userform.jpg

Le bouton démarrer va faire inscrire les items dans la ligne une colonne la plus à gauche et fermé l’userform.

Pour le moment je n’ai que
Code:

1 2 3 Dim Lg As String Lg = Sheets("Feuil2").Cells(65536, 1).End(xlUp).Row + 1 Sheets("Feuil2").Cells(Lg, "A").Value = UserForm1.TextBox1.Value
Ce qui me permet d’inscrire la valeur textbox dans une plage ou la textbox recherché ses items…
Voilà, merci de m’aider.

Bonjour,
une proposition
sur userform j'ai ListBox1, TextBox1, Bouton nommé Ajout et Bouton nommé Suppr
la listbox est remplie à l'aide des données de la plage A2:A... de la feuille MaFeuille

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Option Explicit
Dim ws As Worksheet
 
Private Sub Ajout_Click()
Dim c As Range
If Me.TextBox1.Value <> "" Then
    With ws
        Set c = .Columns("A:A").Find(Me.TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)
        If c Is Nothing Then
            .Range("A" & .Cells(.Rows.Count, 1).End(xlUp).Row + 1).Value = Me.TextBox1.Value
            Me.ListBox1.AddItem Me.TextBox1.Value
        End If
        Set c = Nothing
    End With
End If
End Sub
 
Private Sub Suppr_Click()
Dim c As Range
If Me.ListBox1.ListIndex > -1 Then
    Me.TextBox1.Value = Me.ListBox1.Value
    Set c = ws.Columns("A:A").Find(Me.TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            Me.ListBox1.RemoveItem Me.ListBox1.ListIndex
            Me.ListBox1.ListIndex = -1
            Me.TextBox1.Value = ""
            With ws
                .Range("A" & c.Row + 1 & ":A" & .Cells(.Rows.Count, 1).End(xlUp).Row + 1).Cut .Range("A" & c.Row)
            End With
        End If
    Set c = Nothing
End If
End Sub
 
Private Sub UserForm_Initialize()
Dim i As Long
Set ws = Sheets("MaFeuille") 'à adapter
 
With ws
    For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
        Me.ListBox1.AddItem .Range("A" & i).Value
    Next i
End With
End Sub

L'ajout: on écrit une entrée dans textbox1 et on ajoute
La suppression, on sélectionne l'Item dans la listbox et on supprime

18/01/2010, 14h00
Invité(e)

Bonjour,

Merci pour cette réponse.

J'obtiens quelques erreurs.

La première était une variable non définie pour les "ws = ..."

J'ai donc mis dim ws as worksheet en pensant que ws = worksheet ;)

J'ai ensuite une erreur sur les lignes :

Code:

Set c = ws.Columns("A:A").Find(Me.TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)

"variable objet ou variable bloc with non définie" là par contre, je sais pas trop comment l'enlever...

j'ai également une erreur accès refusé sur la ligne

Code:

Me.ListBox1.AddItem .Range("A" & i).Value

Je précise que j'ai enlevé la protection de mes feuilles avant de tester.
Je précise également que j'ai bien changé le "mafeuille" en "feuil2" ;)
18/01/2010, 14h23
mercatog

le

Code:

Dim ws As worksheet

est bien en haut du module de l'userform
tu as bien dans >Intialize de ton userform ceci

Code:

Set ws=sheets("Feuil2")

ps: j'ai testé
18/01/2010, 14h41
Invité(e)

Euh j'ai mis

Code:

Dim ws As Worksheet

dans [general] [declaration]
Je n'ai donc plus la première erreur sur la variable, par contre une nouvelle :

Code:

Me.ListBox1.AddItem Me.TextBox1.Value

Accès refusé...
18/01/2010, 14h59
mercatog

Si tu mettais un extrait de ton fichier?
18/01/2010, 15h21
Invité(e)

Voici mon fichier réduit au minimum, mais conservant l'erreur....

http://www.cijoint.fr/cjlink.php?fil...cij6rHLPWb.xls

Peut-être s'agit-il d'une erreur connue sur v2000...
18/01/2010, 15h28
mercatog

Supprime des propriétés de ta listebox le RowSource (laisse là vide)
18/01/2010, 15h36
Invité(e)

Rebonjour,

Je me permet d’enlever la bannière résolu, car j’ai du modifier mon fichier et donc j’ai dû adapter la solution obtenu… Le truc, c’est que je n’y arrive pas…

J’ai essayé de modifier les lignes de codes afin de pouvoir ajouter des noms de colonnes sur la ligne 1. Sur la dernière case pleine +1.

Donc au lieu des lignes

Code:

.Range("A" & .Cells(.Rows.Count, 1).End(xlUp).Row + 1).Value = Me.TextBox1.Value

J’ai essayé de metre :

Code:

.Range (.Cells(1, .Columns.Count).End(xlToLeft).Column + 1 & "1").Value = Me.textBox1.Value

ou

Code:

.Range("IV1").End(xlToLeft).Value = Me.TextBox1.Value

J’arrive donc à écrire sur la dernière case de ma ligne, le problème c’est que je n’arrive pas à ajouter le « +1 » ou il faut pour que ça se rajoute à la fin.

Mon deuxième soucis c’est quand je souhaite supprimer l’item, j’ai également une erreur…

Enfin voilà, si vous pouviez me donner l'astuce pour arriver à faire exactement la même chose que le code déjà donné, mais sur la ligne 1 au lieu de la colonne A...

Merci beaucoup

:oops:

Je ne comprends pas pourquoi à la place d’un

Code:

1
2
3
4
5
6
7
8
9
10
11
 Dim c As Range
If Me.TextBox1.Value <> "" Then
    With ws
        Set c = .Rows("1:1").Find(Me.TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)
        If c Is Nothing Then
            .Range("A" & .Cells(.Rows.Count, 1).End(xlUp).Row + 1).Value = Me.TextBox1.Value
            Me.ListBox1.AddItem Me.TextBox1.Value
        End If
        Set c = Nothing
    End With
End If

Code:

1
2
3
4
5
6
7
8
9
10
11
 Dim c As Range
If Me.TextBox1.Value <> "" Then
    With ws
        Set c = .Columns("A:A").Find(Me.TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)
        If c Is Nothing Then
            .Range(.Cells(.Columns.Count, 1).End(xlToLeft).Column + 1 & "1").Value = Me.TextBox1.Value
            Me.ListBox1.AddItem Me.TextBox1.Value
        End If
        Set c = Nothing
    End With
End If

Ne fonctionne pas par exemple… Je penses pourtant suivre la logique de l’inversement des noms et positions pour le .Range…

A moins que ça ne fonctionne pas du tout comme ça :D Mais bon, ça serait ennuyant...

Bonjour,
je t'avais laissé pour adapter
ci-joint la totalité des changements à opérer

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Dim ws As Worksheet
Dim LastCol As Integer
 
 
Private Sub UserForm_Initialize()
Dim i As Integer
Set ws = Sheets("MaFeuille") 'à adapter
 
With ws
    LastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
    For i = 1 To LastCol
        Me.ListBox1.AddItem .Cells(1, i).Value
    Next i
End With
End Sub
 
Private Sub Ajout_Click()
Dim c As Range
If Me.TextBox1.Value <> "" Then
    With ws
        Set c = .Rows(1).Find(Me.TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)
        If c Is Nothing Then
            LastCol = LastCol + 1
            .Cells(1, LastCol).Value = Me.TextBox1.Value
            Me.ListBox1.AddItem Me.TextBox1.Value
        End If
        Set c = Nothing
    End With
End If
End Sub
 
Private Sub Suppr_Click()
Dim c As Range
If Me.ListBox1.ListIndex > -1 Then
    Me.TextBox1.Value = Me.ListBox1.Value
    With ws
        Set c = .Rows(1).Find(Me.TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)
            If Not c Is Nothing Then
                Me.ListBox1.RemoveItem Me.ListBox1.ListIndex
                Me.ListBox1.ListIndex = -1
                Me.TextBox1.Value = ""
                .Range(.Cells(1, c.Column + 1), .Cells(1, LastCol + 1)).Cut .Cells(1, c.Column)
                LastCol = LastCol - 1
            End If
        Set c = Nothing
    End With
End If
End Sub

19/01/2010, 11h34
Invité(e)

Je te remercie encore beaucoup pour ce code, juste une dernière question :

ma façon de tester à inverser les row et column comme montré dans mon dernier post, est-ce faisable, ou est-ce qu'il faut obligatoirement faire comme toi, c'est à dire déclarer une nouvelle variable?

Dernier truc, c'est de tête ou tu as une mine d'or de code utiles dans un fichier texte? :D

Merci encore ;)

Déclarer une nouvelle variable c'était juste pour une lisibilité du code (en fait pour faciliter la compréhension du code)

en plus, tu as ici une erreur de conception, il fallait faire

Code:

1
2
3
4
        If c Is Nothing Then
            .Cells(1, .Cells(1,.columns.Count).End(xltoleft).column+ 1).Value = Me.TextBox1.Value
            Me.ListBox1.AddItem Me.TextBox1.Value
        End If

[/QUOTE]
à la place de

Code:

1
2
3
4
        If c Is Nothing Then
            .Range("A" & .Cells(.Rows.Count, 1).End(xlUp).Row + 1).Value = Me.TextBox1.Value
            Me.ListBox1.AddItem Me.TextBox1.Value
        End If

19/01/2010, 11h53
Invité(e)

Merci encore, résolu ! :ccool: