boucle while "Interminable"

Version imprimable

Bonjour, voilà mon code actuel :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Sub jetdeau_Click()
Dim test As String
Dim continuer As String
Dim numericcheck10 As Boolean
 
 
jet = Sheets("devis").Range("L9999").End(xlUp).Row + 1
 
test = ("Jet d'eau")
Sheets("devis").Range("L" & jet).Value = test
 
Usinage.Hide
 
Do
    Do
        Do
    tusinage = InputBox("Indiquez le temps d'usinage")
    numericcheck10 = IsNumeric(tusinage)
    Loop While numericcheck <> True
        Loop while tusinage < 0
 
jet2 = Sheets("devis").Range("M9999").End(xlUp).Row + 1
Sheets("devis").Range("M" & jet2).Value = tusinage
 
commentaire = InputBox("Avez-vous un commentaire à ajouter sur cette opération ?")
Comment = Sheets("devis").Range("Q9999").End(xlUp).Row + 1
Sheets("devis").Range("Q" & Comment).Value = commentaire
 
    rep$ = InputBox("Tapez 'oui' si vous désirez arrêter la saisie, sinon tapez 'non'")
    If rep$ = "non" Then
    Sheets("accueil").Select
    End If
Loop Until rep$ = "oui"
 
End

Le problème est que, lorsque je rentre une valeur dans mon inputbox de début pour tusinage, le programme tourne en rond, quelque soit ce que je rentre... et je ne comprend pas du tout pourquoi..

Quelqu'un pourrait-il m'aider ?

05/12/2009, 11h25
mercatog
d'abord, parlons de tes variables,
fais une
Code:

1 2 3 Option explicit Private Sub jetdeau_Click() '....ton code
ce test reprend quelle variable?

Code:

Loop While numericcheck <> True

le code est certes à améliorer
05/12/2009, 11h31
Pierre Fauconnier

Salut.

Je complète Mercatog.

En tout début de module, place

Code:

option explicit

Dans Outils/options, coche Déclaration automatique des variables => placement automatique de "option explicit" au début des nouveaux modules...

Ainsi, tu seras obligé de déclarer tes variables et tu limiteras tes erreurs de saisie de code.

Ci joint un essai pour ton code

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Option Explicit
Private Sub jetdeau_Click()
Dim jet As Long
Dim tusinage As Variant
 
With Sheets("devis")
    Usinage.Hide
    Do
        Do
            tusinage = InputBox("Indiquez le temps d'usinage")
            If Len(tusinage) = 0 Then Exit Sub
        Loop While Not IsNumeric(tusinage) Or tusinage < 0
 
        jet = .Cells(.Rows.Count, 12).End(xlUp).Row + 1
        .Range("L" & jet).Value = "Jet d'eau"
        .Range("M" & jet).Value = tusinage
        .Range("Q" & jet).Value = InputBox("Avez-vous un commentaire à ajouter sur cette opération ?") 'commentaire
 
    Loop Until MsgBox("Vous désirez arrêter la saisie?", vbYesNo + vbDefaultButton2) = vbYes
End With
End Sub

Tu peux te passer de la demande sur une nouvelle saisie, puisque ton inputbox possède le bouton Annuler

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
    With Sheets("devis")
        Do
            Do
                tusinage = InputBox("Indiquez le temps d'usinage ou cliquez sur Annuler pour arrêter la saisie")
            Loop While (Not IsNumeric(tusinage) Or tusinage < 0) And tusinage <> ""
            If tusinage <> "" Then
                jet = .Cells(.Rows.Count, 12).End(xlUp).Row + 1
                .Range("L" & jet).Value = "Jet d'eau"
                .Range("M" & jet).Value = tusinage
                .Range("Q" & jet).Value = InputBox("Avez-vous un commentaire à ajouter sur cette opération ?") 'commentaire
            End If
        Loop While tusinage <> ""
    End With