PropertyGrid et lecture fichier XML

Version imprimable

Bonjour à tous,
En Préambule, je précise : débutant...
J'alimente un propertygrid avec un fichier XML; tout se passe normalement.
L'objectif est de permettre à l'utilisateur, pour une propriété, le choix dans une liste en cas de création - modification, ou bien de saisir une valeur non encore répertoriée.
Bref le fonctionnement classique d'un combobox bindé.
Le problème se situe dans le chargement des valeurs proposées pour cette propriété; je n'obtiens toujours que la seule valeur lue dans mon fichier XML.
Mes recherches sur les forums n'ont rien donné...
Voici le code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
Imports System.ComponentModel
Imports System.ComponentModel.Design
Imports System.Drawing.Design
Imports System.Xml.Serialization
 
Public Class ListEvenement
    Inherits TypeConverter         'même comportement avec StringConverter
 
Public Overloads Overrides Function GetStandardValuesSupported( _
                    ByVal context As ITypeDescriptorContext) As Boolean
        Return True
    End Function
 
    Public Overloads Overrides Function GetStandardValues( _
                     ByVal context As ITypeDescriptorContext) _
                  As StandardValuesCollection
        Return New StandardValuesCollection(New String() {"test1", _
                                                          "test2", _
                                                          "test3"})
    End Function
 
    Public Overloads Overrides Function GetStandardValuesExclusive( _
               ByVal context As ITypeDescriptorContext) As Boolean
        Return False
    End Function
End Class
 
<Serializable()> _
Public Class Calendrier
 
Private VCalEvnt As String
 
    <TypeConverter(GetType(ListEvenement)), BrowsableAttribute(True), _
        Description("Nom de l'évènement"), Category("Evènement"), DisplayName("Evènement"), _
        Editor(GetType(MultilineStringEditor), GetType(UITypeEditor)), _
        XmlAttribute()> _
        Public Property CalEvnt() As String
        Get
            Return VCalEvnt
        End Get
        Set(ByVal value As String)
            VCalEvnt = value
        End Set
    End Property

Pour le chargement dans le formulaire :

Code:

1
2
3
4
5
 
Private Sub CalBS_CurrentChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CalBS.CurrentChanged
'PG = PropertyGrid  -  BS = BindingSource        
CalPG.SelectedObject = CalBS.Current
    End Sub

Si quelqu'un peut m'orienter... Merci d'avance

17/08/2009, 10h46
tomlev

Je pense qu'il faut que tu définisses un éditeur spécifique pour la propriété concernée. Pour cela il faut hériter de la classe UITypeEditor, et appliquer l'attribut EditorAttribute sur la propriété.
18/08/2009, 00h12
manrc
Merci pour ta réponse Tomlev.
J'ai tenté d'implémenter la solution via les liens que tu as indiqué, mais sans succès.
N'y aurait-il pas une possibilité lors du chargement du formulaire de préciser, pour le propertygrid, une liste de valeurs?
J'ai essayé avec :
Code:

1 2 CalPG.BrowsableAttributes.Item(0)
mais je ne parviens pas à effectuer le setting des valeurs.
Mer
18/08/2009, 02h55
tomlev

Citation:

Envoyé par manrc

N'y aurait-il pas une possibilité lors du chargement du formulaire de préciser, pour le propertygrid, une liste de valeurs?

Seulement avec la solution que je t'ai indiquée... désolé :aie:
18/08/2009, 09h16
manrc

Merci encore de tes efforts....
Je vais sans doute m'orienter vers un autre contrôle que le propertygrid.

trouvé...

Pour ceux que cela intéresserait, voici comment j'ai procédé pour résoudre (ou contourner?) le problème.
Rappel : l'objectif est d'alimenter une dropdown liste dans une propriété d'un propertygrid, avec pour source des attributs issus d'un fichier XML, et de permettre à l'utilisateur de rajouter de nouvelles données, que l'on retrouve dans la liste après chaque saisie.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Public Class EvtSelEditor
    Inherits ObjectSelectorEditor
 
    Public Overloads Overrides Function GetEditStyle( _
    ByVal context As ITypeDescriptorContext) _
    As UITypeEditorEditStyle
 
        Return UITypeEditorEditStyle.DropDown
    End Function
 
    Protected Overloads Overrides Sub FillTreeWithData( _
        ByVal selector As Selector, _
        ByVal context As ITypeDescriptorContext, _
        ByVal provider As IServiceProvider)
 
        selector.Nodes.Clear()
        Dim XDoc As XDocument = XDocument.Load("Mon document.xml")
        Dim evt = (From elt In XDoc.Descendants("Element")  _
        Select elt.Attribute("MonAttribut").Value).ToArray
        For i = 0 To UBound(evt)
            selector.AddNode(evt(i), evt(i), Nothing)
        Next
    End Sub
End Class

Puis pour la propriété :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
<Serializable()> Public Class Calendrier
     Private VarCalEvnt As String
 
    <Description("Nom de l'évènement"), Category("Evènement"), _ 
      DisplayName("Evènement"),Editor(GetType(EvtSelEditor), _ 
      GetType(UITypeEditor)),  XmlAttribute()> _
      Public Property CalEvnt() As String
        Get
            Return VarCalEvnt
        End Get
        Set(ByVal value As String)
            VarCalEvnt = value
        End Set
    End Property

Je ne sais si c'est très orthodoxe, mais dans mon cas, ça fonctionne...
Si cela peut aider...

19/08/2009, 10h38
tomlev

Bien vu, je ne connaissais pas cette classe ObjectSelectorEditor... plus pratique que d'hériter directement de UITypeEditor ;)