ma fonction retourne toujours null

Voila j'ai réussi en utilisant le dispatchEvent
Je sais pas si c'est très correct comme code, d'ailleurs pour ceux qui sont intéressé, voilà comment j'ai fais :

Ma classe Param.as extends de EventDispatcher
j'ajoute une variable constante Param.CHARGEMENT_TERMINE
et j'ajoute à la fin de mon listener loadXML un dispatch event dispatchEvent(new Event(Param.CHARGEMENT_TERMINE ));

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
 
package com.haco.xmlLoad { 
 
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;
	import flash.events.Event;
	import flash.events.HTTPStatusEvent;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.events.EventDispatcher;
 
	public class Param extends EventDispatcher{
 
		public var XMLDOC:XML;
		public var _title:String = "";
		public var _bgColor:String = "";
		private var loader:URLLoader = new URLLoader();
		public static const CHARGEMENT_TERMINE:String = "chargementTermine";
 
		public function Param(xmlFile:String){
			loader.addEventListener(Event.COMPLETE, loadXML); 
			loader.addEventListener(ProgressEvent.PROGRESS, avancement);
			loader.addEventListener(IOErrorEvent.IO_ERROR, ioerror);
			loader.load(new URLRequest(xmlFile)); 
			XML.ignoreWhitespace = true;
		}
 
		// définition de la fonction exécutée par l'événement PROGRESS :
		// déclenchée à chaque avancement du chargement )
		private function avancement( event:Event) {
			trace(event.target.bytesLoaded+" Ko chargés sur "+event.target.bytesTotal + " Ko");
		}
 
 
		private function loadXML(pEvt:Event):void{
			trace ( "Phase : " + pEvt );
			var xml:XML = new XML(pEvt.target.data);
			this.XMLDOC = xml;
			for(var i:String in this.XMLDOC..item) {
				if(this.XMLDOC.item[i].@name == "title"){
					setTitle(this.XMLDOC.item[i].@value);
				}else if(this.XMLDOC.item[i].@name == "bgcolor"){
					setBgColor(this.XMLDOC.item[i].@value);
				}
			}
			dispatchEvent(new Event(Param.CHARGEMENT_TERMINE ));
		}
 
		private function ioerror(pEvt:IOErrorEvent){
			trace("Erreur lors du chargement du fichier XML");
			trace(pEvt.text);
		}
 
		public function getTitle():String{
			return this._title;
		}
		public function setTitle(atitle:String):void{
			this._title = atitle;
		}
 
		public function getBgColor():String{
			return this._bgColor;
		}
		public function setBgColor(aBgColor:String):void{
			this._bgColor = aBgColor;
		}
	}
}

ensuite sur ma scène je cré mon Objet Param
et j'ajoute un eventListener qui va prendre en argument ma variable constante CHARGEMENT_TERMINE de ma classe Param
et va executer la methode traceResult:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
import com.haco.xmlLoad.Param;
stop();
 
/**load parameters**/
var parameters:Param = new Param("param.xml");
 
parameters.addEventListener ( Param.CHARGEMENT_TERMINE, traceResult );
 
// fonction écouteur
function traceResult ( pEvt:Event ):void{
	trace("chargement terminé !");
	trace("title => " + parameters.getTitle());
	trace("bgColor => " + parameters.getBgColor());
}
/**End of load parameters**/
 
gotoAndStop(2);

du coup je récupère bien les valeurs de mon fichier XML
ma fonction traceResult me retourne

Code:

1
2
3
4
5
6
7
 
Contenu flash généré en 2 ms
152 Ko chargés sur 152 Ko
Phase : [Event type="complete" bubbles=false cancelable=false eventPhase=2]
chargement terminé !
title => EARTH COM
bgColor => 0xFF0000

Voila :roll: