Getobject ou createobject non réalisé en tache planifiée

Version imprimable

10/12/2005, 07h15
BEROUNET

Getobject ou createobject non réalisé en tache planifiée

Bonjour,
J'ai une base access qui tourne à merveilles et dans laquelle j'utilise des getobject pour acceder à d'autres bases ACCESS . Tout se passe très bien sauf lorsque j'appelle l'appli en tache planifiée. L'exécution du code s'arrête à cette ligne. Bien entendu impossoible d'avoir de code d'erreur puisque l'exécution se fait en arrière plan, machine déloguée)
j'ai tenté un createobject mais résultat identique.
Pour info les bases auxquelles je fais référence sont bien résidentes je veux dire que ce n'est pas un pb de disque déconnecté.
Si qq a une idée ce serait cool !!
D'avance merci.
10/12/2005, 10h01
keita

BEROUNET a écrit:

Citation:

....L'exécution du code s'arrête à cette ligne.

De quelle ligne tu parles? et puis pourquoi ne pas deboguerton code directement d'abord avant de le mettre en tache planifiée?
@+
10/12/2005, 14h32
MC2

N'aurais-tu pas un pb de connexion utilisateur ?
Ta tâche planifiée l'est-elle sous un nom d'utilisateur particulier ? style utilisateur local, sans droits d'accès distants alors que ton mdb l'est ?...
10/12/2005, 19h23
BEROUNET

déboguage

... bien entendu j'aurai voulu déboguer mais tout se passe a merveilles quand on est en session classique. Le pb apparait dès qu'on est en tâche planifiée.
Pour l'histoire des droits ça m'échappe un peu mais je vais essayer de creuser le truc. Ca sent bien un truc comme ça !

Merci !
11/12/2005, 14h12
MC2

Quand tu fais un prg comme ça, en tâche de fond, il faudrait que tu rediriges les erreurs vers un fichier ou bien vers l'observateur d'évènements Windows.
Je vais creuser la chose, je l'ai déjà fait mais je ne l'ai pas sous la main.
A+
11/12/2005, 14h14
BEROUNET

Merci, je suis vraiment preneur si tu as le tuyau.
A+
11/12/2005, 15h46
keita

BEROUNET a écrit:

Citation:

J'ai une base access qui tourne à merveilles et dans laquelle j'utilise des getobject pour acceder à d'autres bases ACCESS ...

je voudrais juste comprendre:
quel est l'interet de getobject ici?
@+
11/12/2005, 16h38
Tofalu

Citation:

Envoyé par keita

BEROUNET a écrit:

Citation:

J'ai une base access qui tourne à merveilles et dans laquelle j'utilise des getobject pour acceder à d'autres bases ACCESS ...

je voudrais juste comprendre:
quel est l'interet de getobject ici?
@+

J'avoue ne pas comprendre non plus

Rappelons que l'utilisation d'automation est trés gourmand en ressources système et donc trés lent. Son utilisation doit être limité au strict nécessaire. Qui plus est pour access, il est possible de réaliser des applications portail (cf la FAQ) et DAO ou ADO pour les requetes

En aucun cas, l'automation Access to Access ne semble justifiable :?

Bonsoir,
certes le getobject n'est pas forcément approprié mais son problème initial persiste et c'est pour cela que je permets de lui donner un petit coup de main.
Il y a là encore peut-être plus simple (fichier log), mais voici un code simplifié (eh oui !) de génération de messages dans l'observateur d'évènements (event viewer) .
Copier ce code dans un module séparé (cf. à la fin pour un exemple d'utilisation) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
Option Compare Database
Option Explicit
 
Public Enum enmLogType
   LogError = 1&
   LogWarning = 2&
   LogInfo = 4&
End Enum
Public Enum enmErrLevel
   lInfo = &H60000000
   lWarning = &HA0000000
   lError = &HE0000000
End Enum
Public Enum LogEventTypeConstants
   vbLogEventTypeError = 1
   vbLogEventTypeInformation = 4
   vbLogEventTypeWarning = 2
End Enum
Private Declare Function RegisterEventSource Lib "advapi32" Alias "RegisterEventSourceA" (ByVal lpUNCServerName As String, ByVal lpSourceName As String) As Long
Private Declare Function DeregisterEventSource Lib "advapi32" (ByVal hEventLog As Long) As Long
Private Declare Function ReportEvent Lib "advapi32" Alias "ReportEventA" (ByVal hEventLog As Long, ByVal wType As Long, ByVal wCategory As Long, ByVal dwEventID As Long, ByVal lpUserSid As Long, ByVal wNumStrings As Long, ByVal dwDataSize As Long, lpStrings As Any, lpRawData As Any) As Long
Private Declare Function GetComputerName Lib "kernel32" Alias "GetComputerNameA" (ByVal lpBuffer As String, nSize As Long) As Long
 
Public Function LogErrorToEventViewer(sErrMsg As String, Optional eEventType As LogEventTypeConstants = vbLogEventTypeError) As Boolean
    Dim lEventLogHwnd As Long
    Dim LogType As enmLogType
    Dim lEventID As Long
    Dim lCategory As Long
    Dim sServerName As String
    Dim lRet As Long
    Dim sSourceName As String
 
    LogErrorToEventViewer = True
    lCategory = 1
    sSourceName = CurrentProject.Name
    sServerName = ComputerName()
 
    If eEventType = vbLogEventTypeError Then
        LogType = LogError
        lEventID = 3& Or enmErrLevel.lError
    ElseIf eEventType = vbLogEventTypeInformation Then
        LogType = LogInfo
        lEventID = 1& Or enmErrLevel.lInfo
    ElseIf eEventType = vbLogEventTypeWarning Then
        LogType = LogWarning
        lEventID = 2& Or enmErrLevel.lWarning
    End If
 
    lEventLogHwnd = RegisterEventSource(lpUNCServerName:=sServerName, lpSourceName:=sSourceName)
 
    If lEventLogHwnd = 0 Then
        LogErrorToEventViewer = False
        Exit Function
    End If
 
    lRet = ReportEvent(hEventLog:=lEventLogHwnd, _
                       wType:=LogType, _
                       wCategory:=lCategory, _
                       dwEventID:=lEventID, _
                       lpUserSid:=0, _
                       wNumStrings:=1, _
                       dwDataSize:=0, _
                       lpStrings:=sErrMsg, _
                       lpRawData:=0)
 
    If lRet = False Then
        LogErrorToEventViewer = False
    Else
        LogErrorToEventViewer = True
    End If
 
    DeregisterEventSource lEventLogHwnd
End Function
 
Public Function ComputerName() As String
    Dim lLong As Long
    Dim sTampon As String
    Dim iR As Integer
 
    sTampon = Space(255)
    lLong = Len(sTampon)
    iR = GetComputerName(sTampon, lLong)
    ComputerName = Left(sTampon, lLong)
End Function
 
'Exemple d'utilisation :
Sub test_LogErrorToEventViewer()
    LogErrorToEventViewer "Mon message d'erreur"
    'Remplace MsgBox "Mon message d'erreur"
    'Possibilité de tester si tout c'est bien passé mais en l'occurence, c'est inutile
End Sub

Pour voir le résultat, ouvrir l'observateur d'évènements dans les Outils d'administration Windows puis choisir la catégorie "Applications".
L'évènement se situe vers la tête de liste.
Double-cliquer dessus pour visualiser le contenu du message (dans mon exemple "Mon message d'erreur").
J'espère que ça va pouvoir t'aider.
Note : et n'oublie pas de suivre les conseils de Keita et Tofalu :wink:
A+