Utilisation d'un dictionary

Version imprimable

Bonjour,
j'ai une chtite question sur les dictionary
Je ne comprends pas pourquoi un de mes codes ne marche pas

voici la partie commune

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public Dico As Scripting.Dictionary
Sub Main()
    Call Calcul
    Call Affiche
End Sub
Sub Calcul()
i = 2
If Not Dico Is Nothing Then
    Set Dico = Nothing
End If
Set Dico = CreateObject("Scripting.Dictionary")
While ThisWorkbook.Sheets("Champs").Cells(i, 1) <> ""
    Dico.Add ThisWorkbook.Sheets("Champs").Cells(i, 1), Int(14 * Rnd())
    i = i + 1
Wend
End Sub

Voici la macro Affiche qui marche

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Sub Affiche()
i = 2
Do While ThisWorkbook.Sheets("Champs").Cells(i, 1) <> ""
    For Each Element In Dico
        If Element = ThisWorkbook.Sheets("Champs").Cells(i, 1) Then
           MsgBox Dico.Item(Element)
           Exit For
        End If
    Next
    i = i + 1
Loop
End Sub

Et voila la macro Affiche qui ne marche pas

Code:

1
2
3
4
5
6
7
Sub Affiche()
i = 2
Do While ThisWorkbook.Sheets("Champs").Cells(i, 1) <> ""
    MsgBox Dico.Item(ThisWorkbook.Sheets("Champs").Cells(i, 1))
    i = i + 1
Loop
End Sub

Quelqu'un sait pourquoi? Ca vient d'un format?
Si ca ne marche vraiment pas, quelq'un connait un objet autre que Dictionnary qui permet de faire cela?
Merci d'avance

18/06/2009, 21h19
laetitia
bonsoir -={-_-}=- le forum
en CreateObject("Scripting.Dictionary") je declarais en tant object
Code:

1 2 Dim dico As objet Set dico = CreateObject("Scripting.Dictionary")
ou une collection !!
Code:

1 2 Dim dico As Collection Set dico = New Collection
pour le reste la finalite de ton code c' est quoi???

Bonjour

L'objet Dictionnary accepte "n'importe quoi" comme Key.

Dans la procédure qui alimente le dictionnaire, tu passes des cellules comme Key et pas des valeurs. (C'est le problème de VBA qui interprète ce que tu passes comme valeur et qui détermine à sa sauce le type de valeur/objet que tu lui passes).

Tu dois donc modifier tes deux procédures.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 Sub Calcul() Dim i As Integer i = 2 If Not Dico Is Nothing Then Set Dico = Nothing End If Set Dico = CreateObject("Scripting.Dictionary") While ThisWorkbook.Sheets("Champs").Cells(i, 1) <> "" Dico.Add ThisWorkbook.Sheets("Champs").Cells(i, 1).Value, Int(14 * Rnd()) i = i + 1 Wend End Sub Sub Affiche() Dim i As Integer i = 2 Do While ThisWorkbook.Sheets("Champs").Cells(i, 1) <> "" MsgBox Dico.Item(ThisWorkbook.Sheets("Champs").Cells(i, 1).Value) i = i + 1 Loop End Sub
En ajoutant.value à ThisWorkbook.Sheets("Champs").Cells(i, 1), tu forces le dictionnaire à prendre la valeur comme clé et non l'objet Cellule. Ton code fonctionnera alors sans problème...

Remarques:
1) N'hésite pas à utiliser la déclaration obligatoire des variables (option explicit au début du module (et Outils/Options/Editeur puis cocher Déclaration des variables obligatoire pour avoir automatiquement la ligne option explicit sur tes nouveaux modules)

2) Vu que tu utilises la librairie, tu peux initialiser ton dico avec

Code:

Set Dico = New Scripting.Dictionary

La déclaration

Code:

Set Dico = CreateObject("Scripting.Dictionary")

s'emploie lorsque tu déclares Dico As Object sans avoir coché la librairie dans les références utilisées.

19/06/2009, 15h04
-={-_-}=-

Citation:

Envoyé par Pierre Fauconnier

Dans la procédure qui alimente le dictionnaire, tu passes des cellules comme Key et pas des valeurs. (C'est le problème de VBA qui interprète ce que tu passes comme valeur et qui détermine à sa sauce le type de valeur/objet que tu lui passes).

En ajoutant.value à ThisWorkbook.Sheets("Champs").Cells(i, 1), tu forces le dictionnaire à prendre la valeur comme clé et non l'objet Cellule. Ton code fonctionnera alors sans problème...

Merci. Je le sentais gros comme une maison que c'était juste une question de format mais au moins maintenant j'en ai la confirmation.

Pour la remaque que vous m'avez faite tous les deux, elle est juste mais disons que je pensais que le mon erreur venait de là (la déclaration de l'objet avec mon set), donc je testais mon code avec les deux déclarations et lorsque j'ai mis mon code sur ce forum j'avais l'autre notation.

Merci à vous deux d'avoir pris du temps pour me répondre.