-
Bonjour,
Effectivement j'ai fait une très grosse erreur sur le "cadeaux ".
Cependant pour que ma fonction compte le nombre de "cadeaux" ayant une chiffre strictement positif en colonne K que dois-je rajouter?
La condition
Code:
=SOMMEPROD((Analyse!$B$3:$B$3000="Cadeaux")*(Analyse!$K$3:$K$3000>0))
n'est elle pas suffisante pour tenir compte seulement des chiffres strictement positifs et différent du vide?
Pourquoi ">0" n'est pas pris en compte?
-
Essaye cette formule :
Code:
=SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>""))
le ">0" n'est pas pris en compte car tes cellules ne comprenant seulement 1 espace " " sont considérées comme supérieures à 0
-
Code:
=SOMMEPROD((Analyse!$B$3:$B$3000="Cadeaux")*(Analyse!$K$3:$K$4002<>""))
Ça me renvoie #N/A
Ça peut rendre fou se genre de chose!
-
Pardon ce n'était pas la même PLAGE.
Mais cela me renvoie quand même 81.
Code:
=SOMMEPROD((Analyse!$B$3:$B$3000="Cadeaux")*(Analyse!$K$3:$K$3000<>""))
-
T'as pas pris la bonne formule
Code:
=SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>""))
-
Il faut bien lire les réponses Rickgoz.
David2304 a écrit :
Code:
=SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>""))
et cela fonctionne.
Et oui, la difficulté de traiter des fichiers importés dont on ne connaît pas (ou on ne vérifie pas) la structure.
-
Excusez-moi..
Si je veux que ce soit supérieur à 10? Comment puis-je ajouter cette condition à la partie en gras.
Code:
=SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>""))
Pour dire "et", c'est &?
-
Code:
=SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>"")*(Analyse!$K$3:$K$4002>10))
Pour rajouter une condition, il faut utiliser "*"
-
Merci beaucoup. Désolé pour mes stupides erreurs et ma mauvaise lectures des réponses.
Une dernière chose, si je veux faire la moyenne de ces valeurs il faut que j'utilise MOYENNE.SI, n'est ce pas? Si oui, de quelle facon?
Code:
=MOYENNE.SI(SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>"";<>"")
-
Salut rickgoz et le forum
Tu veux faire quoi ? une moyenne (pas avec les cadeaux, j'espère) ? de quoi par rapport à quoi ?
Une moyenne c'est un total divisé par le nombre d'"objets" qui compose le total.
Tu pourrais envisager un pourcentage de cadeaux par rapport au total des lignes non vides, mais une moyenne!!!
A+
-
Bonsoir Gorfael,
De plus il existe quand même deux sortes de moyennes :
-la moyenne arithmétique (celle dont vous parlez)
-la moyenne pondérée (par exemple dans ce sujet, en fonction de la valeur trouvée dans la colonne K)
-
Bonsoir,
Je vais préciser ma question.
Ma question précédente a eu pour but de trouver le nombre de valeur supérieure à 10 se situant dans la colonne K s'il y a "cadeaux" dans la colonne A.
Maintenant je souhaite donc faire la moyenne arithmétique de ces valeurs (celle qui sont supérieurs à 10 en colonne K).
J'espère être plus clair.
Merci d'avance
Richard
-
-
Salut à tous
Code:
=SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>"")*(Analyse!$K$3:$K$4002>10)*Analyse!$K$3:$K$4002)/SOMMEPROD((SUPPRESPACE(Analyse!$B$3:$B$4002)="Cadeaux")*(SUPPRESPACE(Analyse!$K$3:$K$4002)<>"")*(Analyse!$K$3:$K$4002>10))
A+
-
Bonjour tout le monde
Il faut d'abord nettoyer les données avant de vouloir commencer la moindre analyse, sinon, c'est la catastrophe assurée.
Supprimer les espaces à droite des saisies en B
S'assurer qu'il n'y a que des valeurs numériques ou des cellules vides en K
Après, la "bête" formule suivante fonctionne
Code:
=SOMMEPROD((B3:B4000="Cadeaux")*(K3:K4000>10)*K3:K4000)/SOMMEPROD((B3:B4000="Cadeaux")*(K3:K4000>10))
Partir de données polluées amènera soit à des résultats pollués, soit à des formules brise-biscuits pour envisager tous les cas de figure.
-
Bonjour
Cette formule prendra en compte toutes les cellules qui contiennent le mot "Cadeau", donc même s'il y a un espace ou un "x" à la fin ou un style "Cadeau mystère" ou encore "Pour un cadeau":
Code:
=SOMMEPROD(ESTNUM(CHERCHE("Cadeau";B3:B4000))*(K3:K4000>10)*ESTNUM(K3:K4000))/SOMMEPROD(ESTNUM(CHERCHE("Cadeau";B3:B4000))*(K3:K4000>10))
Amicalement
Nad
-
Merci beaucoup,
J'ai fais le ménage dans le fichier: suppression des petits espaces et vérification de la colonne K.
La formule marche parfaitement.
Merci beaucoup
-
Encore moi!
J'ai voulu utiliser cette formule sur une autre colonne que K.
Code:
=SOMMEPROD((Analyse!B3:B4000="Cadeaux")*(Analyse!J3:J4000>0)*Analyse!J3:J4000)/SOMMEPROD((Analyse!J3:J4000="Cadeaux")*(Analyse!J3:J4000>0))
Et voilà le résultat #VALEUR!
Qu'est ce que cela signifie?
J'abuse un peu, je sais.
Merci beaucoup!
-
Dans la deuxième partie, tu as mis
Code:
/SOMMEPROD((Analyse!J3:J4000="Cadeaux")*(Analyse!J3:J4000>0))
au lieu de
Code:
/SOMMEPROD((Analyse!b3:b4000="Cadeaux")*(Analyse!J3:J4000>0))
Il faut bien relire la formule pour rechercher l'erreur... :roll:
-
Exact,
Mais cela ne me change pas le résultat...
Code:
=SOMMEPROD((Analyse!B3:B4000="Cadeaux")*(Analyse!J3:J4000>0)*Analyse!J3:J4000)/SOMMEPROD((Analyse!B3:B4000="Cadeaux")*(Analyse!J3:J4000>0))