Contenu des groupes dans l'AD

Version imprimable

Salut,

j'essaie de faire un peu de ménage dans mon AD, alors je veux connaitre le contenu des groupes d'une OU, jusque la tout va bien, sauf que mon script ne me ressort que les groupes ayant UN SEUL utilisateur, et je ne comprend pas pourquoi.

Normalement, il devrait tous me les sortir, avec le nom du groupe, et les utilisateurs a coté, séparés par un ";".

Voila le code

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
 
on error resume next
 
dim objfichier, Myfile, Ouchoisi
 
const forReading = 1, ForWriting = 2, ForAppending = 8
 
'routine de connexion a l'AD
 
Const ADS_SCOPE_SUBTREE = 2
 
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection
 
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
 
'choix du domaine a éxaminer
 
DomaineChoisi="XXX"			'inputbox ("veuillez Choisir le domaine que vous voulez inspecter","Choix du domaine")
 
DomaineChoisi2="local"		'inputbox ("veuillez Choisir la fin du nom de domaine que vous voulez inspecter","Choix du domaine")
 
OuChoisi=inputbox ("veuillez Choisir l'Unité d'organisation que vous voulez inspecter","Choix de l'OU")
 
'sélection de l'OU dans le domaine
 
objCommand.CommandText = _
    "SELECT AdsPath FROM 'LDAP://OU="& OuChoisi &", dc="& DomaineChoisi &", dc="& DomaineChoisi2 &"' WHERE objectCategory='group'"
Set objRecordSet = objCommand.Execute
 
'création du fichier texte
 
set objfichier = createobject("scripting.filesystemobject")
 
NomFichier="test.txt"            '   inputbox ("Veuillez entrez le nom de fichier","Nom du Fichier")
 
set Myfile = objfichier.opentextfile(NomFichier, ForWriting, true)
 
'boucle qui vérifie les groupes 1 par 1
 
objRecordSet.MoveFirst
Do Until objRecordSet.EOF
    Set objUser = GetObject(objRecordSet.Fields("AdsPath").Value)
 
	If objUser.member <> "" then
 
		Myfile.Writeline objUser.sAMAccountName & ";" & objUser.member & ";"
	End if
 
    objRecordSet.MoveNext
 
Loop
 
'message de fin d'éxecution du script
 
MsgBox "votre recherche dans l'AD est terminée", vbExclamation, "Avertissement"

J'ai essayé de modifier les valeurs sur lesquels je filtre... et pas mal d'autre trucs, et j'ai toujours seulement les groupes avec un utilisateur.

Si quelqu'un sait d'ou ca pourrais venir ce serait sympa de m'aider

merci

24/03/2009, 14h06
spantemonium
en fait tu utilises objUser.member , comme s'il n'y avait qu'une valeur unique.

alors que lorsqu'il y a plusieurs utilisateurs dans ton groupe, le résultat est une collection.

essaie cà :
Code:

1 2 3 4 5 6 objMembers = objUser.GetEx("member") For Each obj in objMembers if not obj = "" Then Myfile.Writeline obj End If
ca devrait te donner le principe, après faut adapter en fonction des infos que tu veux remonter...

OK, merci ça me permet déjà de cherche dans la bonne direction !!

et avec ta formule, comment on récupère les différents objets?

c'est comme ca?
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 objRecordSet.MoveFirst Do Until objRecordSet.EOF Set objUser = GetObject(objRecordSet.Fields("AdsPath").Value) If objUser.member <> "" then Myfile.Writeline objUser.sAMAccountName & ";" objMembers = objUser.GetEx("member") For Each obj in objMembers if not obj = "" Then Myfile.Writeline obj End If End if objRecordSet.MoveNext Loop
Par ce que du coup la il considère plus mon script comme valide et le lance plus.

j'essaie de trouver la bonne syntaxe mais je sais pas si je cherche dans la bonne direction.

merci pour ton aide en tout cas :)

plutot comme cà en fait :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
 
on error resume next
 
dim objfichier, Myfile, Ouchoisi
 
const forReading = 1, ForWriting = 2, ForAppending = 8
 
'routine de connexion a l'AD
 
Const ADS_SCOPE_SUBTREE = 2
 
Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection
 
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 
 
'choix du domaine a éxaminer
 
DomaineChoisi="XXX"			'inputbox ("veuillez Choisir le domaine que vous voulez inspecter","Choix du domaine")
 
DomaineChoisi2="local"		'inputbox ("veuillez Choisir la fin du nom de domaine que vous voulez inspecter","Choix du domaine")
 
OuChoisi=inputbox ("veuillez Choisir l'Unité d'organisation que vous voulez inspecter","Choix de l'OU")
 
'sélection de l'OU dans le domaine
 
objCommand.CommandText = _
    "SELECT AdsPath FROM 'LDAP://OU="& OuChoisi &", dc="& DomaineChoisi &", dc="& DomaineChoisi2 &"' WHERE objectCategory='group'"
Set objRecordSet = objCommand.Execute
 
'création du fichier texte
 
set objfichier = createobject("scripting.filesystemobject")
 
NomFichier="test.txt"            '   inputbox ("Veuillez entrez le nom de fichier","Nom du Fichier")
 
set Myfile = objfichier.opentextfile(NomFichier, ForWriting, true)
 
'boucle qui vérifie les groupes 1 par 1
 
 
 
 
 
'MODIFICATIONS
 
objRecordSet.MoveFirst
Do Until objRecordSet.EOF
	Set objUser = GetObject(objRecordSet.Fields("AdsPath").Value)
	membres = ""
	objMembers  = objUser.GetEx("member")
	For Each obj in objMembers  
		if not obj = "" Then
			membres = Membres & ";" & obj 
		End If
	Next
	Myfile.Writeline objUser.sAMAccountName & membres
	objRecordSet.MoveNext	
Loop
 
'message de fin d'éxecution du script
 
MsgBox "votre recherche dans l'AD est terminée", vbExclamation, "Avertissement"

24/03/2009, 16h49
geriler

C cool merci ca fonctionne ;)