[E-07] Méthode de tri tableau

Version imprimable

14/03/2009, 15h47
helprojet

[E-07] Méthode de tri tableau

Bonjour,

Je dois trier un tableau avec 5 colonnes et 41 lignes.

Voici le tableau en question : t_general(j, i)

FR0000031122 AIR FRANCE 20,66 24,1218604 0,16756343
FR0000045072 CREDIT AGRICOLE 22,46 23,2544186 0,035370374
FR0000120073 AIR LIQUIDE 91,618 80,50849612 - 0,121258965
FR0000120172 CARREFOUR 50,49 45,08139535 - 0,107122295
FR0000120271 TOTAL 57,03 50,96108527 - 0,10641618
FR0000120321 L OREAL 86,95 78,5227907 - 0,096920176

Le tableau continue comme ca sur 41 lignes.
Je souhaite le trier a partir de la colonne de droite (0,16756343) en tri décroissant. Il faut bien sur que les autres colonnes soient elles aussi triées en correspondance.

Si quelqu'un voulait bien avoir la bienveillance de mettre un algorithme de tri pour le réaliser, cela serait très gentils !!!

bonjour helprojet le forum si j ai compris!! avec l enregistreur de macros

Code:

1
2
3
4
5
6
7
Sub Macro2()
    Range("A1:E41").Select
    Range("E41").Activate
    Selection.Sort Key1:=Range("E41"), Order1:=xlDescending, Header:=xlGuess, _
     OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
     DataOption1:=xlSortNormal
End Sub

14/03/2009, 18h03
helprojet

Je me suis mal exprimé, mon tableau n'est pas sur une feuille excel, c'est juste un tableau vb avec les données suivantes que j'ai imprimées afin de montrer comment le tableau était fait.
15/03/2009, 11h57
edelweisseric

Bonjour à tous
Bonjour helprojet

Tout d'abord, pourquoi trier ? à quoi cela peut te servir ?

Ne pas oublier que de nombreuses fonctions Excel sont utilisables en VBA avec l’objet WorksheetFunction, suivi du nom en anglais de la fonction : le plus petit, le plus grand, la somme, .......

Une solution complétant celle de Laetitia : tu copies ton Tablo() sur une feuille, tu le tries et tu remets le tout dans ton Tablo(). Un peu capilotracté, mais pourquoi pas.....

Une 2ème solution : le tri à bulle ou par permutations (jamais essayé, tu trouveras des exemples sur internet)

Une 3ème solution : le tri par sélection (jamais essayé, tu trouveras des exemples sur internet)

Tu nous dis

Eric

Bonjour.

Avec 41 lignes, un tri par substitution devrait faire l'affaire.
On considère Tablo(1 to 41, 1 to 5) as variant à trier. On ajoute un tableau Index(1 to 41) as integer.
L'idée est d'enregistrer l'ordre des éléments de Tablo dans Index.
Comme j'ai un peu de temps :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Dim Tablo(1 To 41, 1 To 5) As Variant, Index() As Integer
Dim i As Integer, k As Integer, Min As Integer, iTemp As Integer
 
Const Fin As Integer = 41
Const jC As Integer = 5
 
ReDim Index(1 To Fin)
For i = 1 To Fin
    Index(i) = i
Next i
 
For i = 1 To Fin
    Min = i
    For k = i + 1 To Fin
        If Tablo(Index(k), jC) < Tablo(Index(Min), jC) Then Min = k
    Next k
    iTemp = Index(i)
    Index(i) = Index(Min)
    Index(Min) = iTemp
Next i

A partir de là, Tablo(Index(i),j) renvoie la donnée de la colonne j et la ième ligne après tri. Suivant le besoin, on peut s'arrêter là.

Maintenant si tu veux que le tri soit physiquement contenu dans le tableau, c-a-d que Tablo(i) soit la ième ligne après tri, tu peux faire

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Dim Tablo(1 To 41, 1 To 5) As Variant, Index() As Integer, v() As Variant
Dim i As Integer, k As Integer, Min As Integer, iTemp As Integer
 
Const Fin As Integer = 41
Const jC As Integer = 5
 
ReDim Index(1 To Fin)
For i = 1 To Fin
    Index(i) = i
Next i
 
For i = 1 To Fin
    Min = i
    For k = i + 1 To Fin
        If Tablo(Index(k), jC) < Tablo(Index(Min), jC) Then Min = k
    Next k
    iTemp = Index(i)
    Index(i) = Index(Min)
    Index(Min) = iTemp
Next i
 
v = Tablo()
For i = 1 To Fin
    For k = 1 To jC
        Tablo(i, k) = v(Index(i), k)
    Next k
Next i
 
Erase Index()
Erase v()

Bon dimanche,

PGZ

15/03/2009, 14h52
helprojet

Merci pour ce programme, je vais le tester cette apres-midi.

Pour ce type de tableau de taille moyenne, ou tous les elements sont rangés de facon très aléatoire, votre algorithme est l'un des plus efficaces ?
15/03/2009, 16h15
pgz

Re,

Cet algo est efficace parce qu'on ne déplace les valeurs qu'une fois : on fait le tri sur un index.
La métode de tri est optimale pour environ 10 lignes.
Pour 41 lignes ce n'est pas le mieux, mais le plus simple sans que la pénalité soit bien lourde.

PGZ