Récupérer des données sur une page HTML

Version imprimable

18/11/2005, 13h15
rupeni

Récupérer des données sur une page HTML

bonjour,

je galère pour faire la partie suivante de mon programme. je souhaite aller chercher des données numériques sur une page HTML. elles se trouvent entre les balises BODY et sont disposées comme ci-dessous :

<body>
45.23
46.22
57.24
37.02
</body>

je souhaite donc récupérer les chiffres entre les balises P et leur affecter un nom de variable utilisable pour toute la suite du programme, par exemple avoir un tableau partant de 1 tel que : a(1)=45.23, a(2)=46.22, a(3)=57.24, a(4)=37.02.
En fait je souhaite utiliser les données pour faire des calculs et des graphiques donc il me faudrait probablement un tel tableau utilisable dans tout le programme.

Mais pour ça je galère pas mal alors SVP aidez-moi !
18/11/2005, 13h30
Xo

Salut,

Pour traiter un cas comme ça, je ferais la chose suivante :

Déclaration d'un tableau dynamique de type chaîne,
Ouverture de mon fichier en accès séquentiel (Input),
Lecture ligne à ligne, avec pour chaque ligne :
__recherche de la chaîne 
____si trouvée, recherche de la chaîne et ajout à mon tableau d'une nouvelle valeur obtenue en tronquant la ligne là ou il faut,
Fermeture du fichier.

A améliorer un peu si il arrive qu'une balise fermante puisse ne pas se trouver sur la même ligne que la balise ouvrante correspondante !

Si une étape te pose problème, indique-nous laquelle ;)

Bonjour,

Il y a enormement de moyens de faire ça, algorithmiquement, tu peux faire ceci ( je ne vais pas coder le programme correspondant, mais je te donne l'idée ) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Initialiser le tableau avec une taille suffisante
Initialiser le compteur de ton tableau de flottants à 0
Ouvrir le fichier html
Boucler sur chaque ligne (séparées par un retour chariot)
    si en début il y a <p>
        Prendre la sous-chaine entre la fin du <p> et le début du </p>
        Transformer cette sous-chaine en flottant
        Ajouter la valeur au tableau
        Incrémenter le compteur
    fin si
Fin boucle
 
' ici tu as donc ton tableau rempli

18/11/2005, 13h31
SfJ5Rpw8

sinon ton fichier html ... il contient autre chose que tes balises... ( tu n'as pas une adresses internet à nous montrer ...)
:wink:
18/11/2005, 13h34
rupeni

j'ai une suggestion.
peut-être est-il possible de faire le code HTML sur une seule ligne (c'est-à-dire "coller" toutes les balises les unes aux autres) puis aller chercher tout le code HTML. On l'affecte ensuite à une variable, par exemple codehtml : codehtml = "<html><head>...</head><body>[ici se trouvent les données]</body></html>".
Puis on va de balise en balise et on récupère les données numériques en les affectant à une variable et ce jusqu'à ce que l'on soit arrivé à la balise </body>.
Je ne sais pas si c'est faisable...
18/11/2005, 13h37
rupeni

merci KiLVaiDeN, je vais essayer d'écrire le code correspondant.

j'ai pas d'adresse à donner en exemple puisque ce sera moi qui créerait le site. En fait c'est une simulation mais qui doit impérativement s'appuyer sur une page web.
18/11/2005, 13h43
rupeni

Citation:

Envoyé par bbil

sinon ton fichier html ... il contient autre chose que tes balises... ( tu n'as pas une adresses internet à nous montrer ...)
:wink:

bah, il n'y a que des balises. C'est une page web toute simple pour ne pas trop compliquer les choses...
18/11/2005, 13h46
rupeni

merci aussi à Xo
18/11/2005, 13h51
rupeni

Xo,

je ne sais pas trop comment faire la lecture ligne à ligne ainsi que tronquer (du moins je ne connais pas les codes).
Si tu pouvais me donner ne serait-ce qu'un exemple, j'apprécierais.

tu peu aussi faire appel au controle internet ( rajoute référence à Microsoft internet control et Microsoft Htlm library ...)

et ainsi :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Sub MajTableau(A() As Single)
 Dim i As Integer
 Dim IE As InternetExplorer
      Set IE = CreateObject("InternetExplorer.Application")
    IE.Visible = True ' On peu mettre false...
 
  Dim t As Date
  IE.Navigate "d:\tmp\toto.html" 'Changer ici l'url...
  t = Now + TimeValue("00:00:30") 'Time-Out De 30 s sur chargement ...
  Do Until IE.ReadyState = READYSTATE_COMPLETE
  DoEvents
    If Now > t Then
      MsgBox "Temps de chargement trop long ", vbCritical
    Exit Sub
    End If
  Loop
 i = 0
 Dim HAC As IHTMLElementCollection
 Dim HA As IHTMLElement
 Set HAC = IE.Document.getElementsByTagName("P")
 For Each HA In HAC
  ReDim Preserve A(i)
 
   A(i) = Val(HA.innerText)
  i = i + 1
 Next
 
 IE.Quit
End Sub
 
Sub test()
  Dim A() As Single
  Dim i As Integer
  MajTableau A
  For i = 0 To UBound(A)
    Debug.Print A(i)
  Next
End Sub

:roll: :wink:

Citation:

Envoyé par rupeni

je ne sais pas trop comment faire la lecture ligne à ligne ainsi que tronquer (du moins je ne connais pas les codes).
Si tu pouvais me donner ne serait-ce qu'un exemple, j'apprécierais.

Avec un TextBox nommé txtFichier qui contient le chemin complert de mon fichier, Ajoute un Button nommé cmdOpen et copie le code suivant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Private Sub cmdOpen_Click()
    'Fichier
    Dim canal As Byte
    Dim chaine As String
 
    'Balises et positions
    Dim baliseOuv As String, baliseFin As String
    Dim posDeb As Integer, posFin As Integer
 
    'Valeurs à récupérer
    Dim mesValeurs() As String
    Dim nbVal As Integer
 
    'indice de boucle
    Dim i As Integer
 
    'Initialisation
    baliseOuv = "<p>"
    baliseFin = "</p>"
 
    nbVal = 0
    ReDim mesValeurs(0)
 
    'Ouverture fichier
    canal = FreeFile
    Open txtFichier.Text For Input As #canal
 
    Do While Not EOF(canal)
        'Récupération d'une ligne
        Line Input #canal, chaine
 
        'Traitement
        'Recherche de balise ouvrante :
        posDeb = InStr(chaine, baliseOuv)
 
        'si balise ouvrante détectée :
        If posDeb > 0 Then
            'Recherche de balise fermante :
            posFin = InStr(chaine, baliseFin)
 
            If posFin >= posDeb + Len(posDeb) Then
                ReDim Preserve mesValeurs(nbVal)
                mesValeurs(nbVal) = Mid(chaine, posDeb + 3, posFin - posDeb - 3)
                nbVal = nbVal + 1
            Else
                'pas de balise fermante
            End If
        End If
    Loop
    Close canal
 
    'Vérification
    For i = 0 To nbVal - 1 'ou Ubound(mesValeurs)
        Debug.Print "A(" & i & ") = " & mesValeurs(i)
    Next i
End Sub

J'ai testé ce code avec ton fichier, en rajoutant qq caractères parasites :

Code:

1
2
3
4
5
6
<body>
<p>45.23</p>
<p>46.22</p>
bla bla <p>57.24</p> bla bla
<p>37.02</p>
</body>

Ce code ne fonctionne pas si une balise fermante n'est pas sur la même ligne qu'une balise ouvrante, mon temps de pause est dépassé :P

18/11/2005, 17h22
rupeni

ok, merci pour votre aide, je vais travailler ça chez moi ce soir.