Shell, attendre fin exe avant continuer macro

Bonjour,

J'ai une macro VBA sous excel 2003 qui lance un exe et qui va ensuite chercher des infos dans un txt généré par l'exe et affiche le contenu.

Mon souci est que la macro n'attend pas que l'exe soit fini avant d'aller lire le txt ...

Est-ce qu'il existe une ligne de commande similaire à Shell qui permet de lancer un exe et d'attendre sa fin ?

Merci

Bonjour,

essaie
Code:

1 2 doevents
après le shell.

Sinon, essaie avec application.wait un délai raisonnable.

bonjour le fil,
tu peux essayer

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Option Explicit

'attente fin processus
Declare Function OpenProcess Lib "kernel32" _
        (ByVal dwDesiredAccess As Long, _
        ByVal bInheritHandle As Long, _
        ByVal dwProcessId As Long) As Long

Declare Function GetExitCodeProcess Lib "kernel32" _
        (ByVal hProcess As Long, _
        lpExitCode As Long) As Long

Public Const PROCESS_QUERY_INFORMATION = &H400
Public Const STILL_ACTIVE = &H103

Public Sub ShellAndWait(ByVal PathName As String, Optional WindowState)
    Dim hProg As Long
    Dim hProcess As Long, ExitCode As Long
    If IsMissing(WindowState) Then WindowState = 1
    hProg = Shell(PathName, WindowState)
    hProcess = OpenProcess(PROCESS_QUERY_INFORMATION, False, hProg)
    Do
        GetExitCodeProcess hProcess, ExitCode
        DoEvents
    Loop While ExitCode = STILL_ACTIVE
End Sub

Sub TestDePatience()
Dim ShellStr As String
'ici tu remplace Shellstr par ta commande
'probablement
'    Path & "\" & "file_analyzer.exe"     
    ShellAndWait ShellStr, vbHide
End Sub

@+:D

Merci avec le bout de code ça marche :)