[E-03] importer des données internet sur excel - référence Microsoft Internet Control

Version imprimable

Bonjour à tous,

Je souhaite importer des données depuis un site web comme boursorama dans un fichier excel. J'ai fait quelques recherches sur le forum et j'ai trouvé le code suivant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
Sub Importer_tableauPageWeb()
    'Nécessite d'activer les références:
        'Microsoft HTML Objects Library
        'et
        'Microsoft Internet Controls
    Dim IE As InternetExplorer
    Dim maPageHtml As HTMLDocument
    Dim Htable As IHTMLElementCollection
    Dim maTable As IHTMLTable
    Dim j As Integer, i As Integer
 
    Set IE = CreateObject("InternetExplorer.Application")
    IE.Visible = True
 
 
    IE.navigate "http://www.mapageperso.html"
        'Attend la fin du chargement pour continuer la procédure
        Do Until IE.readyState = READYSTATE_COMPLETE
        DoEvents
    Loop
 
    Set maPageHtml = IE.document
    'objet type table
    Set Htable = maPageHtml.getElementsByTagName("table")
    'premier tableau dans la page Web
    Set maTable = Htable(0)
 
    'boucle sur toutes les lignes du tableau
    For i = 1 To maTable.Rows.Length
        'boucle sur les cellules dans chaque ligne
        For j = 1 To maTable.Rows(i - 1).Cells.Length
            'Transfert les données dans la feuille de calcul
            Cells(i, j) = maTable.Rows(i - 1).Cells(j - 1).innerText
        Next j
    Next i
 
    IE.Quit
    Set IE = Nothing
 
End Sub

J'ai bien activé la référence HTML mais je ne trouve pas "Microsoft Internet Controls". (je suis sous Excel 2003 comme dit dans le titre)
Du coup le code ne donne rien. :?
Quelqu'un aurait-il la solution ou du moins une piste?
Merci d'avance,

Question subsidiaire : que faut-il changer dans le code pour utiliser Mozilla?

05/02/2009, 18h40
SilkyRoad

bonsoir

Citation:

je ne trouve pas "Microsoft Internet Controls".

Quelle version d'internet explorer utilises tu ?

bonne soirée
michel
06/02/2009, 09h04
kokoVBA

Bonjour SilkyRoad,

j'utilise IE 7.0 (version du boulot, je n'ai pas les droits d'admin sur cet ordi)

Bonne matinée
06/02/2009, 12h13
SilkyRoad

bonjour

Sans garantie (et qui n'expliquera pas pourquoi tu ne trouves pas la bibliothèque), fait un essai en remplaçant

Code:

Dim IE As InternetExplorer

par

Code:

Dim IE As Object

et

Code:

Do Until IE.readyState = READYSTATE_COMPLETE

par

Code:

Do Until IE.readyState = 4

bonne journée
michel
06/02/2009, 12h51
fred65200

bonjour,

Si tu ne trouves pas la référence Microsoft Internet Controls, tu peux cliquer sur Parcourir dans la fenêtre des références et la trouver c:\Windows\System32\ieframe.dll.

Cordialement

Bonjour SilkyRoad, bonjour fred65200,

merci pour vos réponses, je viens de tester la proposition de SilkyRoad et ça marche! :king:
Voici donc un exemple de code qui fonctionne bien, il est nécessaire d'activer "Microsoft HTML objects Library", mais pas "Microsoft Internet Controls" :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Sub Importer_tableauPageWeb_v2()
    'Nécessite d'activer les références:
        'Microsoft HTML Objects Library
 
    Dim IE As Object
    Dim maPageHtml As HTMLDocument
    Dim Htable As IHTMLElementCollection
    Dim maTable As IHTMLTable
    Dim j As Integer, i As Integer
 
    Set IE = CreateObject("InternetExplorer.Application")
    IE.Visible = True
 
 
    IE.navigate "http://www.boursorama.com/tableaux/cours_az.phtml?MARCHE=1rPCAC"
        'Attend la fin du chargement pour continuer la procédure
        Do Until IE.readyState = 4
        DoEvents
    Loop
 
    Set maPageHtml = IE.document
    'objet type table
    Set Htable = maPageHtml.getElementsByTagName("table")
    '3ème tableau dans la page Web ("0" est le premier tableau)
    Set maTable = Htable(2)
 
    'boucle sur toutes les lignes du tableau
    For i = 1 To maTable.Rows.Length
        'boucle sur les cellules dans chaque ligne
        For j = 1 To maTable.Rows(i - 1).Cells.Length
            'Transfert les données dans la feuille de calcul
            Cells(i, j) = maTable.Rows(i - 1).Cells(j - 1).innerText
        Next j
    Next i
 
    IE.Quit
    Set IE = Nothing
 
End Sub

edit : je viens de rentrer chez moi et le même code ne fonctionne plus sur mon ordi perso. il bug à :

Code:

Do Until IE.readyState = READYSTATE_COMPLETE

et idem avec :

Code:

Do Until IE.readyState = 4

je precise que je suis cette fois sur vista alors que je suis sur XP au boulot. Dois-je faire des réglages supplémentaires?

Merci encore pour votre précieuse aide et bonne journée à tous!

12/02/2009, 19h26
kokoVBA

Pas de réponses par rapport à la dernière question? (pourquoi le même code marche-t-il sous xp et pas sous Vista):cry:
Bon je clique quand même résolu parce que le problème initial a été résolu (merci d'ailleurs :D )