série d'actions automatique

Version imprimable

Bonjour,

pour un fichier de tracking, j'aurais besoin d'une commande pour exécuter automatiquement une série d'action.

Concrètement, j'ai un code barre que je scanne avec une douchette dans une cellule, mais je bosse sur un système anglais, et donc le "1" c'est une "&", le "2" un "é" etc. car la douchette ne fonctionne qu'avec un qwerty. Ne pouvant décemment pas bosser en QWERTY, je voudrais qu'une fois scanné, les caractères soient remplacés automatiquement, pour passer de "CD)àçà&)ààé_" à "CD-0901-0028" sans appuyer sur un bouton.

voilà mon code actuel, le pbl c qu'il plante à chaque utilisation et ça tourne en boucle :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 Private Sub Worksheet_Change(ByVal Target As Range) If Target.Address = "$C$5" Then Cells(5, 3) = Replace(Cells(5, 3), "&", "1") Cells(5, 3) = Replace(Cells(5, 3), "é", "2") Cells(5, 3) = Replace(Cells(5, 3), """", "3") Cells(5, 3) = Replace(Cells(5, 3), "'", "4") Cells(5, 3) = Replace(Cells(5, 3), "(", "5") Cells(5, 3) = Replace(Cells(5, 3), "-", "6") Cells(5, 3) = Replace(Cells(5, 3), "è", "7") Cells(5, 3) = Replace(Cells(5, 3), "_", "8") Cells(5, 3) = Replace(Cells(5, 3), "ç", "9") Cells(5, 3) = Replace(Cells(5, 3), "à", "0") Cells(5, 3) = Replace(Cells(5, 3), ")", "-") End If End Sub
Merci d'avance,
Phil....

Bonjour

C'est normal que cela plante, en effet tu demandes le changement de la valeur en C5, du coup lorsque tu changes celle-ci tu relances l'événement Change.

Essayes un code de ce type

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Worksheet_Change(ByVal Target As Range)
 
        If Target.Address = "$C$5" Then
            Select Case Target.Value
                Case "&"
                    Cells(5, 3) = Replace(Cells(5, 3), "&", "1")
 
                Case "é"
                    Cells(5, 3) = Replace(Cells(5, 3), "é", "2")
                Case Else
            End Select
        End If
End Sub

Je te laisse tester et faire la suite, je l'ai tapé à la main, sans test.

Philippe

02/02/2009, 17h38
TaleMaker

et bien j'ai tout tapé, mais rien ne change en fait.... à part que ça plante plus, mais les caractères restent inchangés....
02/02/2009, 18h39
Invité

Re

Pourtant chez moi, le bout de code que je t'ai donné marche, je viens de tester sur Excel 2002 et Excel 2007.

Philippe

Bonjour,

cela tient au fait que ta cellule n'est pas = lecaractère mais contient le caractère...
Tu pourrais utiliser Like ou Instr, pour vérifier, mais .....inutilement long. Tu ferais aussi bien de remplacer sans même t'en préoccuper, ainsi :
Code:

1 2 3 4 5 6 7 If Target.Address = "$C$5" Then lescars = Array("é", """", "'", "(", "-", "è", "_", "ç", "à", ")") mescars = Array("2", "3", "4", "5", "6", "7", "8", "9", "0", "-") for i = 0 to ubound(lescars) Cells(5, 3) = Replace(Cells(5, 3), lescars(i), mescars(i)) next End If
ceci étant dit, j'ai quelques inquiétudes car tu remplaces "-" par "6" et que tu remplaces ")" par "-".
Pour peu que tu rencontres d'abord un ")", il sera remplacé par "-", puis, donc, par "6" !!!

02/02/2009, 19h29
TaleMaker

C'est un peu ce que j'avais fait, avec une boucle, mais oui, le pbl c la triplette ") - 6" qui risque de faire chier, mais les - sont tjs à la mm place, donc limite, ça se règle facilement....

Mais le pbl, c que ça tourne tjs en boucle.

Et avec le code de Philippe, rien ne se passe. J'ai rajouté tous les caractères pourtant, g testé avec la douchette, à la main, et aucun des caractères ne change.... :?
02/02/2009, 19h35
Pierre Fauconnier

Citation:

Envoyé par ucfoutu

...
ceci étant dit, j'ai quelques inquiétudes car tu remplaces "-" par "6" et que tu remplaces ")" par "-".
Pour peu que tu rencontres d'abord un ")", il sera remplacé par "-", puis, donc, par "6" !!!

Est-ce que tu n'évites justement pas ce problème puisque, avec les arrays tels que tu les as écris, on rencontrera "-" avant de rencontrer ")"...

Me trompé-je?
02/02/2009, 19h48
TaleMaker

Citation:

Envoyé par Pierre Fauconnier

avec les arrays tels que tu les as écris, on rencontrera "-" avant de rencontrer ")"...

Dans l'absolu, le pbl n'en est pas vraiment un puisque en effet, les caractères sont changés dans l'ordre, et donc chacun est remplacé par le bon, y compris le ) qui devient un -.... le pbl, c qu'une fois à la fin du code, ça tourne en boucle et le nouveau - devient 6 au 2e passage.... et le code ne termine pas....

Il faut inhiber la gestion des événements
Code:

1 2 3 4 5 6 7 8 9 10 11 On Error goto fin If Target.Address = "$C$5" Then application.enableevents = false ... ... application.enableevents=true end if Fin: application.enableevents = true
Surtout, ne pas oublier la gestion d'erreur et le basculement à TRUE en fin de procédure

02/02/2009, 19h55
ucfoutu

Citation:

Envoyé par Pierre Fauconnier

Est-ce que tu n'évites justement pas ce problème puisque, avec les arrays tels que tu les as écris, on rencontrera "-" avant de rencontrer ")"...

Me trompé-je?

tu as raison (donc pas de problème dans cet ordre là)
Il est toutefois nécessaire, alors, de ne pas risquer un "double-lancement" car sinon "badaboum". La chose est à mon sens évitable avec une simple variable booléenne static pour éviter la répétition du traitement.

donc compliant toutes vos réponses, j'arrive à ça :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$C$5" Then
        Application.EnableEvents = False
        lescars = Array("&", "é", """", "'", "(", "-", "è", "_", "ç", "à", ")")
        mescars = Array("1", "2", "3", "4", "5", "6", "7", "8", "9", "0", "-")
        For i = 0 To UBound(lescars)
            Cells(5, 3) = Replace(Cells(5, 3), lescars(i), mescars(i))
        Next
        GoTo fin
    End If
fin:
    Application.EnableEvents = True
End Sub

et c bon, ça marche niquel, plus de boucle, pas de pbl de -, tout marche niquel.

Merci à tous....

02/02/2009, 20h50
Pierre Fauconnier

Si je puis me permettre...

Le Goto Fin n'est pas nécessaire. Par contre, ce qui le serait, c'est la gestion d'erreur avec On Error goto fin en début de procédure.

Pourquoi? Si, pour une raison ou une autre (cellule verrouillée, ...) il y a une erreur d'exécution, tu vas stopper le code, mais les événements resteront désactivés, ce qui risque bien sûr de poser problème.
03/02/2009, 13h33
TaleMaker

Citation:

Envoyé par Pierre Fauconnier

Si je puis me permettre...

Le Goto Fin n'est pas nécessaire. Par contre, ce qui le serait, c'est la gestion d'erreur avec On Error goto fin en début de procédure.

En effet, très judicieux, merci....