Ajout d'un popupmenu a un Combobox

Version imprimable

16/12/2008, 13h15
cmon_compte

Ajout d'un popupmenu a un Combobox

Bonjour ,je voudrai savoir s'il est possible d'ajouter un popupmenu a un combobox sachant que l'evemnement qui doit déclancher le popupmenu est le click droit de la souris (sachant aussi que le combobox a par defaut sont popupmenu donc comment le désactiver et le remplacer avec un autre )
"sous vb6"
merci.
19/12/2008, 22h42
ucfoutu

Bonsoir,

Importance des mots ...!!!

1) le click sur une combo ne peut être reconnu que dans la zone de liste de la combo
2) la zone "éditable" ne répond pas à un évènement pouvant reconnaître, depuis VB, le bouton utilisé
3) la seule "pop-up" que je voie personnellement s'appelle le menu contextuel ouvert par VB sur click droit dans la zone éditable ...

Il va donc te falloir (c'est indispensable) être extrêmement précis sur ces points, en précisant (avec détails) ce que tu veux modifier, en cliquant sur quoi précisément et dans quel but précis ...
20/12/2008, 11h00
cmon_compte

Précision

En bref
Je veux afficher un menu contextuel en cliquant sur la zone éditable d’un combo box (avec un liste box ça marche très bien)
20/12/2008, 11h41
ucfoutu

Une listbox n'a pas de zone éditable...
Il ne t'est donc possible, dans une listbox, que d'ajouter un menu contextuel lors d'un évènement de souris dans la liste elle-même
Tu pourrais faire exactement la même chose, avec une combobox, mais également dans la zone de liste, pas dans la zone éditable qui, elle, n'est pas capable re reconnaître depuis VB le bouton pressé ...
Rien, ne t'empêche, maintenant, de reconstituer une combobox, qui n'est jamais que l'association d'une zone éditable (que tu peux remplacer par une textbox que tu peux doter d'un menu contextuel personnalisé) et d'une zone de liste (que tu peux remplacer par une listbox).
Tout celà, maintenant (je répète ma question) : pourquoi (dans quel but exact) ?.. car si cela se trouve, il y a peut-être beaucoup plus simple à mettre en oeuvre (si c'est par exemple pour empêcher un "coller" !...)
20/12/2008, 13h22
cmon_compte

je viens de comprendre :aie: j''ai suivi ton conseil j'ai reconstituer un combocox
mais le hik c'est meme le textbox me donne un menu contextuel par defaut
qui s'affiche avec le click droit 8O

pour ta question : mon but avec le menu contextuel et le combobox c'est de pouvoir faire des mise a jour proposer dans le menu contextuel sur l'element selectionné dans le combo box tout en sachant que ce dérnier est dynamique

Citation:

Envoyé par cmon_compte

je viens de comprendre :aie: j''ai suivi ton conseil j'ai reconstituer un combocox
mais le hik c'est meme le textbox me donne un menu contextuel par defaut
qui s'affiche avec le click droit 8O

pour ta question : mon but avec le menu contextuel et le combobox c'est de pouvoir faire des mise a jour proposer dans le menu contextuel sur l'element selectionné dans le combo box tout en sachant que ce dérnier est dynamique

Bon...
Il faut alors que tu saches ce qui suit :
Il est toujours possible de supprimer ou modifier le menu contextuel d'une textbox, mais la chose passe nécessairement par le sous-classement (par Fonctions de l'Api de Windows) et on peut alors décider :
- soit de supprimer carrément le menu contextuel et d'écrire une code VB pour ouvrir une pop-up (à fabriquer) au click droit
- soit de substituer (-plus dur encore) au menu originel un menu "sur mesure"

Dans les deux cas de figure ci-dessus, une très bonne connaissance du sous-classement (toujours dangereux pour une appli si on ne sait pas le gérer parfaitement) est absolument indispensable.

Ce que tu exposes ne me parais pas nécessiter cette acrobatie (correspond-elle d'ailleurs aux connaisances que tu possèdes ?), puisqu'au bout du compte, ce que tu veux est (citation)

Citation:

"pouvoir faire des mise a jour proposer dans le menu contextuel sur l'element selectionné dans le combo box"

Il te suffit alors d'un simple bouton additionnel contenant ton code et utilisant l'article sélectionné ! Ou encore (si tu veux éviter le bouton additionnel) d'utiliser l'évènement click-droit sur l'article sélectionné pour exécuter tes instructions !...

EDIT et afin qu'il n'y ait aucune espèce d'ambiguïté :

Il est clair que ce que je te propose s'applique au cas de la substitution (à la combobox) d'une textbox et d'une listbox, hein ...

et voilà comment récupérer l'article sélectioonné par ce click droit sur l'article PREALABLEMENT SELECTIONNE :
Code:

1 2 3 4 5 Private Sub List1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single) If Button = 2 Then MsgBox "tu as cliqué sur l'article " & List1.ListIndex & " qui dit " & List1.List(List1.ListIndex) End If End Sub
C'est tout et c'est simple ...

Et si tu veux maintenant imiter la combo, voilà ...

Une Form avec, dessus, une listbox List1 et une textbox Text1
et un Module.bas

Dans le module.bas :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Public Sub traitons(F As Form, LB As ListBox, TB As TextBox) ', evenement As String)
  Select Case LCase(TypeName(F.ActiveControl))
    Case "listbox"
      TB.Text = LB.List(LB.ListIndex)
      TB.Tag = LB.ListIndex
      TB.SelStart = 0
      TB.SelLength = Len(TB.Text)
      LB.Visible = False
    Case "textbox"
      If TB.Text = "" Then Exit Sub
      Dim monindice As Long, moncontenu As String
      monindice = F.ActiveControl.Tag
      moncontenu = F.ActiveControl.Text
      MsgBox "montre ici ta popup et mets-y du code se référant à l'article " & vbCrLf & _
      "d'indice " & monindice & vbCrLf & _
      "et contenant " & moncontenu
  End Select
End Sub

Et sur ta Form :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub Form_Load()
 'juste de qui peupler pour des essais
 For i = 1 To 10
   List1.AddItem "a" & i
 Next
 List1.Visible = False
 Text1.Text = ""
 '=====================================================================================
 'juste pour placer (en exemple) les 2 contrôles)
 'toi, tu les places en mode création ...
 Me.ScaleMode = vbTwips
 Text1.Move Me.Width / 3, 150, 1500, 170
 List1.Move Text1.Left, Text1.Top + Text1.Height, Text1.Width, 2000
End Sub


'==============Voilà le seul code à copier sur ta Form (le reste est a faire en mode création)==========
Private Sub List1_Click()
  traitons Me, ActiveControl, Text1
End Sub

Private Sub Text1_DblClick()
  traitons Me, List1, ActiveControl
End Sub

Private Sub Text1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
   List1.Visible = True
End Sub

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
  List1.Visible = False
End Sub

Ce que j'ai mis en rouge dans le code de la Form n'est là que pour la démo, hein...
Toi, tu places tes contrôles en mode création et n'as pas besoin de faire celà .

Voilà l'idée (elle est simple)
Lance, sélectionne un article, vois, double-clique sur la textbox après une sélection et vois (c'est auto explicite)
Peaufine ensuite comme tu l'entends

=========================E D I T ==========================

Si tu as compris ce qui est au dessus, mais que tu veux pouvoir agir au click droit sur la textbox, maintenent ...

J'ai voulu essayer de voir si l'on pouvait faire quelque-chose sans mettre en oeuvre du trop complexe et risqué.
On le peut ...

Exemple avec une textbox Text1 et un module bas :

dans le module bas :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Explicit
Declare Function SetWindowLong& Lib "user32" Alias "SetWindowLongA" (ByVal hwnd&, ByVal nIndex&, ByVal dwNewLong&)
Declare Function CallWindowProc& Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc&, ByVal hwnd&, ByVal uMsg&, ByVal wParam&, ByVal lParam&)
Dim FP As Long
 
Function procedure(ByVal hwnd&, ByVal uMsg&, ByVal wParam&, ByVal lParam&) As Long
    If uMsg = &H7B& Then uMsg = 0 ' on inhibe le menu contextuel de la textbox
    procedure = CallWindowProc(FP, hwnd, uMsg, wParam, lParam)
End Function
 
Sub definir_si_menu(la_textbox As TextBox, menu_permis As Boolean)
  If menu_permis Then
    If FP Then SetWindowLong la_textbox.hwnd, -4, FP
  Else
    Dim R As Long
    R = SetWindowLong(la_textbox.hwnd, -4, AddressOf procedure)
    If FP = 0 Then FP = R
  End If
End Sub

Sur ta Form :

Code:

1
2
3
4
5
6
7
8
9
10
Private Sub Form_Activate()
  definir_si_menu Text1, False ' ici on zigouille le menu contextuel
End Sub
 
Private Sub Text1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  ' et ici tu envoies ta pop-up avec ce que tu veux
  If Button = 2 And Text1.Text <> "" Then
    MsgBox "voilà, ami ... mets-à la place de cette msgbox l'appel de ta pop-up ...)"
  End If
End Sub

Dans le code précédent (avant l'édit) :
Suppression de :

Code:

1
2
3
Private Sub Text1_DblClick()
  traitons Me, List1, ActiveControl
End Sub

à remplacer donc par :

Code:

1
2
3
4
5
6
Private Sub Text1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  ' et ici tu envoies ta pop-up avec ce que tu veux
  If Button = 2 And Text1.Text <> "" Then
    MsgBox "voilà, ami ... mets-à la place de cette msgbox l'appel de ta pop-up ...)"
  End If
End Sub

tout le reste étant inchangé...
Bon Week-End.