[VBS] Retour d'un UPLOAD FTP

Version imprimable

02/12/2008, 22h03
bodbod

[VBS] Retour d'un UPLOAD FTP

Bonjour,

J'ai un script qui à la fin de son traitement envoi un fichier excel sur un serveur FTP.

J'utilise donc le code suivant :

Code:

WSHShell.Run "ftp.exe -s:" & FicTemp, 0 , True

Dans le fichier Temp se trouve les commandes FTP (open->login->pass->PUT).
Mon problème est que parfois il y a un souci pendant le transfert (réseau ou mémoire tampon...) ce qui fait que mon fichier Excel devient illisible.

Comment puis je tester la bonne exécution de l'UPLOAD ?
Est il possible de récupérer la sortie (comme ce qui s'écrit en mode invite de commande par exemple) ?

Pour info, j'utilise Run plutôt que Exec car je n'ai pas trouvé comment "cacher" l'exécution avec Exec (exécution silencieuse).

Merci.
02/12/2008, 22h48
SfJ5Rpw8

J'ai pas trop d'idée .. ce soir..

tu peu passer par un .bat :

Code:

WSHShell.Run "envoi.bat", 0 , True

envoi.bat

Code:

ftp -s:envoi.ftp > liste.txt

puis tu relis le fichier liste.txt...
03/12/2008, 21h38
bodbod
Citation:

Envoyé par bbil

J'ai pas trop d'idée .. ce soir..

tu peu passer par un .bat :

Code:

WSHShell.Run "envoi.bat", 0 , True

envoi.bat

Code:

ftp -s:envoi.ftp > liste.txt

puis tu relis le fichier liste.txt...

Merci pour ton info.

J'aurais préféré resté en VBscript mais comme cette solution marche, je vais partir la dessus.

Je trouve bien les lignes de retour dans le fichier
Code:

1 2 3 4 ... 150 Ok to send data. 226 File receive OK. ftp : 6185 octets envoy‚s en 0,00 secondes … 6185000,00 Ko/sec.
Me reste plus qu'a lire le ichier derriere l'éxécution du .bat.
03/12/2008, 23h05
SfJ5Rpw8
Bonsoir,

l'on peu se passer du .bat :
Code:

1 2 3 Dim WshShell Set WshShell = CreateObject("WScript.Shell") WSHShell.Run "cmd /c ftp -s:envoi.ftp > result.txt" , 0 , True
PS : bodbod .. à l'occasion si tu fini par écrire une fonction .vbs d'envoi de fichier (par exemple en générant le fichier script ftp..) puis en lisant le résultat..
cela pourrai devenir une bonne contribution ;)
04/12/2008, 09h46
bodbod
Citation:
Envoyé par bbil

Bonsoir,

l'on peu se passer du .bat :

Code:

1 2 3 Dim WshShell Set WshShell = CreateObject("WScript.Shell") WSHShell.Run "cmd /c ftp -s:envoi.ftp > result.txt" , 0 , True

PS : bodbod .. à l'occasion si tu fini par écrire une fonction .vbs d'envoi de fichier (par exemple en générant) le fichier script..) puis en lisant le résultat..
cela pourrai devenir une bonne contribution ;)
Il me semble avoir essayer cela sans succès. Mais je vais retester avec un mini code (non intégré avec le reste de mon code).

Bien vu, j'avais effectivement l'intention de mettre cela dans une fonction (génération du fichier de commande, puis envoi, puis controle).

Je vais voir cela d'ici quelques jours.
05/12/2008, 21h42
bodbod
Citation:
Envoyé par bbil

Bonsoir,

l'on peu se passer du .bat :

Code:

1 2 3 Dim WshShell Set WshShell = CreateObject("WScript.Shell") WSHShell.Run "cmd /c ftp -s:envoi.ftp > result.txt" , 0 , True

PS : bodbod .. à l'occasion si tu fini par écrire une fonction .vbs d'envoi de fichier (par exemple en générant le fichier script ftp..) puis en lisant le résultat..
cela pourrai devenir une bonne contribution ;)
Bon j'ai retesté calmement avec un fichier de commande OK.
Effectivement ca marche nickel depuis VBS avec la commande suivante (il faut appeller cmd et non ftp directement)

Code:

WSHShell.Run "cmd /c ftp.exe -s:" & FicTemp & " > retour.txt", 0 , True

Me reste plus qu'a coder la mini fonction pour contrôler le fichier de retour.

Merci bbil

J'essai de vous faire une petite fonction d'envoi+controle la semaine prochaine

Bon, j'ai commencé a ecrire la petite fonction.

Mais comme dans le topic suivant, j'ai un souci avec le SHELL a l'interieur d'une fonction (function).

Lorsque j'insère le code dans un SUB, ca marche nickel mais je ne peux pas avoir de valeur de retour indiquant le résultat du transfert.
Lorsque je le mets dans une fonction, j'ai bien un True/False mais le shell ne fonctionne plus (donc toujours False).

Le FTP ne fonctionne pas :
Code:

1 2 3 4 5 6 7 8 9 10 Function Function_UploadByFTP(ByVal FichierLocal, ByVal Repertoire, ByVal FichierFTP, ByRef Retour) [...] Écriture du fichier de commande FTP [...] Set WSHShell = CreateObject("WScript.Shell") WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True [...] Vérification du fichier de retour [...] End Function
Ce code fonctionne mais je ne peux pas avoir de retour True/False
Code:

1 2 3 4 5 6 7 8 9 10 Sub Sub_UploadByFTP(ByVal FichierLocal, ByVal Repertoire, ByVal FichierFTP, ByRef Retour) [...] Écriture du fichier de commande FTP [...] Set WSHShell = CreateObject("WScript.Shell") WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True [...] Vérification du fichier de retour [...] End Sub

bonsoir,

je n'ai pas soucis, avec les fonctions, n'as tu pas un code de transfert un peu plus avancé, voir si je vois un problème dans ton code..?

tiens voilà un début ... :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Dim oFso 'J'utilise un objet Global oFso ...
Const ForReading = 1, ForWriting = 2 
Set oFso = CreateObject("Scripting.FileSystemObject")
 
 
Dim Retour
Wscript.Echo UploadByFTP ("MonFichier", "MonRep","FichieFtp", Retour)
Wscript.Echo Retour
 
Function UploadByFTP(ByVal FichierLocal, ByVal Repertoire, ByVal FichierFTP, ByRef Retour)
  Dim  fFtpScript
  Dim  fRetour 'Fichier retour
  Dim  stFicRet 'Lecture fichier retour
  Dim  FichierCommandeFTP 'Nom complet du fichier script
  Dim  FichierRetourFTP   
  Dim  stScript ' Script
  Retour = "------" & Now & "------------" & vbCrlf
  FichierCommandeFTP = FicTemp 'Détermine un nom de fichier temporaire pour le script
  FichierRetourFTP   = FicTemp 'Détermine nom du fichier retour
  'Création fichier script ftp 
  set fFtpScript =  oFso.OpenTextFile(FichierCommandeFTP, ForWriting,true)
  stScript =  "?" & vbCrlf & "bye"
  fFtpScript.write stScript
  fFtpScript.close
  Retour = Retour & stScript & vbCrlf & "----------------------------" & vbCrlf 
  Set WSHShell = CreateObject("WScript.Shell")
  WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True   
  set fRetour = oFso.OpenTextFile(FichierRetourFTP, ForReading,true)
  stFicRet = fRetour.ReadAll
  fRetour.close
  Retour = Retour & stFicRet
  oFso.DeleteFile FichierCommandeFTP 'Efface le fichier script temporaire
  oFso.DeleteFile FichierRetourFTP 'Efface le fichier script temporaire
  UploadByFTP = true
End Function
 
 
'
' Fonction FicTemp : renvoi le nom d'un fichier temporaire
'
Function FicTemp ' as string ..
dim oFldTemp
Const TemporaryFolder = 2
set oFldTemp =  ofso.GetSpecialFolder(TemporaryFolder)
 FicTemp = oFldTemp.path & "\" & oFso.GetTempName
End Function

Citation:

Envoyé par bbil

bonsoir,

je n'ai pas soucis, avec les fonctions, n'as tu pas un code de transfert un peu plus avancé, voir si je vois un problème dans ton code..?

tiens voilà un début ... :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Dim oFso 'J'utilise un objet Global oFso ...
Const ForReading = 1, ForWriting = 2 
Set oFso = CreateObject("Scripting.FileSystemObject")
 
 
Dim Retour
Wscript.Echo UploadByFTP ("MonFichier", "MonRep","FichieFtp", Retour)
Wscript.Echo Retour
 
Function UploadByFTP(ByVal FichierLocal, ByVal Repertoire, ByVal FichierFTP, ByRef Retour)
  Dim  fFtpScript
  Dim  fRetour 'Fichier retour
  Dim  stFicRet 'Lecture fichier retour
  Dim  FichierCommandeFTP 'Nom complet du fichier script
  Dim  FichierRetourFTP   
  Dim  stScript ' Script
  Retour = "------" & Now & "------------" & vbCrlf
  FichierCommandeFTP = FicTemp 'Détermine un nom de fichier temporaire pour le script
  FichierRetourFTP   = FicTemp 'Détermine nom du fichier retour
  'Création fichier script ftp 
  set fFtpScript =  oFso.OpenTextFile(FichierCommandeFTP, ForWriting,true)
  stScript =  "?" & vbCrlf & "bye"
  fFtpScript.write stScript
  fFtpScript.close
  Retour = Retour & stScript & vbCrlf & "----------------------------" & vbCrlf 
  Set WSHShell = CreateObject("WScript.Shell")
  WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True   
  set fRetour = oFso.OpenTextFile(FichierRetourFTP, ForReading,true)
  stFicRet = fRetour.ReadAll
  fRetour.close
  Retour = Retour & stFicRet
  oFso.DeleteFile FichierCommandeFTP 'Efface le fichier script temporaire
  oFso.DeleteFile FichierRetourFTP 'Efface le fichier script temporaire
  UploadByFTP = true
End Function
 
 
'
' Fonction FicTemp : renvoi le nom d'un fichier temporaire
'
Function FicTemp ' as string ..
dim oFldTemp
Const TemporaryFolder = 2
set oFldTemp =  ofso.GetSpecialFolder(TemporaryFolder)
 FicTemp = oFldTemp.path & "\" & oFso.GetTempName
End Function

Si si j'ai bien un code a donner.
Je ne l'ai pas mis car je voulais me concentré sur ce qui ne marche pas.
Encore une fois, si je remplace Function par Sub ca marche (sauf le retour)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
If UploadByFTP("C:\MonFichierLocal.txt" , "www/rep" , "FichierFTP.txt") Then
	Msgbox "Upload OK"
Else
	Msgbox "problème lors du transfert"
End If
 
Function UploadByFTP(ByVal FichierLocal, ByVal Repertoire, ByVal FichierFTP)
    Const ForReading = 1, ForWriting = 2, ForAppending = 8
    Dim fso, f_cmd, f_ret
 
    FichierCommandeFTP = "Cmdftp.ftp"
    FichierRetourFTP = "return.txt"
 
    FTP = "ftp.site.com"
    Login = "user"
    Pass = "pass"
 
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set f_cmd = fso.OpenTextFile(FichierCommandeFTP, ForWriting, True)	
    f_cmd.Write "OPEN " & FTP & vbCrLf
    f_cmd.Write "USER " & Login & vbCrLf & Pass & vbCrLf
    f_cmd.Write "cd " & Repertoire & vbCrLf
    f_cmd.Write "put " & FichierLocal & " " & FichierFTP & vbCrLf
    f_cmd.Write "quit"
    f_cmd.Close
 
	Set WSHShell = CreateObject("WScript.Shell")	
    WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True
 
    UploadByFTP = False
    Set f_ret = fso.OpenTextFile(FichierRetourFTP, ForReading)
	while Not f_ret.AtEndOfStream And UploadByFTP = False
		iF Trim(f_ret.ReadLine) = "226 File receive OK." Then
			UploadByFTP = True
		End If
    Wend
    f_ret.close
    fso.DeleteFile FichierCommandeFTP
    fso.DeleteFile FichierRetourFTP
    Set WSHShell = Nothing
    Set fso      = Nothing
    Set f_cmd    = Nothing
    Set f_ret    = Nothing
End Function

06/12/2008, 20h15
SfJ5Rpw8
ton code marche, je viens de le tester sur le serveur ftp de dvp.

j'ai du modifier le script ftp en supprimant la commande user :
Code:

1 2 3 4 .. f_cmd.Write "OPEN " & FTP & vbCrLf f_cmd.Write Login & vbCrLf & Pass & vbCrLf f_cmd.Write "cd " & Repertoire & vbCrLf ...
script ftp :
Code:

1 2 3 4 5 6 OPEN bbil.developpez.com xLog XXXXX cd articles put C:\tmp\fichier1.txt FichierFTP.txt quit
pour le retour j'ai :

Citation:

ftp> put C:\tmp\fichier1.txt FichierFTP.txt
200 PORT command successful.
150 Opening ASCII mode data connection.
226 Transfer completed.
ftp : 191 octets envoyés en 0,00 secondes à 191000,00 Ko/sec.
ftp> quit
221 Goodbye.

j'ai modifié ta ligne

Code:

if Trim(f_ret.ReadLine) = "226 File receive OK." Then

en

Code:

if Left(f_ret.ReadLine,4) = "226 " Then

Ah ben oui, ca marche.
Décidément, j'ai un peu de mal en ce moment :marteau:

Pour les modifs que tu propose :
Au taf, le FTP du client me demande le USER devant le login mais effectivement, mon hébergement chez OVH n'en a pas besoin. Bref, c'est un détail.

Concernant l'autre modification, le LEFT est plus rapide que le Trim ?
Sinon, j'avais aussi penser a InStr().

Ci-dessous, voici donc mes fonction GET/PUT/LIST sur FTP
Ils tiennent de ton code avec les fichiers temporaires.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
 
If UploadByFTP("test.xls" , "www/pro" , "test.xls")  Then
	Msgbox "Upload du fichier OK"
Else
	Msgbox "probleme"
End If
 
If GetListFTP( "www/pro","listftp.txt")  Then
	Msgbox "Liste du repertoire OK"
Else
	Msgbox "probleme"
End If
 
If DownloadByFTP("test.xls" , "www/pro" , "test2.xls")  Then
	Msgbox "Download OK"
Else
	Msgbox "probleme"
End If
 
 
Function UploadByFTP(ByVal FichierLocal, ByVal Repertoire, ByVal FichierFTP)
    Const ForReading = 1, ForWriting = 2, ForAppending = 8
    Dim fso, f_cmd, f_ret
 
    FTP = "ftp.site.com"
    Login = "login"
    Pass = "pass"
 
    Set fso = CreateObject("Scripting.FileSystemObject")
 
    FichierCommandeFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
    FichierRetourFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
 
    Set f_cmd = fso.OpenTextFile(FichierCommandeFTP, ForWriting, True)	
    f_cmd.Write "OPEN " & FTP & vbCrLf
    f_cmd.Write "" & Login & vbCrLf & Pass & vbCrLf
    f_cmd.Write "cd " & Repertoire & vbCrLf
    f_cmd.Write "put " & FichierLocal & " " & FichierFTP & vbCrLf
    f_cmd.Write "quit"
    f_cmd.Close
 
	Set WSHShell = CreateObject("WScript.Shell")	
    WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True
 
    UploadByFTP = False
    Set f_ret = fso.OpenTextFile(FichierRetourFTP, ForReading)
	while Not f_ret.AtEndOfStream And UploadByFTP = False
		iF Left(f_ret.ReadLine,4) = "226 " Then
			UploadByFTP = True
		End If
    Wend
    f_ret.close
 
    fso.DeleteFile FichierCommandeFTP
    fso.DeleteFile FichierRetourFTP
 
    Set WSHShell = Nothing
    Set fso      = Nothing
    Set f_cmd    = Nothing
    Set f_ret    = Nothing
End Function
 
Function DownloadByFTP(ByVal FichierFTP, ByVal Repertoire, ByVal FichierLocal)
    Const ForReading = 1, ForWriting = 2, ForAppending = 8
    Dim fso, f_cmd, f_ret
 
    FTP = "ftp.site.com"
    Login = "login"
    Pass = "pass"
 
    Set fso = CreateObject("Scripting.FileSystemObject")
 
    FichierCommandeFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
    FichierRetourFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
 
    Set f_cmd = fso.OpenTextFile(FichierCommandeFTP, ForWriting, True)	
    f_cmd.Write "OPEN " & FTP & vbCrLf
    f_cmd.Write "" & Login & vbCrLf & Pass & vbCrLf
    f_cmd.Write "CD " & Repertoire & vbCrLf
    f_cmd.Write "GET " & FichierFTP & " " & FichierLocal & vbCrLf
    f_cmd.Write "quit"
    f_cmd.Close
 
	Set WSHShell = CreateObject("WScript.Shell")	
    WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True
 
    DownloadByFTP = False
    Set f_ret = fso.OpenTextFile(FichierRetourFTP, ForReading)
	while Not f_ret.AtEndOfStream And DownloadByFTP = False
		iF Left(f_ret.ReadLine,4) = "226 " Then
			DownloadByFTP = True
		End If
    Wend
    f_ret.close
 
    fso.DeleteFile FichierCommandeFTP
    fso.DeleteFile FichierRetourFTP
 
    Set WSHShell = Nothing
    Set fso      = Nothing
    Set f_cmd    = Nothing
    Set f_ret    = Nothing
End Function
 
Function GetListFTP(ByVal Repertoire,ByVal FichierListe)
    Const ForReading = 1, ForWriting = 2, ForAppending = 8
    Dim fso, f_cmd, f_ret
 
    FTP = "ftp.site.com"
    Login = "login"
    Pass = "pass"
 
    Set fso = CreateObject("Scripting.FileSystemObject")
 
    FichierCommandeFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
    FichierRetourFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
 
    Set f_cmd = fso.OpenTextFile(FichierCommandeFTP, ForWriting, True)	
    f_cmd.Write "OPEN " & FTP & vbCrLf
    f_cmd.Write "" & Login & vbCrLf & Pass & vbCrLf
    f_cmd.Write "cd " & Repertoire & vbCrLf
    f_cmd.Write "ls * " & FichierLocal & " " & FichierListe & vbCrLf
    f_cmd.Write "quit"
    f_cmd.Close
 
    Set WSHShell = CreateObject("WScript.Shell")	
    WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True
 
    GetListFTP = False
    Set f_ret = fso.OpenTextFile(FichierRetourFTP, ForReading)
	while Not f_ret.AtEndOfStream And GetListFTP = False
		iF Left(f_ret.ReadLine,4) = "226 " Then
			GetListFTP = True
		End If
    Wend
    f_ret.close
 
    fso.DeleteFile FichierCommandeFTP
    fso.DeleteFile FichierRetourFTP
 
    Set WSHShell = Nothing
    Set fso      = Nothing
    Set f_cmd    = Nothing
    Set f_ret    = Nothing
End Function

06/12/2008, 21h25
SfJ5Rpw8

:king:

non le left c'était juste que la réponse de mon serveur n'était pas la même que pour le tiens..:

Citation:

226 Transfer completed.

au lieu de

Citation:

226 File receive OK.

j'ai donc limité le test au 4° caractères .. , pour le Trim , je n'en avais pas besoin car pas d'espace avant le 226 , faut voir si c'est pareil pour ton serveur ..;)
06/12/2008, 21h32
bodbod

Citation:

Envoyé par bbil

:king:

non le left c'était juste que la réponse de mon serveur n'était pas la même que pour le tiens..:

au lieu de

j'ai donc limité le test au 4° caractères .. , pour le Trim , je n'en avais pas besoin car pas d'espace avant le 226 , faut voir si c'est pareil pour ton serveur ..;)

OK donc il faut mieux garder "226 " car ce début de message doit être plus générique.
08/12/2008, 09h41
ced600

Citation:

j'ai donc limité le test au 4° caractères .. , pour le Trim , je n'en avais pas besoin car pas d'espace avant le 226 , faut voir si c'est pareil pour ton serveur ..

Dans tous les cas un Trim ne devrait pas faire de mal même s'il n'y a pas d'espace non ?
Juste par mesure de sécurité.
08/12/2008, 10h46
bodbod

Citation:

Envoyé par ced600

Dans tous les cas un Trim ne devrait pas faire de mal même s'il n'y a pas d'espace non ?
Juste par mesure de sécurité.

Oui je pense que je vais ajouter le TRIM.

Par contre, je suis de nouveau confronté aux problemes cité plus haut (shell dans fonction).

En fait, mon VBS fonctionne lorsque je le lance (FTP OK), mais lorsque je passe par les "taches planifiées" windows, mon script plante sur le shell et n'ecrit pas le fichier de retour (fichier commande est OK).

Un probleme d'autorisation ?
08/12/2008, 11h50
ced600

possible.
Cela plante à la création de l'objet shell ou au niveau du run ?
08/12/2008, 11h55
bodbod

Citation:

Envoyé par ced600

possible.
Cela plante à la création de l'objet shell ou au niveau du run ?

En fait, je n'ai pas de message d'erreur mais le RUN ne dure qu'une fraction de seconde (au lieu du temps de téléchargement) et cela me crée le fichier FTP vide. De plus, le fichier de retour FTP n'est pas crée.
08/12/2008, 12h55
ced600

ok alors peut être que tout simplement la commande ""cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP" ne fonctionne pas correctement dans "taches planifiées".

Crée un fichier .bat avec dedans la commande en statique (sans variable avec un exemple de leur valeur).
Et dans les traches planifiées de window, planifie un lancement du .bat comme tu le fait pour le .vbs

Si cela fonctionne pas alors cela vient de l'exécution via une tache planifiée.

Dans ta commande remplace /c par /k, /k ordonne à cmd de ne pas se fermer après exécution de la commande. Donc s'il y a une erreur ecrite dans la console tu pourras la voir.

Heu au fait pkoi le sujet est dans ce sous forum, et non dans le forum supérieur ?
08/12/2008, 14h14
bodbod

Citation:

Envoyé par ced600

ok alors peut être que tout simplement la commande ""cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP" ne fonctionne pas correctement dans "taches planifiées".

Crée un fichier .bat avec dedans la commande en statique (sans variable avec un exemple de leur valeur).
Et dans les traches planifiées de window, planifie un lancement du .bat comme tu le fait pour le .vbs

Si cela fonctionne pas alors cela vient de l'exécution via une tache planifiée.

Dans ta commande remplace /c par /k, /k ordonne à cmd de ne pas se fermer après exécution de la commande. Donc s'il y a une erreur ecrite dans la console tu pourras la voir.

Heu au fait pkoi le sujet est dans ce sous forum, et non dans le forum supérieur ?

Du nouveau.

En fait, mes script etait placés sur le reseau.
En deplacant le dossier en local, la tache planifiée semble fonctionnée.

Peut etre une histoire d'autorisation.
08/12/2008, 14h41
ced600

que valent FichierCommandeFTP et FichierRetourFTP ?
08/12/2008, 18h54
bodbod

Citation:

Envoyé par ced600

que valent FichierCommandeFTP et FichierRetourFTP ?

Je n'ai pas regarder precisement le chemin de ces deux fichiers.
Mais j'ai essayer de les mettre a "cmd.ftp" et "return.txt" sans changement.

Le contenu du fichier commande était oK mais le fichier retour n'était même pas crée.
08/12/2008, 18h58
SfJ5Rpw8

bonsoir,

tu à précisé un chemin pour la création du fichier return.txt..?
08/12/2008, 19h32
bodbod

Citation:

Envoyé par bbil

bonsoir,

tu à précisé un chemin pour la création du fichier return.txt..?

J'ai testé ca :

Code:

FichierRetourFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName

et ca

Code:

FichierRetourFTP = "return.txt"
08/12/2008, 19h38
SfJ5Rpw8

Je crois que t'on probléme n'est pas VBS mais plutôt le gestionnaire de tache...

peu-être te faut'il activer l'option "commande interactive".. tu devrai essayer direct la commande ftp .. comme te la dit cedric, et précise bien le chemin complet de tes 2 fichiers au cas ou...
08/12/2008, 19h44
bodbod

Citation:

Envoyé par bbil

Je crois que t'on probléme n'est pas VBS mais plutôt le gestionnaire de tache...

peu-être te faut'il activer l'option "commande interactive".. tu devrai essayer direct la commande ftp .. comme te la dit cedric, et précise bien le chemin complet de tes 2 fichiers au cas ou...

Bon pour le moment, je vais deja finir mon script en local car j'ai besoin qu'il tourne rapidement.

Par la suite, je vais voir pour le basculer sur le reseau.

Qu'entends tu par "commande interactive" ?
08/12/2008, 19h48
SfJ5Rpw8

une option de AT ... ;) on doit la retrouver dans le planificateur de taches..

Citation:

C:\>AT /?
La commande AT planifie l'exécution des commandes et programmes sur
l'ordinateur à une date et une heure spécifiées. Le service Planification
doit fonctionner pour utiliser la commande AT.

AT [\\ordinateur] [ [id] [/DELETE] | /DELETE [/YES]]
AT [\\ordinateur] heure [/INTERACTIVE]
[ /EVERY:date[,...] | /NEXT:date[,...]] "commande"

\\ordinateur Spécifie un ordinateur distant. Les commandes sont planifiées
sur l'ordinateur local si ce paramètre est omis.
id Identificateur (nombre) affecté à une commande
planifiée.
/DELETE Supprime une commande planifiée. Si id est omis, toutes
les commandes sur l'ordinateur sont supprimées.
/YES Utilisée pour supprimer toutes les tâches sans demande de
confirmation.
heure Heure de l'exécution de la commande.
/INTERACTIVE Permet au travail d'interagir avec le bureau de l'utilisateur
qui est connecté au moment où le travail est effectué.
/EVERY:date[,...] Exécute la commande tous les jours spécifiés de la semaine
ou du mois. Si la date est omise, le jour en cours du mois
est utilisé par défaut.
/NEXT:date[,...] Exécute la commande lors de la prochaine occurrence du jour
(par exemple, jeudi prochain). Si la date est omise, le
jour en cours du mois est utilisé par défaut.
"commande" Commande Windows NT, ou programme de commandes à exécuter.
08/12/2008, 19h57
bodbod

Citation:

Envoyé par bbil

une option de AT ... ;) on doit la retrouver dans le planificateur de taches..

Je vais essayer d'étudier cela ;)
11/02/2009, 17h12
tiamat59
Bonjour,

Je voulais avoir une précision sur votre script.

Par exemple:
Code:

1 2 3 4 5 If UploadByFTP("test.xls" , "www/pro" , "test.xls") Then Msgbox "Upload du fichier OK" Else Msgbox "probleme" End If
Je voi qu'il y a 2 fois test.xls fichier local et fichier FTP
Est ce que la fonction compare les 2 fichier pour savoir si le dl c'est bien passé?

Sinon je développe le même genre de fonction en ce moment
mais le transfert ne se fait pas.
Code:

1 2 3 4 5 connect = rep & "commandes.txt" Set WshShell = CreateObject("WScript.Shell") retour = rep & "\result.txt" WSHShell.Run "cmd /c ftp.exe -s:" & connect & " > " & retour, 0 , True
Il me créé bien mon fichier log mais il est vide et rien ne se transfert.
par contre quand j'utilise juste la commande ftp et non cmd avant le transfert est ok mais dans ce cas pas de fichier log.

Serait il possible aussi que vous commentiez un peu le code car j'ai du mal a le comprendre, je ne suis pas vraiment débutant mais celui la est peu complexe je trouve.

Merci d'avance

Citation:

Envoyé par tiamat59

Bonjour,

Je voulais avoir une précision sur votre script.

Par exemple:

Code:

1
2
3
4
5
If UploadByFTP("test.xls" , "www/pro" , "test.xls")  Then
	Msgbox "Upload du fichier OK"
Else
	Msgbox "probleme"
End If

Je vois qu'il y a 2 fois test.xls fichier local et fichier FTP
Est ce que la fonction compare les 2 fichier pour savoir si le dl c'est bien passé?

En fait, on peut donner un nom différent entre le fichier local et celui du FTP.
Exemple : Tu veux Uploader un fichier de ton PC qui s'appelle toto.txt mais tu souhaite qu'il se nomme tata.txt sur le FTP.

Code:

UploadByFTP "toto.txt" , "www/pro" , "tata.txt"

Citation:

Envoyé par tiamat59

Sinon je développe le même genre de fonction en ce moment
mais le transfert ne se fait pas.

Code:

1
2
3
4
5
 
       connect = rep & "commandes.txt"
       Set WshShell = CreateObject("WScript.Shell")
	retour = rep & "\result.txt"
	WSHShell.Run "cmd /c ftp.exe -s:" & connect & " > " & retour, 0 , True

Il me créé bien mon fichier log mais il est vide et rien ne se transfert.
par contre quand j'utilise juste la commande ftp et non cmd avant le transfert est ok mais dans ce cas pas de fichier log.

Qu'appelle tu le fichier "log" ? Le fichier de compte rendu FTP ?
Tu exécute ton script en local sur ton OC ou depuis un répertoire réseau ?

Citation:

Envoyé par tiamat59

Serait il possible aussi que vous commentiez un peu le code car j'ai du mal a le comprendre, je ne suis pas vraiment débutant mais celui la est peu complexe je trouve.

Merci d'avance

Effectivement, le code n'est pas très commenté

Voici quelques petits commentaires :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Function UploadByFTP(ByVal FichierLocal, ByVal Repertoire, ByVal FichierFTP)
    Const ForReading = 1, ForWriting = 2, ForAppending = 8
    Dim fso, f_cmd, f_ret
 
    ' Initialisation de données de connexions au FTP   
    FTP = "ftp.site.com"
    Login = "mon_login"
    Pass = "mon_mot_de_passe"
 
    Set fso = CreateObject("Scripting.FileSystemObject")
 
    ' Récuperation du nom des fichiers temporaires (Dossier Temp de Windows) 
    FichierCommandeFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
    FichierRetourFTP = fso.GetSpecialFolder(2).path & "\" & fso.GetTempName
 
    ' Écriture du fichier des commandes FTP 
    Set f_cmd = fso.OpenTextFile(FichierCommandeFTP, ForWriting, True)	
    f_cmd.Write "OPEN " & FTP & vbCrLf
    f_cmd.Write "" & Login & vbCrLf & Pass & vbCrLf
    f_cmd.Write "cd " & Repertoire & vbCrLf
    f_cmd.Write "put " & FichierLocal & " " & FichierFTP & vbCrLf
    f_cmd.Write "quit"
    f_cmd.Close
 
    ' Appel a FTP.exe pour exécution du fichier de commande
    ' L'éxécution créera le fichier de retour
    Set WSHShell = CreateObject("WScript.Shell")	
    WSHShell.Run "cmd /c ftp.exe -s:" & FichierCommandeFTP & " > " & FichierRetourFTP, 0 , True
 
    ' Si le fichier de retour existe
    ' Si inexistant => Probleme d'execution => Retour à False
    UploadByFTP = False
    If fso.FileExists(FichierRetourFTP) Then
        Set f_ret = fso.OpenTextFile(FichierRetourFTP, ForReading)
        ' Parcour du fichier de retour à la recherche de l'indication "Transfert OK"
    	while Not f_ret.AtEndOfStream And UploadByFTP = False
                ' Si une des lignes commence par "226 ", alors il n'y a pas eu de probleme lors du transfert
    		iF Left(f_ret.ReadLine,4) = "226 " Then
        			UploadByFTP = True
    		End If
        Wend
        f_ret.close
        Set f_ret    = Nothing
        ' Suppression du fichier de retour
        fso.DeleteFile FichierRetourFTP
    End If 
 
    ' Suppression du fichier de commande FTP
    fso.DeleteFile FichierCommandeFTP
 
    Set WSHShell = Nothing
    Set fso      = Nothing
    Set f_cmd    = Nothing
End Function

Merci pour ta réponse trés compléte.

Je vais mettre mon script vous pourrez peu être m'aider car je sui bloquer.

Voila un code que j'arrive a faire fonctionner
j'ai mis tous mon code mais ici le principal est la connexion au ftp le reste n'est pas important.
Donc ce script fonctionne, il envoi simplement un fichier sur le ftp et l'archive.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 'Tester si le fichier de paie est dans le dossier ODPAIE rep = "\\serveur\d$\FTP\ODPAIE" If (Month(Now) < 10) Then mois = "0" & Month(Now) Else mois = Month(Now) End If annee = Year(Now) fic = "CONINTCO." & mois & ".smaj" Set objFSO = CreateObject("Scripting.FileSystemObject" ) If objFSO.FileExists(rep & "\" & fic) Then 'Le fichier existe, il est renomme avec un nom generique objFSO.MoveFile rep & "\" & fic , rep & "\CONINTCO.smaj" 'Il est ensuite transfere sur le serveur ASW Set WshShell = CreateObject("WScript.Shell") WSHShell.Run "ftp.exe -n -s:commandes.txt" 'Créaton du dossier d'archivage If Not objFSO.FolderExists(rep & "\" & annee) Then objFSO.CreateFolder(rep & "\" & annee) End If 'le deplacement ds l'archive est faite ds un autre script qui sera planifié quelque seconde plus tard End If
Ce que je voudrait faire c'est un test pour voir si le fichier a bien été transférer et si il y a un problème sur le transfert ne pas l'archiver et envoyer un mail.
Pour cela je voulait donc récupérer le résultat de la connexion dans un fichier log pour pouvoir le traiter par la suite.

Et voici l'autre code qui ne fonctionne pas, j'ai pourtant bien respecter la synthaxe (enfin je pense) au niveau de la connexion ftp
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 'Tester si le fichier de paie est dans le dossier ODPAIE rep = "\\serveur\d$\FTP\ODPAIE" If (Month(Now) < 10) Then mois = "0" & Month(Now) Else mois = Month(Now) End If annee = Year(Now) fic = "CONINTCO." & mois & ".smaj" connect = rep & "commandes.txt" Set objFSO = CreateObject("Scripting.FileSystemObject" ) If objFSO.FileExists(rep & "\" & fic) Then 'Le fichier existe, il est renomme avec un nom generique objFSO.MoveFile rep & "\" & fic , rep & "\CONINTCO.smaj" 'Il est ensuite transfere sur le serveur ASW Set WshShell = CreateObject("WScript.Shell") retour = rep & "\result.txt" connect = rep & "commandes.txt" WSHShell.Run "cmd /c ftp.exe -s:" & connect & " > " & retour, 0 , True 'Créaton du dossier d'archivage If Not objFSO.FolderExists(rep & "\" & annee) Then objFSO.CreateFolder(rep & "\" & annee) End If 'le deplacement ds l'archive est faite ds un autre script qui sera planifié quelque seconde plus tard End If
Mais dans ce cas le transfert ne se fait pas, le fichier result.txt se crée bien mais il est vide.

Pourriez vous m'aider?

12/02/2009, 16h59
tiamat59

Bonj'ai un peu avancé depuis mon dernier post.

Mes script était stocké sur un serveur et c'est surment pour cela qu'i lne s"exécutait pas bien puisque j'était en partage administratif.
De plus j'ai modifier ma variable rep en mettant le chemin relatif (juste \test)
J'ai ensuite fait une copi en local des mes script et la miracle ça marche
Le transfert et le fichier résult sont OK

Par contre j'ai donc essayer de remttre mes script sur le serveur et de prendre la main en TSE dessus pour aller les exécuter mais la rien, mais alors rien de chez rien, j'ai l'impression qu'il ne s'execute pas du tous. Pourtant en étant connecté en TSE sa devrait revenir au même que quand j'exécute les autres en local.

Quelqu'un aurai une idée?