blocage d'un userform

Version imprimable

Bonjour,

Je vous expose mon soucis :
J'ai un classeur xls qui doit se mettre à jour dès son ouverture avec le code suivant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub Workbook_Open()
    If variable.Cells(1, 10) < Month(Now()) Then
        majauto.Show
        majauto.etat.Caption = "initialisation"
        majauto.ProgressBar1.Value = 0
        For i = 1 To numerosaff.Cells(Rows.Count, 13).End(xlUp).Row
            majauto.etat.Caption = "incrémentation paiement client"
            If StrComp(numerosaff.Cells(i, 13), "R") = 0 Then
                numerosaff.Cells(i, 16) = numerosaff.Cells(i, 16) + 1
            End If
            majauto.ProgressBar1.Value = (i / numerosaff.Cells(Rows.Count, 13).End(xlUp).Row) * 100
        Next
        majauto.Hide
        variable.Cells(1, 10) = variable.Cells(1, 10) + 1
    End If
    menu.Show
End Sub

Pour faire patienter j'utilise un userform (majauto) qui contient un label (etat) et une progressbar.

mon soucis est que le code semble se bloque à

Code:

majauto.etat.Caption = "initialisation"

, je n'ai que la fenêtre "majauto" qui s'affiche et rien ne se passe ensuite.:aie:

Où est le problème ???

13/11/2008, 12h43
decondelite

Rajoute un majauto.Repaint (ou DoEvents l'effet est le même mais pas le sens: c'est toi qui vois) derrière ça devrait marcher. ;)
13/11/2008, 13h25
pgz

Bonjour.

Je pense que tu ouvres ton userform en modal, ce qui arrête l'exécution du code. Essaie :

Code:

majauto.Show vbModeless

Ensuite, comme le dit decondelite si tu modifies ton uform, pense à faire Repaint pour qu'il se mette à jour.

Bon courage,

PGZ

:king:
Voici le code avec les corrections que vous m'avez donné :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub Workbook_Open()
    If variable.Cells(1, 10) < Month(Now()) Then
        majauto.Show vbModeless
        majauto.etat.Caption = "initialisation"
        majauto.ProgressBar1.Value = 0
        majauto.etat.Caption = "incrémentation paiement client"
        majauto.Repaint
        For i = 1 To numerosaff.Cells(Rows.Count, 13).End(xlUp).Row
            If StrComp(numerosaff.Cells(i, 13), "R") = 0 Then
                numerosaff.Cells(i, 16) = numerosaff.Cells(i, 16) + 1
            End If
            majauto.ProgressBar1.Value = (i / numerosaff.Cells(Rows.Count, 13).End(xlUp).Row) * 100
        Next
        majauto.Hide
        variable.Cells(1, 10) = variable.Cells(1, 10) + 1
    End If
    menu.Show
End Sub

Merci à tous les deux pour votre aide.

En cherchant de mon coté, j'ai trouvé une autre solution :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub Workbook_Open()
    If variable.Cells(1, 10) < Month(Now()) Then
        majauto.Show
    End If
    menu.Show
End Sub
 
Private Sub UserForm_Activate()
    majauto.etat.Caption = "initialisation"
    majauto.ProgressBar1.Value = 0
    majauto.etat.Caption = "incrémentation paiement client"
    majauto.Repaint
    For i = 1 To numerosaff.Cells(Rows.Count, 13).End(xlUp).Row
        If StrComp(numerosaff.Cells(i, 13), "R") = 0 Then
            numerosaff.Cells(i, 16) = numerosaff.Cells(i, 16) + 1
        End If
        majauto.ProgressBar1.Value = (i / numerosaff.Cells(Rows.Count, 13).End(xlUp).Row) * 100
    Next
    majauto.Hide
    variable.Cells(1, 10) = variable.Cells(1, 10) + 1
End Sub

Les deux fonctionnent, mais la première utilise moins de ligne et m'a permis de découvrir une instruction que je connaissait pas (vbmodeless) :king:

13/11/2008, 15h38
decondelite

J'ajouterais que la propriété ShowModal figure dans la fenêtre des propriétés du Userform, et que tu peux la modifier pendant la phase de conception avant toute exécution. ;)

Personnellement je la modifie à cet endroit si je n'ai pas besoin de changer la modalité du userform en cours d'exécution soit par la manière qu'on t'a indiqué (que je ne connaissais pas non plus), soit en la traitant directement en faisant Userform.ShowModal = false. Et comme je n'ai jamais senti ce besoin, j'ai donc toujours changé cette propriété dans la fenêtre propriété.