[E-07] Affichage d'un tableau dynamique dans une MsgBox

Version imprimable

Bonsoir,

je suis débutant en VBA et en parcourant les discussions, je n'ai pas trouvé de solution à mon problème.

Ainsi, je voudrai afficher réellement mon tableau dans une MsgBox et non pas de la manière dont le le fait dans le programme ci-dessous...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
 
Sub saisieTableau(ByRef tableau() As Integer, ByRef dimension As Integer)
    Dim i As Integer
    Dim temp As Integer
    dimension = InputBox("Entrer la dimension du tableau <50: ")
    Do While dimension < 1 Or dimension > 50
        dimension = InputBox("Erreur, la valeur doit être comprise entre 1 et 50. Entrez une nouvelle valeur : ")
    Loop
    i = 0
    Do
        temp = InputBox("Saisir la valeur numéro " & i + 1 & " du tableau : ")
        tableau(i) = temp
        i = i + 1
    Loop While i < dimension
End Sub
 
Sub afficheTableau(ByRef tableau() As Integer, ByRef dimension As Integer)
    Dim i As Integer
    Dim affichage As Integer
    For i = 0 To dimension - 1
        affichage = MsgBox(tableau(i), , "")
    Next i
End Sub
Sub testExo4TD1()
    Dim tableau(50) As Integer
    Dim dimension As Integer
    Call saisieTableau(tableau(), dimension)
    Call afficheTableau(tableau(), dimension)
End Sub

Merci de m'éclairer...:aie:

Bonjour,

Un de truc de ce style ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Dim tablo() As Variant
'##########################################################################################################################
Sub saisieTableau()
    Dim dimension As Variant, i As Integer
 
recom:
    dimension = InputBox("Introduisez la dimension du tableau (de 1 à 50)", "Dimension Tableau")
 
    If dimension = "" Then
        Select Case MsgBox("Vous n'avez rien introduit" & vbLf & "Voulez-vous quitter la procédure ?", vbQuestion + vbYesNo)
            Case vbYes: Exit Sub
            Case Else: GoTo recom
        End Select
    End If
 
    If dimension < 1 Or dimension > 50 Then
        MsgBox "Veuillez introduire un nombre de 1 à 50", vbExclamation
        GoTo recom
    End If
 
    ReDim tablo(dimension - 1)
 
    For i = 0 To UBound(tablo)
        tablo(i) = InputBox("Veuillez saisir la valeur n° " & i + 1 & " du tableau")
    Next
 
    afficheTableau
End Sub
'##########################################################################################################################
Sub afficheTableau()
    Dim i As Integer, strTablo As String
 
    For i = 0 To UBound(tablo)
        strTablo = strTablo & Chr(10) & tablo(i)
    Next
 
    MsgBox strTablo
End Sub
'##########################################################################################################################
Sub test()
    saisieTableau
End Sub

Cdlt

22/10/2008, 09h57
perchman

ça me va très bien !!

Merci beaucoup.:king:

Question de curiosité: est-il possible d'afficher un tableau avec 2 colonnes ??

Comme ça :

1 3
2 3
3 2
4 8

Ci-dessous le code modifié avec un tableau à 2 dimensions (2 colonnes et un nombre de lignes de 1 à 10)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Dim tablo() As Variant
'##########################################################################################################################
Sub saisieTableau()
    Dim dimension As Variant, i As Integer
 
recom:
    dimension = InputBox("Introduisez la dimension du tableau (de 1 à 10)", "Dimension Tableau")
 
    If dimension = "" Then
        Select Case MsgBox("Vous n'avez rien introduit" & vbLf & "Voulez-vous quitter la procédure ?", vbQuestion + vbYesNo)
            Case vbYes: Exit Sub
            Case Else: GoTo recom
        End Select
    End If
 
    If dimension < 1 Or dimension > 10 Then
        MsgBox "Veuillez introduire un nombre de 1 à 50", vbExclamation
        GoTo recom
    End If
 
    ReDim tablo(2, dimension - 1)
 
    For i = 0 To UBound(tablo, 2)
        tablo(1, i) = InputBox("Veuillez saisir la valeur n° " & i + 1 & " de la 1ère colonne du tableau")
        tablo(2, i) = InputBox("Veuillez saisir la valeur n° " & i + 1 & " de la 2ème colonne du tableau")
    Next
 
    afficheTableau
End Sub
'##########################################################################################################################
Sub afficheTableau()
    Dim i As Integer, strTablo As String
 
    For i = 0 To UBound(tablo, 2)
        strTablo = strTablo & Chr(10) & tablo(1, i) & Space(7) & tablo(2, i)
    Next
 
    MsgBox strTablo
End Sub
'##########################################################################################################################
Sub test()
    saisieTableau
End Sub