XSL et NameSpace variable

Version imprimable

Bonjour,

Prenons un XML de ce type :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
<?xml version="1.0" encoding="utf-8" ?>
<pipo>
  <totos>
    <blabla>aaa</blabla>
    <blabla>bbb</blabla>
    <blabla>ccc</blabla>
  </totos>
  <gigis>
    <mumu>hhh</mumu>
    <mumu>kkk</mumu>
    <mumu>vvv</mumu>
  </gigis>
  <dudus xmlns="loulou">
    <riri>111</riri>
    <riri>222</riri>
    <riri>333</riri>
  </dudus>
</pipo>

Je désire construire 2 fichiers XSL :

le premier donnerait en sortie tout le fichier sans le sous arbre <dudus>,
le deuxième donnerait en sortie uniquement le sous arbre <dudus>.

Comment faire sachant que le NameSapce est variable d'un XML a un autre ?

J'ai bien trouvé ça pour le 2ème XSL, mais en spécifiant le Name Space hélas :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:zz="loulou">
  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="/">
    <xsl:apply-templates select="//zz:dudus"/>
  </xsl:template>
</xsl:stylesheet>

Merci.

16/10/2008, 10h41
domiq44

J'ai ajouté « DEFI » car je n'ai absolument rien trouvé sur le net 8O

Est-ce que quelqu'un a une idée ? :?
16/10/2008, 10h46
GrandFather

Bonjour,

regarde du côté de la fonction XPath local-name(). ;)

Oui en effet, ça marche en utilisant cette commande XPath :D

Même en complexifiant juste un peu le XML de départ comme ceci :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
<?xml version="1.0" encoding="utf-8" ?>
<pipo>
  <totos>
    <blabla>aaa</blabla>
    <blabla>bbb</blabla>
    <blabla>ccc</blabla>
  </totos>
  <gigis>
    <mumu>hhh</mumu>
    <mumu>kkk</mumu>
    <mumu>vvv</mumu>
  </gigis>
  <dudus xmlns="loulou">
    <dudu>
      <riri>111</riri>
      <riri>222</riri>
      <riri>333</riri>
    </dudu>
  </dudus>
</pipo>

En utilisant le XSL suivant (merci à GrandFather):

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:zz="loulou">
  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="/">
    <xsl:apply-templates select="//*[local-name() = 'dudus']/*"/>
  </xsl:template>
</xsl:stylesheet>

On obtient bien ceci :

Code:

1
2
3
4
5
6
7
 
<?xml version="1.0" encoding="UTF-8"?>
<dudu xmlns="loulou">
  <riri>111</riri>
  <riri>222</riri>
  <riri>333</riri>
</dudu>

Question : Pourquoi <dudu> hérite-t-il du NameSpace « loulou » ? 8O

Merci.

Citation:

Envoyé par domiq44

Question : Pourquoi <dudu> hérite-t-il du NameSpace « loulou » ? 8O

Parce que dans le document source il appartient à cet espace de noms (un espace de nom par défaut s'applique pour l'élément où il est déclaré et à tous ses descendants), et xsl:copy ne change pas l'espace de nom de l'élément copié.

Si tu souhaites que dudu n'ait pas d'espace de noms, utilise plutôt ceci :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 <?xml version="1.0" encoding="UTF-8"?> <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:zz="loulou"> <xsl:output method="xml" encoding="UTF-8" indent="yes"/> <xsl:template match="@*|processing-instruction()|comment()"> <xsl:copy-of select="."/> </xsl:template> <xsl:template match="*"> <xsl:element name="{local-name()}"> <xsl:apply-templates /> </xsl:element> </xsl:template> <xsl:template match="/"> <xsl:apply-templates select="//*[local-name() = 'dudus']/*"/> </xsl:template> </xsl:stylesheet>

16/10/2008, 14h41
domiq44

Ce script est qu'il supprime bien le NameSpace de <dudu>, mais aussi à tord celui de ses descendant :?

Moi ce que je souhaite réussir à faire, est une copie conforme de <dudu> et de ses descendants.

C'est à dire que si <dudu> possède un NameSpace, le prendre, et la même chose pour ses descendants.

Si un enfant, n'en possède pas, le laisser comme ça et ne pas en ajouter.

Est-ce possible ? :aie:
16/10/2008, 14h45
GrandFather

Citation:

Envoyé par domiq44

Est-ce possible ? :aie:

Ben oui, et c'est d'ailleurs ce que tu avais réussi à faire dans ton précédent post... :aie:

Relis ma définition d'un espace de nom par défaut :

Citation:

un espace de nom par défaut s'applique à l'élément où il est déclaré et à tous ses descendants

Citation:

Envoyé par domiq44

Je désire construire 2 fichiers XSL :

le premier donnerait en sortie tout le fichier sans le sous arbre <dudus>,
le deuxième donnerait en sortie uniquement le sous arbre <dudus>.

Quant au premier script, il doit ressembler à ça :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 <?xml version="1.0" encoding="UTF-8"?> <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:zz="loulou"> <xsl:output method="xml" encoding="UTF-8" indent="yes"/> <xsl:template match="@*|node()"> <xsl:copy> <xsl:apply-templates select="*[local-name() != 'dudus']"/> </xsl:copy> </xsl:template> <xsl:template match="/"> <xsl:apply-templates/> </xsl:template> </xsl:stylesheet>
Mais je ne récupère pas les attributs :(

16/10/2008, 14h53
domiq44

Citation:

Envoyé par GrandFather

Ben oui, et c'est d'ailleurs ce que tu avais réussi à faire dans ton précédent post... :aie:

Relis ma définition d'un espace de nom par défaut :

Ok, je viens de comprendre :oops:

Merci GrandFather ;)
16/10/2008, 15h46
domiq44

Quelqu'un a-t-il une idée sur le premier script? 8O

Ce n'est qu'une variante du second, en encore plus simple :

Code:

1
2
3
4
5
6
7
8
9
10
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates />
    </xsl:copy>
  </xsl:template>
  <xsl:template match="*[local-name() = 'dudus']"/>
</xsl:stylesheet>

17/10/2008, 09h30
domiq44

Merci pour tout GrandFather :king:

:salut: