[Batch Dos] incrementation +3 à %date%

Version imprimable

02/10/2008, 11h55
dob2806

[Batch Dos] incrementation +3 à %date%
bonjour à tous, dans le but de creer une tache planifiée se lancant 3 jours apres l'execution de mon script j'essai tant bien que mal de faire un script en incrementant 3 a %dateù, le probleme que j'ai et le changement des mois et des années.

Voici ce que j'ai reussi a faire et a n'utiliser qu'avant le 25,27 et 28 de chaque mois.
Code:

1 2 3 4 5 6 7 8 9 10 for /f "tokens=1,2,3 delims=/" %%i in ('date/T') do ( set jour=%%i set mois=%%j set anne=%%k ) set /A jour3=%jour%+3 Echo %jour3%/%mois%/%anne% pause
j'aimerai ne pas me soucier de savoir quand lancer le batch et faire un script qui me donen la bonne date meme s'il y a changement de mois/années.

PS: sous windows 2003
02/10/2008, 13h16
Laurent Dardenne
Salut,
En batch cela ne va pas être facile :?

Citation:

Envoyé par dob2806

PS: sous windows 2003

En PowerShell ?
Code:

1 2 3 4 5 6 7 >$date=Get-date >$date jeudi 2 octobre 2008 13:14:37 >$date.AddDays(91) jeudi 1 janvier 2009 13:14:37
02/10/2008, 14h27
dob2806

le probleme c'est que je suis une quiche en prog le script je commence a me debrouiller mais la le powershell !!

en fait j'ai un script qui doit tourner pour generer un mot de passe aleatoire suivant un dico (ça c'est ok) ensuite il me genere un mail a envoyé aux utilisateurs concernés et il programme une tache planifiée pour que 3 jours apres avoir executer le script le mot de passe change dans l'AD.

je coince a la generation du script pour l'envoi(deja un post de créé)
et à comment planifié une tache 3 jours apres execution du script...

voila vous savez tout :D et on m'a demandé de faire ça en batch dos, donc je tente de m'y appliquer.
02/10/2008, 14h59
Laurent Dardenne

Citation:

Envoyé par dob2806

le probleme c'est que je suis une quiche en prog le script je commence a me debrouiller mais la le powershell !!

L'usage de base de powerShell est aisée faut juste accepter de débuter. Comment ai-je fait à ton avis ?
Ensuite c'est sûr que cela demande qq réflexions à propos de son déploiement sur un parc de machines.

Citation:

Envoyé par dob2806

on m'a demandé de faire ça en batch dos, donc je tente de m'y appliquer.

:king:
02/10/2008, 17h23
Laurent Dardenne

Peut être un début de solution ici:
http://www.computing.net/answers/win...pt/143775.html
ou là
http://www.robvanderwoude.com/datetiment.html#DateAdd

Tu as un budget pour l'aspirine ?
:mouarf:

j'etais tomber en cherchant sur ce script tiré d'un post sur ce forum mais je ne le comprend pas:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
rem le nombre d jours est passé en paramètre du batch = %1=periode
for /f "tokens=1,2,3 delims=/" %%i in ('date/T') do (
set jouri=%%i
set moisi=%%j
set ani=%%k
)
set periode=%1
if %moisi:~0,1% EQU 0 set moisi=%moisi:~1,1%
if %jouri:~0,1% EQU 0 set jouri=%jouri:~1,1%
set /a diffperiode=(%moisi%*30)+%jouri%
echo debut annee %diffperiode%

set /A difannee=%periode%/365
set /A ani=%ani%-%difannee%
echo %difannee% ; %ani%

set /a difjour=%periode%-(%difannee%*365)

if %diffperiode%  LSS %difjour% goto rattrapagemois


set /a moisref=%difjour%/30
echo %moisref%
set /a moisi=%moisi%-%moisref%
echo %moisref% ; %moisi%


set /a jourref=%difjour%-(%moisref%*30)
echo %jourref%
if %jourref% GTR %jouri% (
set /a moisi=%moisi%-1
set jouri=%jourref%-%jouri%
) ELSE (
set /a jouri=%jouri%-%jourref%
)
echo %jourref% ; %jouri%

goto fin

:rattrapagemois
set /A ddif=%difjour%-%diffperiode%
set /A ani=%ani%-1
set /A diffmois=%ddif%/30
echo %diffmois%
echo %ddif%
echo %difjour%

set /a moisi=12-%diffmois%
echo %moisi%
set /A diffjour=%ddif%-(%diffmois%*30)
set /a jouri=%jouri%-%diffjour%
echo %jouri%
:fin

rem on arrive avec %ani% , %moisi% et %jouri% 
rem qui sont les jour mois et année compte tenu du cécalage de la période
rem on peut affiner, je suis parti du principe qu'un mois fait 30 jours

cela pourrait-il m'aider ?

02/10/2008, 17h24
dob2806

post croisés :D :D :D

j'ai des actions chez Doliprane :D :D :D
02/10/2008, 17h39
Laurent Dardenne

Citation:

Envoyé par dob2806

cela pourrait-il m'aider ?

Faut voir.
Mais le code rob van der woude me semble de bonne facture, ce n'est pas tous les jours que je vois des algo codés en batch.

Citation:

Envoyé par dob2806

j'ai des actions chez Doliprane

ça tombe bien ! Coté bourse c'est peut être les seuls en ce moment à ne pas trop se faire de mouron :lol:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
@echo off
echo. & echo Nous sommes Aujourd'hui le %DATE%
set /p NJ="Entrez un nombre de jours positif ou negatif : "

set /a J=%DATE:~0,2%
set /a M=%DATE:~3,2%
set /a A=%DATE:~6,4%
set /a JJ=%NJ% + (1461 * (%A% + 4800 + (%M% - 14) / 12)) / 4 + (367 * (%M% - 2 - 12 * ((%M% - 14) / 12))) / 12 - (3 * ((%A% + 4900 + (%M% - 14) / 12) / 100)) / 4 + %J% - 32075
set /a T0=%JJ% + 68569
set /a T1=(4 * %T0%) / 146097
set /a T0=%T0% - (146097 * %T1% + 3) / 4
set /a T2=(4000 * (%T0% + 1)) / 1461001
set /a T0=%T0% - (1461 * %T2%) / 4 + 31
set /a T3=(80 * %T0%) / 2447
set /a J=%T0% - (2447 * %T3%) / 80
set /a M=%T3% + 2 - (12 * (%T3% / 11))
set /a A=100 * (%T1% - 49) + %T2% + (%T3% / 11)

if %J% LSS 10 set J=0%J%
if %M% LSS 10 set M=0%M%

echo.
if %NJ% EQU 0 echo Nous sommes le %DATE% !
if %NJ% GTR 0 echo Dans %NJ:+=% jour(s) nous serons le %J%/%M%/%A%
if %NJ% LSS 0 echo Il y a %NJ:-=% jour(s) nous etions le %J%/%M%/%A%
echo.

Citation:

resultat:

H:\Batch>test

Nous sommes Aujourd'hui le 05/10/2008
Entrez un nombre de jours positif ou negatif : 3

Dans 3 jour(s) nous serons le 08/10/2008

H:\Batch>test

Nous sommes Aujourd'hui le 05/10/2008
Entrez un nombre de jours positif ou negatif : -3

Il y a 3 jour(s) nous etions le 02/10/2008

H:\Batch>

05/10/2008, 19h41
Laurent Dardenne

Belle implémentation !
:bravo:
05/10/2008, 22h10
ram-0000

Question de pinailleur !!

Cela marche avec les années bissextiles ?
07/10/2008, 11h12
dob2806

Trop cool :yaisse2::yaisse2: , je teste ca de suite et je remonte les infos eventuelles.

Trés grand merci :king:
07/10/2008, 11h16
dob2806
je viens de tester en changeant ma date et cela fonctionne pour les années bissextiles et pour le changement d'année aussi. j'inmplement dans mon script et je reviens vers vous.

par contre histoire de m'endormir moins con ce soir y a possibilité éventuelle d'expliquer en survolant tout au moins ?

deja ça:
Code:

1 2 3 set /a J=%DATE:~0,2% set /a M=%DATE:~3,2% set /a A=%DATE:~6,4%
et la suite si ce n'est pas trop demander.

Merci.
07/10/2008, 17h44
Laurent Dardenne

Pour la commande Set voir l'aide en ligne

Code:

Set /?
08/10/2008, 09h56
dob2806

merci pour ces infos :mrgreen::mrgreen: ce n'etait pas la la question :mrgreen::mrgreen:, ce que je ne comprend pas ce sont les ~0,2%, ~3,2% et ~6,4% .

mais c'est toujours bien aimable à toi d'avoir repondu.

heu les script ne fonctionne pas aujourd'hui ???? ni demain ????

en modifiant la date systeme a differente date j'ai cette erreur:
Code:

1 2 3 4 Nombre non valide. Les constantes numériques doivent être soit décimales (17), soit hexadécimales (0x11), soit octales (021). Dans 3 jour(s) nous serons le 03/10/2008

08/10/2008, 10h46
dob2806

bon je viens de tester tous les jours de ce mois et ca ne plante que le 8 et le 9 pareil pour le mois de novembre ... bizarre !!

y a moyen de contourner le probleme avec des if ?
08/10/2008, 13h17
Laurent Dardenne

Salut,

Citation:

Envoyé par dob2806

merci pour ces infos :mrgreen::mrgreen: ce n'etait pas la la question :mrgreen::mrgreen:, ce que je ne comprend pas ce sont les ~0,2%, ~3,2% et ~6,4% .
mais c'est toujours bien aimable à toi d'avoir repondu.

Si tu veux je peux te copier ici l'aide en ligne :

Citation:

>Set /?
...
Vous pouvez aussi spécifier des sous-chaînes pour une expression.
%PATH:~10,5%

développe la variable d'environnement PATH et utilise seulement 5 caractères à partir du onzième (décalage de 10) dans le résultat sous forme développée. Si la longueur n'est pas spécifiée, tout le reste de la valeur de la variable est traité. Si l'une des valeurs (décalage ou longueur)
est négative, alors le nombre utilisé est la longueur de la valeur de la variable d'environnement ajoutée au décalage ou à la longueur donné.

%PATH:~-10%

extrait les 10 derniers caractères de la variable PATH.

%PATH:~0,-2%

extrait tous les caractères sauf les deux derniers de la variable PATH.
...
08/10/2008, 14h12
dob2806

Milles excuses et merci pour l'info.

mais pourquoi cela ne fonctionne t'il pas le 8 et 9 ?
08/10/2008, 14h17
Laurent Dardenne

Citation:

Envoyé par dob2806

mais pourquoi cela ne fonctionne t'il pas le 8 et 9 ?

Je ne sais pas.
Poste ton code de test stp.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
@echo off
echo. & echo Nous sommes Aujourd'hui le %DATE%

set /a NJ=3
set /a J=%DATE:~0,2%
set /a M=%DATE:~3,2%
set /a A=%DATE:~6,4%
set /a JJ=%NJ% + (1461 * (%A% + 4800 + (%M% - 14) / 12)) / 4 + (367 * (%M% - 2 - 12 * ((%M% - 14) / 12))) / 12 - (3 * ((%A% + 4900 + (%M% - 14) / 12) / 100)) / 4 + %J% - 32075
set /a T0=%JJ% + 68569
set /a T1=(4 * %T0%) / 146097
set /a T0=%T0% - (146097 * %T1% + 3) / 4
set /a T2=(4000 * (%T0% + 1)) / 1461001
set /a T0=%T0% - (1461 * %T2%) / 4 + 31
set /a T3=(80 * %T0%) / 2447
set /a J=%T0% - (2447 * %T3%) / 80
set /a M=%T3% + 2 - (12 * (%T3% / 11))
set /a A=100 * (%T1% - 49) + %T2% + (%T3% / 11)

if %J% LSS 10 set J=0%J%
if %M% LSS 10 set M=0%M%

echo Dans 3 jours nous serons le %J%/%M%/%A%

L'extraction des jours et des mois pose problème s'ils sont inférieure à 10.
Pourtant le test existe enfin de batch :koi:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@echo off
rem Aucun affichage des msg d'erreur
rem  getdate2 2>null
rem Mémorisation des msg d'erreur dans le répertoire courant
rem getdate2 2>%CDd%\log.txt
rem Mémorisation des msg d'erreur dans le répertoire %temp%
rem getdate2 2>%TEMP%\log.txt
 
echo Nous sommes Aujourd'hui le %DATE%
set /p NJ="Entrez un nombre de jours positif ou negatif : "
set /a J=%DATE:~0,2%
if errorlevel 1 set /a J=%DATE:~1,1%
set /a M=%DATE:~3,2%
if errorlevel 1 set /a M=%DATE:~4,1%
 
set /a A=%DATE:~6,4%
set /a JJ=%NJ% + (1461 * (%A% + 4800 + (%M% - 14) / 12)) / 4 + (367 * (%M% - 2 - 12 * ((%M% - 14) / 12))) / 12 - (3 * ((%A% + 4900 + (%M% - 14) / 12) / 100)) / 4 + %J% - 32075
set /a T0=%JJ% + 68569
set /a T1=(4 * %T0%) / 146097
set /a T0=%T0% - (146097 * %T1% + 3) / 4
set /a T2=(4000 * (%T0% + 1)) / 1461001
set /a T0=%T0% - (1461 * %T2%) / 4 + 31
set /a T3=(80 * %T0%) / 2447
set /a J=%T0% - (2447 * %T3%) / 80
set /a M=%T3% + 2 - (12 * (%T3% / 11))
set /a A=100 * (%T1% - 49) + %T2% + (%T3% / 11)
if %J% LSS 10 set J=0%J%
if %M% LSS 10 set M=0%M%
@echo .
if %NJ% EQU 0 echo Nous sommes le %DATE% !
if %NJ% GTR 0 echo Dans %NJ:+=% jour(s) nous serons le %J%/%M%/%A%
if %NJ% LSS 0 echo Il y a %NJ:-=% jour(s) nous etions le %J%/%M%/%A%
@echo .

Il se peut que "le moteur" de batch soit différent ?
Par exemple la syntaxe Echo. a tjr fonctionnée sous XP sp1 mais pas sous XP sp3, à vérifier.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
@echo off
echo. & echo Nous sommes Aujourd'hui le %DATE%
set /p NJ="Entrez un nombre de jours positif ou negatif : "

set /a J=1%DATE:~0,2% - 100
set /a M=1%DATE:~3,2% - 100
set /a A=%DATE:~6,4%
set /a JJ=%NJ% + ((1461 * (%A% + 4800 + (%M% - 14) / 12)) / 4 + (367 * (%M% - 2 - 12 * ((%M% - 14) / 12))) / 12 - (3 * ((%A% + 4900 + (%M% - 14) / 12) / 100)) / 4 + %J% - 32075)
set /a T0=%JJ% + 68569
set /a T1=(4 * %T0%) / 146097
set /a T0=%T0% - (146097 * %T1% + 3) / 4
set /a T2=(4000 * (%T0% + 1)) / 1461001
set /a T0=%T0% - (1461 * %T2%) / 4 + 31
set /a T3=(80 * %T0%) / 2447
set /a J=%T0% - (2447 * %T3%) / 80
set /a M=%T3% + 2 - (12 * (%T3% / 11))
set /a A=100 * (%T1% - 49) + %T2% + (%T3% / 11)

if %J% LSS 10 set J=0%J%
if %M% LSS 10 set M=0%M%

echo.
if %NJ% EQU 0 echo Nous sommes le %DATE% !
if %NJ% GTR 0 echo Dans %NJ:+=% jour(s) nous serons le %J%/%M%/%A%
if %NJ% LSS 0 echo Il y a %NJ:-=% jour(s) nous etions le %J%/%M%/%A%
echo.

08/10/2008, 18h23
Laurent Dardenne

Citation:

Envoyé par magma²

[code]
set /a J=1%DATE:~0,2% - 100

Je me doutais bien qu'on pouvait faire + simple et + élégant :roll:
Peux-tu nous dire sous quel OS tu as testé ce script ?
Et est-ce un algo particulier ?
Merci.
09/10/2008, 00h34
dob2806

je testerai ca demain sur mon 2003 R2 en tout cas ca fonctionne sur mon xp SP3 !!

Un trés grand merci à vous deux d'avoir pris le temps de me repondre meme si je n'ai pas tout compris :mrgreen::mrgreen:

petite question pourquoi declare t'on plusieurs fois la variable T0 ?
09/10/2008, 22h58
maxim_um

Salut tout le monde,

dob2806,
la variable TO n'est pas déclarée plusieurs fois comme tu le dis, elle est recalculée. (du moins son contenu si tu préfères)

Citation:

TO=%TO% + x -y <=[veut dire]=> TO=f(%TO%) <=[c'est à dire]=>
NouvelleValeurDeTO = RésultatOpérationsSur(PrécédenteValeurDeTO)

Laurent Dardenne,
je ne suis pas sûr de bien cerner ta demande, regarde si la discussion sur le problème de date répond à ta question.

.
09/10/2008, 23h12
Laurent Dardenne

Citation:

Envoyé par maxim_um

Laurent Dardenne,
je ne suis pas sûr de bien cerner ta demande, regarde si la discussion sur le problème de date répond à ta question.

Et moi je ne comprend pas de quoi tu parles ?
:koi:
Tu réponds à la question que j'ai posé à magma² ?
09/10/2008, 23h15
maxim_um

salut
oui, la dernière question, car il me semblait que tu t'interrogeais sur le format octal de l'interpréteur de commande cmd.