Combobox à 2 colonnes (EXCEL-ACCES)

Bonjour le forum!!!!

Je souhaite créer une combobox à 2 colonnes, dont les données proviennent d'une base de données access.
Souci mon programme plante lorsque je souhaite ajouter des éléments à ma combobox :aie:(Text en vert)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub MiseAjourListeDeroulante()

Dim BD As DAO.Database
Dim RST As DAO.Recordset
Dim NbClient, Compteur As Long

Dim ElementList, NbrElement As Integer

Application.StatusBar = "Chargement des Données Administratives Clients en cours. Veuillez patienter..." 'Affichage Message pour utilisateur
Application.Cursor = xlWait                             'Curseur de la sourie devient un sablier

Set BD = OpenDatabase("R:\Informatique\Formation VBA\toto.mdb") 'Ouverture de la base de données
'Formulation de la requête : choisir sans doublons dans la table T_article le champ CodeClient
Requete = "select distinct ucase(Code_Client),Nom_Societe_Client from T_DonneesAdministrativesClient ;"

Set RST = BD.OpenRecordset(Requete)      'Chargement des données suivant la requête
RST.MoveLast
RST.MoveFirst

NbClient = RST.RecordCount               'Comptage du nombre de lignes du champ code client
CboIdentifiantClient.ColumnWidths = NbClient
CboIdentifiantClient.ColumnWidths = "50; 50"
For Compteur = 1 To NbClient                  'Boucle de chargement des codes clients
    fmChoixClient.CboIdentifiantClient.AddItem
    CboIdentifiantClient.List(Compteur, 0) = RST.Fields(0)
    CboIdentifiantClient.List(Compteur, 1) = RST.Fields(1)
   RST.MoveNext                         'Passe à la ligne suivante
Next Compteur
RST.MoveFirst
RST.Close                                   'Fermeture de la table
BD.Close                                     'Fermeture de la base de données
Set RST = Nothing                        'Déchargement de la mémoire utilisée pour la table
Set BD = Nothing                          'Déchargement de la mémoire utilisée pour la base

Application.StatusBar = ""               'Initialisation zone message
Application.Cursor = xlDefault           'Curseur redevient normal

End Sub

:cry: Quelqu'un aurait-il une petite idée???

Bonjour,

Quel est le message d'erreur? Ceci dit je pense que tu peux simplifier ta boucle:

Code:

1
2
3
4
5
6
7
With CboIdentifiantClient
    For Compteur = 1 To NbClient       'Boucle de chargement des codes clients
        .AddItem rst.Fields(0).Value
        .List(Compteur, 1) = rst.Fields(1).Value
       rst.MoveNext                         'Passe à la ligne suivante
    Next Compteur
End With

Cordialement,

Tirex28/

Salut Tirex28 !!!

c'est l'erreur d'éxécution 381 : impossible de définir la propriété de list. Index de table de propriété non valide :?

Re,

Avec List, les index de lignes et de colonnes commencent à zero.

Code:

1
2
3
4
5
6
7
With CboIdentifiantClient
    For Compteur = 1 To NbClient       'Boucle de chargement des codes clients
        .AddItem rst.Fields(0).Value
        .List(Compteur - 1, 1) = rst.Fields(1).Value
       rst.MoveNext                         'Passe à la ligne suivante
    Next Compteur
End With

Cordialement,

Tirex28/

Parfait TIREX28 :king:

Ca fonctionne bien...

Merci pour ton aide....

@+ Jeanvaljean