Calculer avec des combobox

Version imprimable

05/09/2008, 20h10
mjp06

Calculer avec des combobox

Bonjour,

Dans excel 2003, j'ai la formule suivante pour calculer la moyenne d'une plage en excluant les cellules N/A :

Code:

=SOMME(plage)/NB.SI(plage;">=0")

J'aimerais savoir si je peux faire le même genre de calcul en utilisant des combobox (zone de liste déroulante ayant comme valeur N/A, 0, 1, 2, 3).

Je pense avoir environ 40 combobox.

La personne remplie son formulaire et en bas de la feuille elle doit obtenir sa moyenne. Sa moyenne doit changer automatiquement si elle change ses réponses.

Merci beaucoup à l'avance,

mjp06
05/09/2008, 21h25
ucfoutu

Bonsoir,

Très clair 8O

Mais encore ?

Quielle est la valeur de ta formule qui est modifiée par le choix dans ta combo (et laquelle, de combo, puisque tu en as plusieurs) ?
J'au des difficultés, personnellement, à deviner ...
05/09/2008, 21h37
JackOuYA

Bonsoir,

je rajouterai : elle sont où ces combobox et comment ce nomment'elles?

Bonsoir tlm,

Si je peux me permettre (je me le permet parce que je viens de terminer le bricolage :mrgreen:)

Vu qu'il y a 40 ComboBox à gérer, il serait intéressant de passer par un UserForm et un module de Classe pour éviter de devoir encoder l'événement Change de chaque ComboBox (adapté de l'exemple de Silkyroad dans la FAQ : Comment identifier sur quel contrôle l'utilisateur a cliqué ?)
dans le module du UserForm
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 Private Sub UserForm_Initialize() Dim Ctrl As Control, Cl As Classe1, i As Byte, Tablo As Variant Set Col = New Collection Tablo = Array("N/A", "0", "1", "2", "3") For Each Ctrl In Me.Controls If TypeOf Ctrl Is MSForms.ComboBox Then Set Cl = New Classe1 Set Cl.Cb = Ctrl Col.Add Cl For i = 0 To UBound(Tablo) Ctrl.AddItem Tablo(i) Next End If Next Ctrl End Sub
dans un module standard
Code:

1 2 3 4 5 Public Col As Collection Sub afficher_usf() UserForm1.Show End Sub
dans un module de classe nommé "Classe1"
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 Public WithEvents Cb As MSForms.ComboBox 'gérer l'evenement Change des ComboBox Private Sub Cb_Change() Dim CtrlCb As Control, Result As Integer, Nbr As Byte, Moy As Single For Each CtrlCb In UserForm1.Controls If TypeOf CtrlCb Is MSForms.ComboBox Then Select Case CtrlCb Case 0, 1, 2, 3 Result = Result + CtrlCb Nbr = Nbr + 1 End Select End If Next Moy = Result / Nbr UserForm1.TextBox1 = Moy End Sub
Testé sur 10 ComboBox et No Problemo, peut s'adapter si les contrôles sont directement sur la feuille ;)
.

05/09/2008, 21h54
mjp06

Désolé de ne pas être assez clair,

C'est un formulaire d'évaluation dans excel 2003

Mon combobox sert de liste déroulante et j'ai les valeurs suivantes :

N/A = non applicable donc pas de point
0 = 0 point
1 = 1 point
2 = 2 points
3 = 3 points

Chaque question aura les même choix dans la liste déroulante.

Donc 40 questions, donc 40 combobox...

Donc lorsqu'une personne aura complété son évaluation j'aurai 40 questions avec des notes qui varient de "non applicable" à 3 points.

Il ne faut pas que les "non applicable" fassent baisser la moyenne.

Elle pourra avoir sa note, par exemple : 2,4/3

J'aime mieux la présentation du combobox (on voit vraiment un bouton avec liste déroulante) comparativement à la liste déroulante→données→validation→liste. (on ne voit pas le bouton de défilement avant d'être sur la cellule.

Si vous avez d'autres questions, n'hésitez pas,

Merci à l'avance,

mjp06
05/09/2008, 21h59
JackOuYA

Tu n'as toujours pas répondu aux question posées ..

tes combobox ils sont ou ? s'ils sont sur un UserForm adapte le code à Fring..

s'ils sont sur des feuilles de calcul dis nous leur nom à tes combobox (afin qu'on sache de qu'elle boîte à outils ils viennent ?)
05/09/2008, 23h51
fring

Citation:

Envoyé par JackOuYA

(afin qu'on sache de qu'elle boîte à outils ils viennent ?)

Bonne question, parce que s'ils proviennent du menu "Formulaires"...:aie:
08/09/2008, 16h03
mjp06

Désolé mais quand j’ai répondu à ucfoutu je ne voyais pas encore vos autres questions…

Mes combobox sont dans une feuille excel. Elles s’appellent ComboBox1 à ComboBox40 (je ne les ai pas renommées). Elles viennent de la boite à outils contrôles→Zone de liste déroulante, et non pas de formulaires…

Pour l’instant, j’ai fait un document test et tous les combobox sont sur ma feuille excel.

Si vous pensez que je suis mieux de faire comme le code de fring avec Userform dit-le moi ou si je peux le faire directement dans la feuille. (le moins compliqué svp…)

Et si je protège ma feuille avec un mot de passe est-ce que je vais avoir des problèmes pour l’exécution des macros? La dernière fois j’ai eu des problèmes et les macros étaient dans la feuille excel.

Merci beaucoup de m’aider,

mjp06

J’ai fait un test avec les codes de fring et ça semble fonctionner.

Cependant, je ne suis pas habituée avec les UserForm, mais je pense que j’aimerais mieux le faire dans la feuille excel. Je pense que ce serait plus facile lorsque les utilisateurs complèteront le formulaire. Ils vont ouvrir le document excel et le formulaire serait déjà là à l’écran(feuille1). De plus, je dois ajouter des images et beaucoup de texte et je suis plus à l'aise de le faire sur une feuille.

Alors est-ce qu’on peut modifier le code de fring si je place tous mes ComboBox dans la feuille excel?

N.B. Je vais protéger la feuille par un mot de passe, donc je veux que ma macro fonctionne quand même…

Merci beaucoup,

mjp06

L'adaptation avec les combo dans une feuille est la suivante :

dans le module de ThisWorkbook

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub Workbook_Open()
Dim Obj As OLEObject, Cl As Classe1, i As Byte, Tablo As Variant
 
Set Col = New Collection
Tablo = Array("N/A", "0", "1", "2", "3")
 
For Each Obj In ActiveSheet.OLEObjects
    If TypeOf Obj.Object Is MSForms.ComboBox Then
        Set Cl = New Classe1
        Set Cl.Cb = Obj.Object
        Col.Add Cl
        For i = 0 To UBound(Tablo)
            Obj.Object.AddItem Tablo(i)
        Next
    End If
Next Obj
End Sub

dans un module standard

Code:

Public Col As Collection

dans un module de classe nommé "Classe1"

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Public WithEvents Cb As MSForms.ComboBox
 
'gérer l'evenement Change des ComboBox
Private Sub Cb_Change()
Dim ObjCb As OLEObject, Result As Integer, Nbr As Byte, Moy As Single
 
For Each ObjCb In ActiveSheet.OLEObjects
    Select Case ObjCb.Object.Value
        Case 0, 1, 2, 3
        Result = Result + Val(ObjCb.Object.Value)
        Nbr = Nbr + 1
    End Select
Next
 
Moy = Result / Nbr
 
Sheets(1).TextBox1 = Moy
End Sub

dans le module de la feuille (code pour un bouton RESET)

Code:

1
2
3
4
5
6
7
8
9
Private Sub CommandButton1_Click()
Dim Obj As OLEObject
For Each Obj In ActiveSheet.OLEObjects
    If TypeOf Obj.Object Is MSForms.ComboBox Then
        Obj.Object.Value = ""
    End If
Next Obj
ActiveSheet.TextBox1 = ""
End Sub

Petit exemple ci-joint

Concernant la protection de la feuille, tu peux la protéger en décochant "objets"
.

09/09/2008, 17h49
mjp06
Bonjour,

Merci beaucoup fring pour les codes dans la feuille excel.

J'aimerais avoir le format de mon TextBox1 avec 2 décimales, exemple : 2,47

Pour l’instant, j’ai 1,857143…

J’ai trouvé ce code, mais je ne sais pas où le placer. J’ai essayé dans le Private Sub du TextBox1 mais ça ne fonctionne pas (pas de mise à jour du résultat) :
Code:

1 2 Var = 1 TextBox1.Value = Format(Var, "0.00")
Merci pour l’idée du bouton Reset, je vais l’utiliser.

Tu m’as aussi donné l’idée de mettre un bouton « valider les résultats » pour vérifier si toutes les questions ont été répondues. Si des ComboBox sont vides, on devrait recevoir un message qui dit de répondre toutes les questions. Alors je fais cela comment ?

Merci mille fois,

mjp06

Pour le format de ta TextBox cela se passe dans le module "Classe1"

Code:

Sheets(1).TextBox1 = Format(Moy, "0.00")

Pour ton bouton "Valider", tu peux faire un truc de ce genre

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub CommandButton2_Click()
Dim Obj As OLEObject, Verif As Boolean
For Each Obj In ActiveSheet.OLEObjects
    If TypeOf Obj.Object Is MSForms.ComboBox Then
        If Obj.Object.Value = "" Then
            Verif = True
            Exit For
        End If
    End If
Next Obj
 
If Verif = True Then
    MsgBox "Veuillez répondre à toutes les questions"
Else
    MsgBox "Félicitation, vous avez répondu à toutes les questions"
End If
 
End Sub

09/09/2008, 22h24
mjp06

Bonjour,

Fring est-ce que tu peux faire le test suivant avec ton petit exemple que tu as mis plus haut :

Si tu mets tous les combobox avec une valeur de 3 on devrait avoir une moyenne de 3 dans le textbox1. Cependant, on obtient une moyenne de 2,72773.

Un autre test : si je mets 2 combobox avec une valeur de N/A et les autres avec une valeur de 3, ma moyenne devrait encore être de 3, cependant on obtient 2,66667.

J'essaie de comprendre tes codes vba mais puisque je suis débutante, je ne sais pas quoi changer pour avoir la bonne réponse et obtenir une bonne valeur pour la moyenne.

Merci,

mjp06

En effet...j'ai oublié d'ajouter la condition dans le module de Classe de ne compter que la valeur des ComboBox ce qu'il fait qu'il compte également la valeur dans le TextBox, c'est ce qui fausse le résultat.

Par la même occasion j'ai modifié un peu les autres codes pour supprimer un bug qui survenait lors du reset

Les codes modifiés sont :

dans le module standard

Code:

1
2
Public Col As Collection
Public RAZ As Boolean

dans le module de la feuille (code du bouton Reset)

Code:

1
2
3
4
5
6
7
8
9
10
11
Private Sub CommandButton1_Click()
Dim Obj As OLEObject
RAZ = True
For Each Obj In ActiveSheet.OLEObjects
    If TypeOf Obj.Object Is MSForms.ComboBox Then
        Obj.Object.Value = ""
    End If
Next Obj
ActiveSheet.TextBox1 = ""
RAZ = False
End Sub

dans le module de Classe "Classe1"

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public WithEvents Cb As MSForms.ComboBox
 
'gérer l'evenement Change des ComboBox
Private Sub Cb_Change()
Dim ObjCb As OLEObject, Result As Integer, Nbr As Byte, Moy As Single
 
If RAZ = True Then Exit Sub
 
For Each ObjCb In ActiveSheet.OLEObjects
    If TypeOf ObjCb.Object Is MSForms.ComboBox Then
        Select Case ObjCb.Object.Value
            Case 0, 1, 2, 3
            Result = Result + Val(ObjCb.Object.Value)
            Nbr = Nbr + 1
        End Select
    End If
Next
 
Moy = Result / Nbr
Sheets(1).TextBox1 = Format(Moy, "0.00")
 
End Sub