Problème avec la commande Set

Version imprimable

Bonjour j'écris pour la première fois un fichier batch, et je semble avoir un problème avec la commande set \p...

Voici le code qui ne fonctionne pas
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 :debut echo: Liste des fichiers auxquels vous pouvez ajouter une entête. echo 1: msrttPenp.RBS echo 2: msrttPersonalData.RBS echo 3: msrttPaymentData.RBS set choix= set /p choix = Choisissez un chiffre: if '%choix%'=='1' goto Menu1 if '%choix%'=='2' goto Menu2 if '%choix%'=='3' goto Menu3 echo %choix% n'est pas bon! goto debut
Il ne semble pas que la variable choix soit lu au clavier pour une raison...

Merci à l'avance!

ce n'est pas des apostrophes qu'il faut mais des guillemets, en plus la tu n'en a pas besoin:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
:debut
   echo:  Liste des fichiers auxquels vous pouvez ajouter une entête.
   echo 1:   msrttPenp.RBS
   echo 2:   msrttPersonalData.RBS
   echo 3:   msrttPaymentData.RBS
   set choix=
   set /p choix = Choisissez un chiffre:
   if "%choix%"=="1" goto Menu1
   if "%choix%"=="2" goto Menu2
   if "%choix%"=="3" goto Menu3
   echo %choix% n'est pas bon!
   goto debut

03/09/2008, 14h47
watiero

J'ai effectué la changement et ça ne fonctionne toujours pas...
On dirait qu'il ne prend pas l'entrée au clavier...
03/09/2008, 14h49
koKoTis

fait voir la script entier

Et voilà!

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
@ECHO off
@if not "%ECHO%"=="" ECHO %ECHO%
@if not "%OS%"=="Windows_NT" goto EXIT

   SETLOCAL enableextensions

   if "%1" == "" goto usage1

   :debut
   echo.
   echo:  Liste des fichiers auxquels vous poulez ajouter une entête.
   echo.
   echo   1 - fichier1.RBS
   echo   2 - fichier2.RBS
   echo   3 - fichier3.RBS
   echo.
   set choix=
   set /p choix = Choisissez un chiffre: 
   if "%choix%"=="1" goto Option1
   if "%choix%"=="2" goto Option2
   if "%choix%"=="3" goto Option3
   echo %choix% Votre choix n'est pas valide!
   goto debut
   
   :Option1
   REM /B for binary mode copy
   CD  ..\TextData\PaymentsData
   COPY /B $$.fle Pensions\%1\SentFiles
   CD Pensions\%1\SentFiles
   REM Copy of the header to the file that will be sent
   COPY /B $$.fle+fichier1.rbs xmitPrep.fle
     
   goto end

   :Option2
   REM /B for binary mode copy
   CD  ..\TextData\PersonalData
   COPY /B $$PersData.fle Pensions\%1\SentFiles
   CD Pensions\%1\SentFiles
   
   REM Copy of the header to the file that will be sent
   COPY /B $$PayData.fle+fichier2.rbs xmitPersonalData.fle
     
   goto end

   :Option3
   REM /B for binary mode copy
   CD  ..\TextData\PaymentData
   COPY /B $$PayData.fle Pensions\%1\SentFiles
   CD Pensions\%1\SentFiles
   
   REM Copy of the header to the file that will be sent
   COPY /B $$PayData.fle+fichier3.rbs xmitPaymentData.fle
     
   goto end

   :usage1
   echo Le premier parametre doit representer une date correspondant au nom du repertoire ou se trouve le fichier.

   :end
   ENDLOCAL

Merci!

03/09/2008, 15h05
koKoTis

et ce te renvoi une erreur ou pas ?
03/09/2008, 15h23
watiero

Oui... ça ne semble pas lire mon entrer au clavier...
03/09/2008, 15h24
koKoTis

enfin je voulai dire un message d'erreur ?
03/09/2008, 15h32
watiero

Ah d'accord:oops:

En fait il fait juste continuer en boucle comme si la valeur lue n'était jamais 1,2 ou 3...
03/09/2008, 15h34
koKoTis

ca y est je voi l'erreur, un espace en trop sur cette ligne:

Code:

set /p choix = Choisissez un chiffre:

c'est comme ca:

Code:

set /p choix= Choisissez un chiffre:

c'est souvent les erreur les plu bête que je met du temps a trouver cela m'arrive souvent pour ne pas dite tout le temps ;) :mouarf:
03/09/2008, 15h36
watiero

Merci beaucoup!

Je ne savais pas que les espaces étaient importants...

Encore merci!
03/09/2008, 15h37
koKoTis

ben si tu rajoute un espace aprés la nom de ta variable, ta variable n'est plu %var% mais %var %