Application.FileDialog(msoFileDialogFolderPicker) : peut-on fixer le folder de départ

Version imprimable

Bonjour,

je souhaiterais avec le code suivant que le système soit positionné sur un folder déterminé, celui correspondant à l'ancien choix stocké dans ma feuille excel.

Est-ce possible et si oui comment ? :?
Code:

1 2 3 4 5 6 7 8 9 10 With Application.FileDialog(msoFileDialogFolderPicker) .AllowMultiSelect = False .Title = "Sélectionnez le répertoire" .Show If .SelectedItems.Count > 0 Then Me.Folder_Mxattach = .SelectedItems(1) End If End With
merci.

Connais pas avec Folder mais avec Dialogs, on peut faire des choses ;)

Code:

1
2
3
4
5
6
7
8
Sub UseFileDialogOpen()
Dim chemin As String
    chemin = "H:\xls\"
    ChDrive "H"
    ChDir chemin
    Application.Dialogs(xlDialogOpen).Show
 
End Sub

27/08/2008, 14h59
Godzestla

re,

ton code marche, alors que

Code:

Application.FileDialog(msoFileDialogFolderPicker)

ne tient pas compte de CHdrive et du Chdir, contrairement à

Code:

Application.Dialogs

mais je cherche un folder et pas un fichier.

tant pis. Je reste sur ma fenêtre qui s'ouvre au dernier endroit utilisé.
Con mais je peux vivre avec.

merci quand-même.

je ferme le post/

:roll:

Si, si on peut (même 3 ans après...)

voilà ce que j'ai trouvé et qui fonctionne très bien :ccool: :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Function BrowseFolder(Title As String, _
        Optional InitialFolder As String = vbNullString, _
        Optional InitialView As Office.MsoFileDialogView = _
            msoFileDialogViewList) As String
    Dim V As Variant
    Dim InitFolder As String
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = Title
        .InitialView = InitialView
        If Len(InitialFolder) > 0 Then
            If Dir(InitialFolder, vbDirectory) <> vbNullString Then
                InitFolder = InitialFolder
                If Right(InitFolder, 1) <> "\" Then
                    InitFolder = InitFolder & "\"
                End If
                .InitialFileName = InitFolder
            End If
        End If
        .Show
        On Error Resume Next
        Err.Clear
        V = .SelectedItems(1)
        If Err.Number <> 0 Then
            V = vbNullString
        End If
    End With
    BrowseFolder = CStr(V)
End Function

lien : http://www.cpearson.com/excel/browsefolder.aspx

Pour ceux qui tombent dessus ...

21/11/2017, 15h24
Slight50

Et ça sert ! (Même presque 6 ans après !)

Merci !

Citation:
Envoyé par Godzestla
Bonjour,

je souhaiterais avec le code suivant que le système soit positionné sur un folder déterminé, celui correspondant à l'ancien choix stocké dans ma feuille excel.

Est-ce possible et si oui comment ? :?
Code:

1 2 3 4 5 6 7 8 9 10 With Application.FileDialog(msoFileDialogFolderPicker) .AllowMultiSelect = False .Title = "Sélectionnez le répertoire" .Show If .SelectedItems.Count > 0 Then Me.Folder_Mxattach = .SelectedItems(1) End If End With
merci.
Code:

Application.FileDialog(msoFileDialogOpen).InitialFileName = "D:\votre dossier\"