Exporter graphique vers image

Version imprimable

Bonjour à tous,
j'aimerais exporter 4 graphiques en une seul image, miracle j'ai trouvé exactement le code qu'il me falait dans les Faqs, mais il y a une erreur ...
J'ai 4 graphiques à exporter sur la "Feuil2"

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
Option Explicit
 
Private Const Fichier As String = "C:\ImageTemp.gif"
 
 
Sub ExporteGIF_GroupeGraphiques()
   Dim Sh As Shape
   Dim Tableau(1 To 4) As String
   Dim i As Integer, Nb As Integer
   'Supprime l'image temporaire si elle existe
   If Dir(Fichier) <> "" Then Kill Fichier
 
    'Boucle sur les 4 premiers graphiques de la feuille active
    For i = 1 To 4
        Tableau(i) = ActiveSheet.ChartObjects(i).Name
    Next
 
    'Regroupe les graphiques
    Set Sh = ActiveSheet.Shapes.Range(Tableau).Group
 
 
    'copie la forme
    Sh.CopyPicture
    'crée un graphique
    With ActiveSheet.ChartObjects.Add(0, 0, _
                        Sh.Width, Sh.Height).Chart
        .Paste 'colle l'image dans graphique
        ' enregistre le graphique au format gif
        .export Fichier, "GIF"
    End With
 
    Nb = ActiveSheet.ChartObjects.Count
    'supprime le graphique
    ActiveSheet.ChartObjects(Nb).Delete
 
    Sh.Ungroup
End Sub

26/08/2008, 14h29
mat-tech

Sans doute parceque l'erreur est :

Citation:

Erreur d'exécution '1004'
Ce paramètre n'a pas une valeur valide

Esi je lance le débogage, il stop à la ligne

Citation:

Set Sh = ActiveSheet.Shapes.Range(Tableau).Group
26/08/2008, 15h52
fring

Merci d'avoir précisé l'erreur ;)

J'ai ramé sur ce code...je suis parvenu à le faire fonctionner en changeant la déclaration de la variable Tableau de type Variant au lieu de type String

Code:

Dim Tableau(1 To 4) As Variant
26/08/2008, 16h44
mat-tech

Est-il possible, lors de l'enregistrement de l'image d'avoir l'invite 'Enregistrer sous ...', afin de pouvoir choisir le nom et l'endroit où on veut enregistrer l'image ainsi créé ?

Un truc de ce style ? (remplace le code initial par celui-ci)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Option Explicit
 
Sub ExporteGIF_GroupeGraphiques()
Dim Fichier As Variant, Tableau(1 To 4) As Variant
Dim Sh As Shape, i As Integer, Nb As Integer
 
'Boucle sur les 4 premiers graphiques de la feuille active
For i = 1 To 4
    Tableau(i) = ActiveSheet.ChartObjects(i).Name
Next
 
'Regroupe les graphiques
Set Sh = ActiveSheet.Shapes.Range(Tableau).Group
 
'copie la forme
Sh.CopyPicture
 
'crée un graphique
With ActiveSheet.ChartObjects.Add(0, 0, Sh.Width, Sh.Height).Chart
    .Paste 'colle l'image dans graphique
 
    ' enregistre le graphique au format gif
    Fichier = Application.GetSaveAsFilename(fileFilter:="Fichier Image (*.gif), *.gif")
    If Fichier = False Then
        MsgBox "vous avez annulé l'opération" & Chr(10) & "l'image ne sera pas exportée"
    Else
        .Export Fichier, "GIF"
    End If
End With
 
Nb = ActiveSheet.ChartObjects.Count
'supprime le graphique
ActiveSheet.ChartObjects(Nb).Delete
 
Sh.Ungroup
End Sub

Pour info afin de compléter l'explication de la FAQ, quelle version d'Excel utilises-tu ?

28/08/2008, 12h46
mat-tech

Dans le bas de l'image exporter est-il possible d'y inclure le pieds de page de la Feuil d'où ont été copiés les graphiques ? :aie:
06/09/2008, 16h08
fring

Si c'est toujours d'actualité :aie:...une solution via une zone de texte dans le fichier joint.

test graph.zip
.
06/09/2008, 21h01
mat-tech

Magnifique, c'est exactement la réponse à ma question, merci beaucoup :D