Export Excel d'une requête paramétrée

Version imprimable

Bonjour,
je souhaite exporter le résultat d'une requête paramétrée vers Excel en utilisant TransferSpreadsheet.
Le problème est que le paramètre est contenu dans une variable mais je n'arrive pas à l'imposer lors de l'export. Access me demande systématiquement de taper la valeur. Avez-vous une idée ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
    Dim oXLApp As Object 
    Set oXLApp = CreateObject("Excel.Application")
    Dim qdf As QueryDef, var as integer
    var = 50
 
    Set qdf = CurrentDb.CreateQueryDef("export", "PARAMETERS [ID_Scenario] Short; SELECT * FROM Calcul_Scénarios WHERE ID = [ID_Scenario];")
    qdf.Parameters("[ID_Scenario]") = var
 
    DoCmd.TransferSpreadsheet acExport, 0, qdf.name, "C:\Export_from_DimPool.xls", True, ""    
 
    DoCmd.DeleteObject acQuery, qdf.name                                            
    Set qdf = Nothing
    oXLApp.Workbooks.Open ("C:\Export_from_DimPool.xls")
    oXLApp.Visible = True        
    Set oXLApp = Nothing

26/08/2008, 00h44
loufab

Bonjour,

Et comme ceci ne il devrait plus rien demander.

Code:

Set qdf = CurrentDb.CreateQueryDef("export", "SELECT * FROM Calcul_Scénarios WHERE ID = " & var & ";")

Il existe également une technique de transfert de recordset. Sur des fichiers Excel existant c'est souvent plus rapide.

Cordialement,
26/08/2008, 09h33
dut-dut

Hmmm... :|
Merci de ta réponse.

En fait le code SQL, je le pioche dans la propriété rowsource d'une zone de liste via une variable de type String. Je voulais donc essayer de trouver une solution permettant de l'utiliser brut sans avoir à retoucher la syntaxe telle que tu le proposes.

Si quelqu'un a une autre proposition...
@+ Guillaume

Eureka !

Bonjour à tous,
j'ai résolu mon problème en utilisant la méthode CopyFromRecorset de la manière suivante, ce qui évite de modifier le SQL de la requête paramétrée.

A+ ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Function Export_to_Excel(ParamValue As Variant)
    Dim oXLApp As Object ' *** Excel.Application
    Dim oWork As Workbook
    Dim oFeuille As Worksheet
 
    Set oXLApp = CreateObject("Excel.Application")
    Set oWork = oXLApp.Workbooks.Add
    Set oFeuille = oWork.Worksheets(1)
    oXLApp.Visible = True
 
    Dim qdf As QueryDef
    Dim rst As Recordset
    Dim fld As Field
    Dim i As Integer
 
 
    '   ouvre la requete dans un recordset avec le paramètre
    Set qdf = CurrentDb.CreateQueryDef("export", "PARAMETERS [ID_Scenario] Short; SELECT * FROM Calcul_Scénarios WHERE ID = [ID_Scenario];")
    qdf.Parameters("[ID_Scenario]")  = ParamValue
    Set rst = qdf.OpenRecordset
 
    ' copie les en-têtes
    i = 1
    For Each fld In rst.Fields
        oFeuille.Cells(1, i).Value = fld.Name
        i = i + 1
    Next fld
 
    ' copie le contenu du recordset
    oFeuille.Cells(2, 1).CopyFromRecordset rst
 
 
    rst.Close
    qdf.Close
    Set rst = Nothing
    Set qdf = Nothing
    Delete_Query "export"
    Set oFeuille = Nothing
    Set oWork = Nothing
    Set oXLApp = Nothing
End Function

Je fais une recherche sur le forum et je trouve la réponse à mon problème du jour dans un post que j'avais créé il y a 3 ans... :aie:
Faut que je parte en vacances moi ! :sleep:

Allez, petit bonus pour la peine : les maniaques de l'économie de ligne de code remplaceront
Code:

1 2 3 4 5 6 ' copie les en-têtes i = 1 For Each fld In rst.Fields oFeuille.Cells(1, i).Value = fld.Name i = i + 1 Next fld
par
Code:

1 2 3 4 ' copie les en-têtes For Each fld In rst.Fields oFeuille.Cells(1, fld.OrdinalPosition + 1).Value = fld.Name Next fld