Lire des données excel après modification de celles-ci

Version imprimable

30/07/2008, 16h01
skytofer31

Lire des données excel après modification de celles-ci

Bonjour,

Je vais solliciter votre aide car j'ai un souci avec les objets ole sous vb.

J'ai besoin de manipuler une feuille excel puis d'importer ensuite ses données dans mon programme vb.

J'ai trouvé pour cela plusieurs solutions :
- soit créer un tableau excel comme ceci

Code:

Set appExcel = CreateObject("Excel.Application")

J'ai ensuite accès à ma fenêtre, je peux faire des saisies, des calculs, mais lorsque ces calculs sont terminés je ne sais pas comment faire pour dire à mon programme vb de reprendre la main pour effectuer à son tour ses traitements sur mes données excel.

- soit utiliser un objet ole de type excel. Comme ça j'ai une fenêtre excel au milieu de mon interface graphique vb dans laquelle je peux faire mes saisies. Mais là encore comment je fais ensuite pour récupérer les valeurs de ma feuille ? Je n'ai pas trouvé de méthode sur l'objet ole qui aille dans ce sens.

Si vous aviez une idée ou une autre solution car là je vous avoue que je bloque un peu.

Merci par avance.
30/07/2008, 19h25
Delbeke

Le sujet est un peu vaste pour répondre ici. Je te conseille de lire cette FAQ.

Tu y trouveras toutes les infos dont tu as besoin.
31/07/2008, 08h38
skytofer31

Merci de ton retour.

Justement j'ai déjà fouiné sur plusieurs forums avant de venir sur ce forum et j'étais tombé sur ta FAQ mais celle-ci ne répond pas tout à fait à ma question.

Ce que je veux juste savoir c'est s'il est possible de récupérer des données d'une feuille excel qui se trouve dans un objet OLE directement via mon programme VB ? En gros est ce que je peux faire
OLE1.FeuilleExcel.Cells... pour récupérer ses données.

A moins que ce soit impossible ?

Voici ce que j'avais ecrit dans un ancien post

Citation:

Envoyé par Delbeke

Encore merci a tous ceux qui m'ont aidé a trouver une solution honorable

Et aux autres aussi :)

voila le code qui semble fonctionner dans tous les cas

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
Option Explicit
 
Dim WithEvents AppExcel As Excel.Application  'atention, déclaré avec withevent
Dim WbExcel As Excel.Workbook
Dim WsExcel As Excel.Worksheet
Dim ExcelOnLine As Boolean        'flag à true si excel etait déjà ouvert
                                  'quand on a ouvert le fichier
Dim ExcelClosable As Boolean      'flag mis à false tant que l'on a pas décidé
                                  'qu'excel pouvait être fermé
 
Private Sub AppExcel_WorkbookBeforeClose(ByVal Wb As Excel.Workbook, Cancel As Boolean)
  'evenement declenché par l'objet Excel.Application
  'à chaque fermeture de workbook
  'note : si plusieurs feuilles sont fermées par la fermeture d'excel
  '       un seul refus empeche sa fermeture
  If Wb Is WbExcel Then
    'il s'agit de la fermeture de notre feuille
    If ExcelClosable Then
      'on a autorisé la fermeture d'excel, donc on ne fait rien
    Else
      'on refuse la fermeture du workbook
      Cancel = True
    End If
  End If
End Sub
 
 
Private Sub cmdOpenFile_Click()
  On Error Resume Next
  'on va essayer de retrouver une occurence de appExcel
  'si excell n'est pas lancé, on aura une erreur que
  'l'on va trapper
  Set AppExcel = GetObject(, "Excel.Application")
  If Err Then
    'excel n'est pas démarrer
    'on le démarre
    Set AppExcel = CreateObject("Excel.Application")
    ExcelOnLine = False
  Else
    'excel est démarré
    ExcelOnLine = True
  End If
 
  AppExcel.Application.Visible = True
  AppExcel.Application.Interactive = True
  'ouverture du workbook
  Set WbExcel = AppExcel.Workbooks.Open(txtFileName.Text)
  'et on refuse la fermeture d'excel
  ExcelClosable = False
  Set WsExcel = WbExcel.Worksheets(1)
  WsExcel.Unprotect
End Sub
 
Private Sub cmdWriteCell_Click()
  'un exemple d'ecriture dans la feuille
  WsExcel.Cells(1, 1) = "AAA"
 
End Sub
 
Private Sub cmdCloseFile_Click()
  'on  ferme notre fichier
  'donc excel doit pouvoir être fermé
  ExcelClosable = True
  WbExcel.Close False 'sans enreister pour ce simple test
  If ExcelOnLine Then
    'si excell etait lancé au démarrage
    'on n'a rien à faire
  Else
    'si on a lancé excel
    'on vérifie s'il reste de workbooks ouverte
    If AppExcel.Workbooks.Count = 0 Then
      'plus de workbooks, on ferme excel
      AppExcel.Quit
    End If
  End If
  'un peu de ménage
  Set WsExcel = Nothing
  Set WbExcel = Nothing
  Set AppExcel = Nothing
End Sub

Ajouter sur une feuille,
un textbox : txtFileName
trois boutons de commandes : cmdOpenFile,cmdWriteCell,cmdCloseFile
et coler le code ci-dessus dans la feuille.

La lecture de cellule n'etant pas invoquée ici

Code:

1
2
3
4
5
Private Sub cmdReadCell_Click()
  'un message box pour afficher le contenu de la callulle 1-1
  Msgbox WsExcel.Cells(1, 1) 
 
End Sub

31/07/2008, 15h44
skytofer31

Merci beaucoup !

Je ne connais pas le

Code:

Dim WithEvents AppExcel As Excel.Application

ainsi que la procédure

Code:

Private Sub AppExcel_WorkbookBeforeClose

et je t'avoue que c'est exactement ce que je cherchais.

je vais tester ça, merci pour ton aide ;)
31/07/2008, 17h20
skytofer31

Vraiment nikel, ça marche impec !

Merci pour tout :yaisse2:
31/07/2008, 17h57
Delbeke

Alors , n'oublie de cliquer sur le bouton :resolu: , Merci
02/08/2008, 15h24
zazaraignée

Citation:

Envoyé par skytofer31

Vraiment nikel, ça marche impec !

Merci pour tout :yaisse2:

Chouette ! Alors, n'oublie pas de cliquer sur le bouton :resolu: .