Vérification d'une copie à partir d'un CSV

Version imprimable

15/07/2008, 15h07
Xavstarblues

Vérification d'une copie à partir d'un CSV

Bonjour, je viens encore vous soumettre un soucis (encore pire que le dernier)
J'ai besoin de créer un batch (j'ai malheureusement assez peu de temps pour developper dans un autre langage, le batch étant celui que je connais le mieux).

Ce batch doit faire plusieurs tâches.
Je vais commencer par expliquer l'environnement de travail:
Un applicatif externe vient déposer de nouveaux fichiers dans des repertoires (ces repertoires n'étant pas toujours les mêmes).
J'ai besoin d'une appli qui me permettent de vérifier le bon dépot des fichiers.

1-Un fichier CSV est crée par l'utilisateur (moi en l'occurrence) à partir d'un fichier Excel, ce fichier csv comprends les données suivantes:
Répertoire - nom du fichier - version - date de modification -taille (en octets)

2-Pour chaque ligne du fichier CSV, le programme récupere une variable pour chaque colonne(boucle For?), VarRep, VarNom,VarVers,VarDate,VarTaille.

3-en faisant ensuite un dir VarRep/VarNom (toujours dans ma boucle!), j'aimerai sortir les variables VarDate1 et VarTaille1 et les comparer aux VarDate et VarTaille.

4-Si il ya une différence, l'appli génére une ligne (comprenant les infos fichier et sur quelle variable est l'erreur) dans un fichier de log(et on reprend la boucle).

5-Affichage du fichier de log

Cette démarche vous parait elle possible? (je bloque un peu sur l'extraction des donnés du CSV)

Merci de vos retours, je bosse sur une premiere version du code :)..
16/07/2008, 09h38
Drizzt [Drone38]

Citation:

1-Un fichier CSV est crée par l'utilisateur (moi en l'occurrence) à partir d'un fichier Excel, ce fichier csv comprends les données suivantes:
Répertoire - nom du fichier - version - date de modification -taille (en octets)

2-Pour chaque ligne du fichier CSV, le programme récupere une variable pour chaque colonne(boucle For?), VarRep, VarNom,VarVers,VarDate,VarTaille.

Boucle FOR sur ton fichier en spécifiant les bon tokens.

Citation:

3-en faisant ensuite un dir VarRep/VarNom (toujours dans ma boucle!), j'aimerai sortir les variables VarDate1 et VarTaille1 et les comparer aux VarDate et VarTaille.

Boucle FOR sur la commande dir. Idem les tokens qui vont bien sont tes amis (faudra trier un peu pour traiter que la ligne du fichier)

Citation:

4-Si il ya une différence, l'appli génére une ligne (comprenant les infos fichier et sur quelle variable est l'erreur) dans un fichier de log(et on reprend la boucle).

IF, puis une redirection d'echo vers ton fichier log

Citation:

5-Affichage du fichier de log

Type.
16/07/2008, 15h04
Xavstarblues

merci de confirmer pour la boucle FOR
J'essaye de voir ce que ca peut donner de mon coté, et je te tiens au courant

bonjour, j'ai un peu du mal a me depaitouiller avec ma commande for
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 @echo off if EXIST d:\tempverif\ goto next mkdir D:\tempverif :next copy a:verif.csv D:\tempverif\ Rem déclaration des variables set VarDir=0 set VarNom=0 Set VarTaille=0 Set VarDate=0 Set VarTaille1=0 Set VarDate1=0 setlocal enabledelayedexpansion FOR /F " tokens=1,2* delims=, " %i in (d:\tempverif\verif.csv) do echo %j% %k%
la je suis juste sur la partie pour me sortir %j% et %k% (respectivement VarDir et VarNom) mais le programme plante au moment de la boucle for...
et je ne vois pas pourquoi....

21/07/2008, 10h56
Xavstarblues

bonjour
Je suis toujours bloqué sur ma boucle for...j'ai essayé à partir d'un csv, d'un txt, rien de passe, le programme plante toujours

en me référant à la doc for /?, j'ai établi que logiquement ma boucle devrait ressembler à cela

Code:

FOR /F " tokens=1,2 delims=; " %i in (d:\tempverif\verif.csv) do echo %i% %j% %k%

j'ai essayé en demandant d'afficher autre chose (echo yahoo), en mettant /enlebant des ' ou des " ou des (), mais rien n'y fait....

Merci de votre aide
21/07/2008, 11h36
Xavstarblues

OK, j'ai trouvé en executant via le dos , la bonne syntaxe (pour me sortir les valeurs qui m'interessent)

Code:

FOR /F " tokens=1,2 delims=; " %i in (d:\tempverif\verif.csv) do echo %i %j

en Commande Dos =>Ok
dans mon batch NOK
dans un batch vierge avec juste cette ligne (rien, même pas d'@echo off) =>NOK

si qqn voit ce qui se passe....
21/07/2008, 13h37
Xavstarblues

je vais continuer a faire ma propre evaluation
en lancant le programme via le ms-dos j'ai droit a un beau

Code:

tempverif\verif.csv) était inattendu

je cherche encore.... (je vais y arriver, sailphe-médemanne)
21/07/2008, 16h01
maxim_um

salut.

Tu rencontres des erreurs parce que tu utilises mal les paramètres remplaçables de type "%x".
Dans un fichier script, le modulo doit être dédoublé tel que "%%x".
Depuis la ligne de commande, il faut en noter qu'un: "%x".
22/07/2008, 08h32
Xavstarblues

Merci du coup de pouce , je me disais bien que c'était devant mon nez ....
Je vais enfin pouvoir avancer....

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
@echo off & color 0A


set vrLog=%userprofile%\Bureau\log_verif_copy.log
set vrFchCsv=fichier.csv

if not exist "%vrLog%" goto sautSuppr
if exist "%vrLog%" set /p vrRepsUser= Voulez vous supprimer l'ancien fichier log ? (o pour oui ou entrer pour non)
if !%vrRepsUser%==! goto sautSuppr
if %vrRepsUser%== o del "%vrLog%"
if %vrRepsUser%== oui del "%vrLog%"
:sautSuppr



if not exist "c:\tempverif" mkdir "c:\tempverif"
copy "a:\verif.csv" "c:\tempverif"



set datetimetmp=%date:~0,2%-%date:~3,2%-%date:~6,4%_%time:~0,2%-%time:~3,2%
 set datetimetmp=%datetimetmp: =%


for /f "tokens=1,2,4,5 delims=;" %%i in ('type "%vrFchCsv%"') do set vrRep=%%i& set vrNom=%%j& set vrDate=%%k& set vrTaille=%%l& call :etap2
goto :fin


:etap2

if not exist "%vrRep%\%vrNom%" echo Le fichier %vrRep%\%vrNom% n'existe pas>> "%vrLog%" & goto :eof

for %%i in ("%vrRep%\%vrNom%") do set vrDate2=%%~ti& set vrTaille2=%%~zi& call :compVar

goto :eof


:compVar

set vrDate2a=%vrDate2:~0,10%

if not "%vrDate2a%"=="%vrDate%" echo Date diff‚rente pour le fichier %vrRep%\%vrNom% Date enregistrer %vrDate% Date du fichier %vrDate2a%>> "%vrLog%"
if not "%vrTaille2%"=="%vrTaille%" echo Poid diff‚rent pour le fichier %vrRep%\%vrNom% Taille enregistrer %vrTaille% Taille du fichier %vrTaille2%>>  "%vrLog%"

goto :eof


:fin

cls & type "%vrLog%"

if not exist "%vrLog%" goto sautOuvrLog
echo.&echo.&echo.& set /p vrRepsUser2= Voulez vous ouvrir le log avec le bloc note ? (o pour oui ou entrer pour non)
if !%vrRepsUser2%==! goto sautOuvrLog
if %vrRepsUser2%== o notepad "%vrLog%"
if %vrRepsUser2%== oui notepad "%vrLog%"
:sautOuvrLog


pause>nul

Je reviens sur le forum...
Suite aux soucis des serveurs l'été dernier certains messages avaient disparus et je n'ai jamais pris le temps de reposter mon code.
Voici donc le code final pour mon programme:
Si vous avez des questions :)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
::---------------------------------------------------------------
::Programme pour vérifier que les fichiers de la télédiff ont bien été déposés aux bons endroits
::---------------------------------------------------------------
cls
@echo off & color 3A
title -=V‚rification fichiers Diffusion=-


::---------------------------------------------------------------
::Déclaration des variables
::---------------------------------------------------------------
set vrLog=c:\log_verif_copy.log
set vrFchCsv=a:\verif.csv
del a:\log_verif_copy.log
::set datetimetmp=%date:~0,2%-%date:~3,2%-%date:~6,4%_%time:~0,2%-%time:~3,2%
::set datetimetmp=%datetimetmp: =%
echo                        Rapport d'erreurs (T‚l‚)Diffusion>> "%VrLog%"
echo.>> "%VrLog%"
echo.>> "%VrLog%"

::---------------------------------------------------------------
::Début programme
::---------------------------------------------------------------
echo "Analyse en Cours"


::---------------------------------------------------------------
::Pour chaque ligne du CSV, on récupere le nom du dossier,
:: le nom du fichier, la taille et la date
::---------------------------------------------------------------
for /f "tokens=1,2,4,5 delims=;" %%i in ('type "%vrFchCsv%"') do set vrRep2=%%i& set vrNom=%%j& set vrDate=%%k& set vrTaille=%%l& call :etap2
goto :fin


:etap2
::---------------------------------------------------------------
::On teste si le fichier existe , si oui, on récupere la taille et la date
::---------------------------------------------------------------
set VrRep=%VrRep2:~0,3%
if not exist "E:\%vrRep%\%vrNom%" echo  Le fichier E:%vrRep%\%vrNom% n'existe pas>> "%vrLog%"& goto :eof
for %%i in ("E:\%vrRep%\%vrNom%") do set vrDate2=%%~ki& set vrTaille2=%%~zi& call :compVar
goto :eof


:compVar
::---------------------------------------------------------------
::On compare les données extraites du CSV et celles trouvées sur l'ordinateur
::et on envoie le résultat vers %VrLog%
::---------------------------------------------------------------
set vrDate2a=%vrDate2:~0,10%
if not "%vrDate2a%"=="%vrDate%" echo  %vrRep%\%vrNom% Date enregistr‚e %vrDate% Date du fichier %vrDate2a%>> "%vrLog%"
if not "%vrTaille2%"=="%vrTaille%" echo  %vrRep%\%vrNom% Taille enregistr‚e %vrTaille% Taille du fichier %vrTaille2%>> "%vrLog%"
goto :eof


:fin
::---------------------------------------------------------------
::Affichage du résultat et sortie de programme
::---------------------------------------------------------------
if exist %VrLog% copy %Vrlog% a:>nul
if not exist "%vrlog%" echo    "Aucune Erreur Detect‚e" >%VrLog%
cls
echo ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍV‚rification des fichiersÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»
type "%VrLog%"                                                     
echo ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍOp‚ration termin‚eÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ¼
Echo.
set choix=
set /p choix=Voulez vous imprimez (Oui/Non)?
if %choix%== O (goto imp) else if %choix%== o (goto imp) else goto sortie

:imp
print %VrLog%>nul
goto sortie

:sortie
del %VrLog%
Echo Fin du programme
Echo Appuyez sur une touche pour quitter, le rapport a ‚t‚ copi‚ sur la disquette
pause>nul
cls
exit

Il me reste qq améliorations (genre ne plus passer par la disquette , etc), mais le programme est fonctionnel et peut servir de base a qqn d'autre.