Utiliser un "groupe" de labels sur clic souris dans un Userform

Version imprimable

12/04/2008, 14h21
ouskel'n'or

Utiliser un "groupe" de labels sur clic souris dans un Userform
Un userform,
une série de labels dont chaque Caption correspond à autant de champs de saisie.
Code:

1 2 Label Label Label ... Champ Champ Champ ...
Souhaitant utiliser l'événement MouseDown sur l'ensemble des labels pour afficher un message identique, (masqué par MouseUp) j'ai pensé les grouper et réaliser une procédure unique.
Les grouper, l'éditeur vba le permet.
Le controlTipText du groupe fonctionne.
Par contre, impossible de nommer le groupe (comme avec les CheckBox ou OptionButton)
- la propriété GroupeName n'existe pas pour le groupe
- la propriété Name pour le groupe non plus

Les collections :
J'ai testé en créant une collection des différents labels concernés, et un module de classe pour intercepter les événements subis par les labels.
Malheureusement, si les événements DblClick et change sont bien interceptés, il n'en est pas de même des événements MouseDown et MouseUp.

Existerait-t-il une solution "simple", avec des label (sans utiliser des textbox) qui puisse résoudre ce problème :

Citation:

MouseDown sur l'un quelconque de plusieurs labels conduisant à un message unique par une procédure unique.
(MouseUp devant masquer le message)

Par avance, merci de votre réponse.

Bonsoir,

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
'Un module de classe nommé LabelsEvents
Option Explicit
Public WithEvents MyLabel As MSForms.Label
 
Private Sub MyLabel_MouseDown(ByVal Button As Integer, ByVal Shift As Integer _
                , ByVal X As Single, ByVal Y As Single)
    MyLabel.Parent.Caption = "Afficher un message"
End Sub
 
Private Sub MyLabel_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, _
                ByVal X As Single, ByVal Y As Single)
    MyLabel.Parent.Caption = MyLabel.Parent.Name
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
'Un formulaire contenant 3 labels nommé Label1,Label2 et Label3
Option Explicit
Dim MesLabels As Collection
 
Private Sub UserForm_Initialize()
    Dim LabEvent As LabelsEvents, i As Long
    Set MesLabels = New Collection
    For i = 1 To 3
        Set LabEvent = New LabelsEvents
        Set LabEvent.MyLabel = Me.Controls("Label" & i)
        MesLabels.Add LabEvent
    Next
End Sub

Ca fonctionne tres bien chez moi, mais je n'ai peut etre pas compris ce que tu cherche a faire.

Cordialement,

Tirex28/

12/04/2008, 22h56
ouskel'n'or

Hello tirex ! :king:
Tu sais quoi ? Je n'avais ni l'événement MouseDown ni up.
J'ai posé ma question
J'ai fermé le fichier
Pour tester ton code, je l'ai réouvert prêt à ajouter ces deux événements même s'ils n'apparaissaient pas dans la liste dans le module de classe, et tu ne sais pas mais ils sont tous là, de BeforeDragOver à MouseUp.
Sans toi, je n'y serais jamais retourné !
Un grand merci
12/04/2008, 23h29
tirex28

Re,

Citation:

Un grand merci

De rien, pour info les évènements d'un objet sont répertoriés dans l'explorateur d'objet au même titre que ses méthodes et propriétés.

A+

Tirex28/
13/04/2008, 02h01
ouskel'n'or

En principe ils apparaissent dans le module de classe mais j'ai eu un problème. J'en ai d'ailleurs plusieurs avec ce foutu fichier : Je mets un bouton, j'écris du code "derrière", j'exécute, le bouton disparaît, le code reste.
Je relance l'ouverture de l'usf, l'usf n'est plus reconnu... etc.
Finalement, j'ai effacé la macro d'ouverture, l'ai ré-écrite et tout est rentrée dans l'ordre... pour le moment ! :arf: :mur: :marteau: :zekill: :evilred:
Depuis, j'ai fermé le fichier et je suis passé à autre chose.